m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 16
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([isoc99_inline],
  16 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  17    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  18    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  19    __APPLE__ && __MACH__ test for MacOS X.
  20    __APPLE_CC__ tests for the Apple compiler and its version.
  21    __STDC_VERSION__ tests for the C99 mode.  */
  22 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  23 # define __GNUC_STDC_INLINE__ 1
  24 #endif])
  25   AH_VERBATIM([unused_parameter],
  26 [/* Define as a marker that can be attached to declarations that might not
  27     be used.  This helps to reduce warnings, such as from
  28     GCC -Wunused-parameter.  */
  29 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  30 # define _GL_UNUSED __attribute__ ((__unused__))
  31 #else
  32 # define _GL_UNUSED
  33 #endif
  34 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  35    is a misnomer outside of parameter lists.  */
  36 #define _UNUSED_PARAMETER_ _GL_UNUSED
  37 ])
  38 ])
  39
  40 # gl_MODULE_INDICATOR_CONDITION
  41 # expands to a C preprocessor expression that evaluates to 1 or 0, depending
  42 # whether a gnulib module that has been requested shall be considered present
  43 # or not.
  44 AC_DEFUN([gl_MODULE_INDICATOR_CONDITION], [1])
  45
  46 # gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
  47 # sets the shell variable that indicates the presence of the given module to
  48 # a C preprocessor expression that will evaluate to 1.
  49 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
  50 [
  51   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=gl_MODULE_INDICATOR_CONDITION
  52 ])
  53
  54 # gl_MODULE_INDICATOR([modulename])
  55 # defines a C macro indicating the presence of the given module
  56 # in a location where it can be used.
  57 #                                             |  Value  |   Value   |
  58 #                                             | in lib/ | in tests/ |
  59 # --------------------------------------------+---------+-----------+
  60 # Module present among main modules:          |    1    |     1     |
  61 # --------------------------------------------+---------+-----------+
  62 # Module present among tests-related modules: |    0    |     1     |
  63 # --------------------------------------------+---------+-----------+
  64 # Module not present at all:                  |    0    |     0     |
  65 # --------------------------------------------+---------+-----------+
  66 AC_DEFUN([gl_MODULE_INDICATOR],
  67 [
  68   AC_DEFINE_UNQUOTED([GNULIB_]translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
  69     [gl_MODULE_INDICATOR_CONDITION],
  70     [Define to a C preprocessor expression that evaluates to 1 or 0, depending whether the gnulib module ]$1[ shall be considered present.])
  71 ])
  72
  73 # gl_MODULE_INDICATOR_FOR_TESTS([modulename])
  74 # defines a C macro indicating the presence of the given module
  75 # in lib or tests. This is useful to determine whether the module
  76 # should be tested.
  77 #                                             |  Value  |   Value   |
  78 #                                             | in lib/ | in tests/ |
  79 # --------------------------------------------+---------+-----------+
  80 # Module present among main modules:          |    1    |     1     |
  81 # --------------------------------------------+---------+-----------+
  82 # Module present among tests-related modules: |    1    |     1     |
  83 # --------------------------------------------+---------+-----------+
  84 # Module not present at all:                  |    0    |     0     |
  85 # --------------------------------------------+---------+-----------+
  86 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
  87 [
  88   AC_DEFINE([GNULIB_]translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
  89     [Define to 1 when using the gnulib module ]$1[.])
  90 ])
  91
  92 # m4_foreach_w
  93 # is a backport of autoconf-2.59c's m4_foreach_w.
  94 # Remove this macro when we can assume autoconf >= 2.60.
  95 m4_ifndef([m4_foreach_w],
  96   [m4_define([m4_foreach_w],
  97     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
  98
  99 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
 100 # ----------------------------------------------------
 101 # Backport of autoconf-2.63b's macro.
 102 # Remove this macro when we can assume autoconf >= 2.64.
 103 m4_ifndef([AS_VAR_IF],
 104 [m4_define([AS_VAR_IF],
 105 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 106
 107 # AC_PROG_MKDIR_P
 108 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
 109 # for interoperability with automake-1.9.6 from autoconf-2.62.
 110 # Remove this macro when we can assume autoconf >= 2.62 or
 111 # autoconf >= 2.60 && automake >= 1.10.
 112 m4_ifdef([AC_PROG_MKDIR_P], [
 113   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
 114   m4_define([AC_PROG_MKDIR_P],
 115     m4_defn([AC_PROG_MKDIR_P])[
 116     AC_SUBST([MKDIR_P])])], [
 117   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
 118   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
 119     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 120      MKDIR_P='$(mkdir_p)'
 121      AC_SUBST([MKDIR_P])])])
 122
 123 # AC_C_RESTRICT
 124 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
 125 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
 126 # works.
 127 # This definition can be removed once autoconf >= 2.62 can be assumed.
 128 AC_DEFUN([AC_C_RESTRICT],
 129 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
 130   [ac_cv_c_restrict=no
 131    # The order here caters to the fact that C++ does not require restrict.
 132    for ac_kw in __restrict __restrict__ _Restrict restrict; do
 133      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 134       [[typedef int * int_ptr;
 135         int foo (int_ptr $ac_kw ip) {
 136         return ip[0];
 137        }]],
 138       [[int s[1];
 139         int * $ac_kw t = s;
 140         t[0] = 0;
 141         return foo(t)]])],
 142       [ac_cv_c_restrict=$ac_kw])
 143      test "$ac_cv_c_restrict" != no && break
 144    done
 145   ])
 146  AH_VERBATIM([restrict],
 147 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 148    nothing if this is not supported.  Do not define if restrict is
 149    supported directly.  */
 150 #undef restrict
 151 /* Work around a bug in Sun C++: it does not support _Restrict, even
 152    though the corresponding Sun C compiler does, which causes
 153    "#define restrict _Restrict" in the previous line.  Perhaps some future
 154    version of Sun C++ will work with _Restrict; if so, it'll probably
 155    define __RESTRICT, just as Sun C does.  */
 156 #if defined __SUNPRO_CC && !defined __RESTRICT
 157 # define _Restrict
 158 #endif])
 159  case $ac_cv_c_restrict in
 160    restrict) ;;
 161    no) AC_DEFINE([restrict], []) ;;
 162    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 163  esac
 164 ])
 165
 166 # gl_BIGENDIAN
 167 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 168 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 169 # macros invoke AC_C_BIGENDIAN with arguments.
 170 AC_DEFUN([gl_BIGENDIAN],
 171 [
 172   AC_C_BIGENDIAN
 173 ])
 174
 175 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 176 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 177 # output a spurious "(cached)" mark in the midst of other configure output.
 178 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 179 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 180 AC_DEFUN([gl_CACHE_VAL_SILENT],
 181 [
 182   saved_as_echo_n="$as_echo_n"
 183   as_echo_n=':'
 184   AC_CACHE_VAL([$1], [$2])
 185   as_echo_n="$saved_as_echo_n"
 186 ])