m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 27
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([_Noreturn],
  16 [/* The _Noreturn keyword of draft C1X.  */
  17 #if ! defined _Noreturn && __STDC_VERSION__ < 201000L
  18 # if (3 <= __GNUC__ || __GNUC__ == 2 && 8 <= __GNUC_MINOR__ \
  19       || 0x5110 <= __SUNPRO_C)
  20 #  define _Noreturn __attribute__ ((__noreturn__))
  21 # else
  22 #  define _Noreturn
  23 # endif
  24 #endif
  25 ])
  26   AH_VERBATIM([isoc99_inline],
  27 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  28    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  29    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  30    __APPLE__ && __MACH__ test for MacOS X.
  31    __APPLE_CC__ tests for the Apple compiler and its version.
  32    __STDC_VERSION__ tests for the C99 mode.  */
  33 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  34 # define __GNUC_STDC_INLINE__ 1
  35 #endif])
  36   AH_VERBATIM([unused_parameter],
  37 [/* Define as a marker that can be attached to declarations that might not
  38     be used.  This helps to reduce warnings, such as from
  39     GCC -Wunused-parameter.  */
  40 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  41 # define _GL_UNUSED __attribute__ ((__unused__))
  42 #else
  43 # define _GL_UNUSED
  44 #endif
  45 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  46    is a misnomer outside of parameter lists.  */
  47 #define _UNUSED_PARAMETER_ _GL_UNUSED
  48
  49 /* The __pure__ attribute was added in gcc 2.96.  */
  50 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
  51 # define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
  52 #else
  53 # define _GL_ATTRIBUTE_PURE /* empty */
  54 #endif
  55
  56 /* The __const__ attribute was added in gcc 2.95.  */
  57 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
  58 # define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
  59 #else
  60 # define _GL_ATTRIBUTE_CONST /* empty */
  61 #endif
  62 ])
  63   dnl Preparation for running test programs:
  64   dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
  65   dnl to /dev/tty, so they can be redirected to log files.  Such diagnostics
  66   dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
  67   LIBC_FATAL_STDERR_=1
  68   export LIBC_FATAL_STDERR_
  69 ])
  70
  71 # gl_MODULE_INDICATOR_CONDITION
  72 # expands to a C preprocessor expression that evaluates to 1 or 0, depending
  73 # whether a gnulib module that has been requested shall be considered present
  74 # or not.
  75 m4_define([gl_MODULE_INDICATOR_CONDITION], [1])
  76
  77 # gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
  78 # sets the shell variable that indicates the presence of the given module to
  79 # a C preprocessor expression that will evaluate to 1.
  80 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
  81 [
  82   gl_MODULE_INDICATOR_SET_VARIABLE_AUX(
  83     [GNULIB_[]m4_translit([[$1]],
  84                           [abcdefghijklmnopqrstuvwxyz./-],
  85                           [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])],
  86     [gl_MODULE_INDICATOR_CONDITION])
  87 ])
  88
  89 # gl_MODULE_INDICATOR_SET_VARIABLE_AUX([variable])
  90 # modifies the shell variable to include the gl_MODULE_INDICATOR_CONDITION.
  91 # The shell variable's value is a C preprocessor expression that evaluates
  92 # to 0 or 1.
  93 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX],
  94 [
  95   m4_if(m4_defn([gl_MODULE_INDICATOR_CONDITION]), [1],
  96     [
  97      dnl Simplify the expression VALUE || 1 to 1.
  98      $1=1
  99     ],
 100     [gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([$1],
 101                                              [gl_MODULE_INDICATOR_CONDITION])])
 102 ])
 103
 104 # gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([variable], [condition])
 105 # modifies the shell variable to include the given condition.  The shell
 106 # variable's value is a C preprocessor expression that evaluates to 0 or 1.
 107 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR],
 108 [
 109   dnl Simplify the expression 1 || CONDITION to 1.
 110   if test "$[]$1" != 1; then
 111     dnl Simplify the expression 0 || CONDITION to CONDITION.
 112     if test "$[]$1" = 0; then
 113       $1=$2
 114     else
 115       $1="($[]$1 || $2)"
 116     fi
 117   fi
 118 ])
 119
 120 # gl_MODULE_INDICATOR([modulename])
 121 # defines a C macro indicating the presence of the given module
 122 # in a location where it can be used.
 123 #                                             |  Value  |   Value   |
 124 #                                             | in lib/ | in tests/ |
 125 # --------------------------------------------+---------+-----------+
 126 # Module present among main modules:          |    1    |     1     |
 127 # --------------------------------------------+---------+-----------+
 128 # Module present among tests-related modules: |    0    |     1     |
 129 # --------------------------------------------+---------+-----------+
 130 # Module not present at all:                  |    0    |     0     |
 131 # --------------------------------------------+---------+-----------+
 132 AC_DEFUN([gl_MODULE_INDICATOR],
 133 [
 134   AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
 135       [abcdefghijklmnopqrstuvwxyz./-],
 136       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
 137     [gl_MODULE_INDICATOR_CONDITION],
 138     [Define to a C preprocessor expression that evaluates to 1 or 0,
 139      depending whether the gnulib module $1 shall be considered present.])
 140 ])
 141
 142 # gl_MODULE_INDICATOR_FOR_TESTS([modulename])
 143 # defines a C macro indicating the presence of the given module
 144 # in lib or tests. This is useful to determine whether the module
 145 # should be tested.
 146 #                                             |  Value  |   Value   |
 147 #                                             | in lib/ | in tests/ |
 148 # --------------------------------------------+---------+-----------+
 149 # Module present among main modules:          |    1    |     1     |
 150 # --------------------------------------------+---------+-----------+
 151 # Module present among tests-related modules: |    1    |     1     |
 152 # --------------------------------------------+---------+-----------+
 153 # Module not present at all:                  |    0    |     0     |
 154 # --------------------------------------------+---------+-----------+
 155 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
 156 [
 157   AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
 158       [abcdefghijklmnopqrstuvwxyz./-],
 159       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
 160     [Define to 1 when the gnulib module $1 should be tested.])
 161 ])
 162
 163 # gl_ASSERT_NO_GNULIB_POSIXCHECK
 164 # asserts that there will never be a need to #define GNULIB_POSIXCHECK.
 165 # and thereby enables an optimization of configure and config.h.
 166 # Used by Emacs.
 167 AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
 168 [
 169   dnl Override gl_WARN_ON_USE_PREPARE.
 170   dnl But hide this definition from 'aclocal'.
 171   AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
 172 ])
 173
 174 # gl_ASSERT_NO_GNULIB_TESTS
 175 # asserts that there will be no gnulib tests in the scope of the configure.ac
 176 # and thereby enables an optimization of config.h.
 177 # Used by Emacs.
 178 AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
 179 [
 180   dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
 181   AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
 182 ])
 183
 184 # Test whether <features.h> exists.
 185 # Set HAVE_FEATURES_H.
 186 AC_DEFUN([gl_FEATURES_H],
 187 [
 188   AC_CHECK_HEADERS_ONCE([features.h])
 189   if test $ac_cv_header_features_h = yes; then
 190     HAVE_FEATURES_H=1
 191   else
 192     HAVE_FEATURES_H=0
 193   fi
 194   AC_SUBST([HAVE_FEATURES_H])
 195 ])
 196
 197 # m4_foreach_w
 198 # is a backport of autoconf-2.59c's m4_foreach_w.
 199 # Remove this macro when we can assume autoconf >= 2.60.
 200 m4_ifndef([m4_foreach_w],
 201   [m4_define([m4_foreach_w],
 202     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
 203
 204 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
 205 # ----------------------------------------------------
 206 # Backport of autoconf-2.63b's macro.
 207 # Remove this macro when we can assume autoconf >= 2.64.
 208 m4_ifndef([AS_VAR_IF],
 209 [m4_define([AS_VAR_IF],
 210 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 211
 212 # AC_PROG_MKDIR_P
 213 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
 214 # for interoperability with automake-1.9.6 from autoconf-2.62.
 215 # Remove this macro when we can assume autoconf >= 2.62 or
 216 # autoconf >= 2.60 && automake >= 1.10.
 217 m4_ifdef([AC_PROG_MKDIR_P], [
 218   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
 219   m4_define([AC_PROG_MKDIR_P],
 220     m4_defn([AC_PROG_MKDIR_P])[
 221     AC_SUBST([MKDIR_P])])], [
 222   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
 223   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
 224     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 225      MKDIR_P='$(mkdir_p)'
 226      AC_SUBST([MKDIR_P])])])
 227
 228 # AC_C_RESTRICT
 229 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
 230 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
 231 # works.
 232 # This definition can be removed once autoconf >= 2.62 can be assumed.
 233 m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.62]),[-1],[
 234 AC_DEFUN([AC_C_RESTRICT],
 235 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
 236   [ac_cv_c_restrict=no
 237    # The order here caters to the fact that C++ does not require restrict.
 238    for ac_kw in __restrict __restrict__ _Restrict restrict; do
 239      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 240       [[typedef int * int_ptr;
 241         int foo (int_ptr $ac_kw ip) {
 242         return ip[0];
 243        }]],
 244       [[int s[1];
 245         int * $ac_kw t = s;
 246         t[0] = 0;
 247         return foo(t)]])],
 248       [ac_cv_c_restrict=$ac_kw])
 249      test "$ac_cv_c_restrict" != no && break
 250    done
 251   ])
 252  AH_VERBATIM([restrict],
 253 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 254    nothing if this is not supported.  Do not define if restrict is
 255    supported directly.  */
 256 #undef restrict
 257 /* Work around a bug in Sun C++: it does not support _Restrict, even
 258    though the corresponding Sun C compiler does, which causes
 259    "#define restrict _Restrict" in the previous line.  Perhaps some future
 260    version of Sun C++ will work with _Restrict; if so, it'll probably
 261    define __RESTRICT, just as Sun C does.  */
 262 #if defined __SUNPRO_CC && !defined __RESTRICT
 263 # define _Restrict
 264 #endif])
 265  case $ac_cv_c_restrict in
 266    restrict) ;;
 267    no) AC_DEFINE([restrict], []) ;;
 268    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 269  esac
 270 ])
 271 ])
 272
 273 # gl_BIGENDIAN
 274 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 275 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 276 # macros invoke AC_C_BIGENDIAN with arguments.
 277 AC_DEFUN([gl_BIGENDIAN],
 278 [
 279   AC_C_BIGENDIAN
 280 ])
 281
 282 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 283 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 284 # output a spurious "(cached)" mark in the midst of other configure output.
 285 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 286 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 287 AC_DEFUN([gl_CACHE_VAL_SILENT],
 288 [
 289   saved_as_echo_n="$as_echo_n"
 290   as_echo_n=':'
 291   AC_CACHE_VAL([$1], [$2])
 292   as_echo_n="$saved_as_echo_n"
 293 ])