m4/hypot.m4

   1 # hypot.m4 serial 4
   2 dnl Copyright (C) 2012-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_HYPOT],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_hypot_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Persuade glibc <math.h> to declare hypot().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Determine HYPOT_LIBM.
  16   gl_COMMON_DOUBLE_MATHFUNC([hypot])
  17
  18   m4_ifdef([gl_FUNC_HYPOT_IEEE], [
  19     if test $gl_hypot_required = ieee && test $REPLACE_HYPOT = 0; then
  20       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  21       AC_CACHE_CHECK([whether hypot works according to ISO C 99 with IEC 60559],
  22         [gl_cv_func_hypot_ieee],
  23         [
  24           save_LIBS="$LIBS"
  25           LIBS="$LIBS $HYPOT_LIBM"
  26           AC_RUN_IFELSE(
  27             [AC_LANG_SOURCE([[
  28 #ifndef __NO_MATH_INLINES
  29 # define __NO_MATH_INLINES 1 /* for glibc */
  30 #endif
  31 #include <math.h>
  32 /* Compare two numbers with ==.
  33    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  34    'x == x' test.  */
  35 static int
  36 numeric_equal (double x, double y)
  37 {
  38   return x == y;
  39 }
  40 static double dummy (double x, double y) { return 0; }
  41 double zero;
  42 double one = 1.0;
  43 int main (int argc, char *argv[])
  44 {
  45   double (*my_hypot) (double, double) = argc ? hypot : dummy;
  46   double f;
  47   /* Test hypot(NaN,Infinity).
  48      This test fails on OSF/1 5.1 and native Windows.  */
  49   f = my_hypot (zero / zero, one / zero);
  50   if (!numeric_equal (f, f))
  51     return 1;
  52   return 0;
  53 }
  54             ]])],
  55             [gl_cv_func_hypot_ieee=yes],
  56             [gl_cv_func_hypot_ieee=no],
  57             [case "$host_os" in
  58                        # Guess yes on glibc systems.
  59                *-gnu*) gl_cv_func_hypot_ieee="guessing yes" ;;
  60                        # If we don't know, assume the worst.
  61                *)      gl_cv_func_hypot_ieee="guessing no" ;;
  62              esac
  63             ])
  64           LIBS="$save_LIBS"
  65         ])
  66       case "$gl_cv_func_hypot_ieee" in
  67         *yes) ;;
  68         *) REPLACE_HYPOT=1 ;;
  69       esac
  70     fi
  71   ])
  72   if test $REPLACE_HYPOT = 1; then
  73     dnl Find libraries needed to link lib/hypot.c.
  74     AC_REQUIRE([gl_FUNC_FABS])
  75     AC_REQUIRE([gl_FUNC_FREXP])
  76     AC_REQUIRE([gl_FUNC_LDEXP])
  77     AC_REQUIRE([gl_FUNC_SQRT])
  78     HYPOT_LIBM=
  79     dnl Append $FABS_LIBM to HYPOT_LIBM, avoiding gratuitous duplicates.
  80     case " $HYPOT_LIBM " in
  81       *" $FABS_LIBM "*) ;;
  82       *) HYPOT_LIBM="$HYPOT_LIBM $FABS_LIBM" ;;
  83     esac
  84     dnl Append $FREXP_LIBM to HYPOT_LIBM, avoiding gratuitous duplicates.
  85     case " $HYPOT_LIBM " in
  86       *" $FREXP_LIBM "*) ;;
  87       *) HYPOT_LIBM="$HYPOT_LIBM $FREXP_LIBM" ;;
  88     esac
  89     dnl Append $LDEXP_LIBM to HYPOT_LIBM, avoiding gratuitous duplicates.
  90     case " $HYPOT_LIBM " in
  91       *" $LDEXP_LIBM "*) ;;
  92       *) HYPOT_LIBM="$HYPOT_LIBM $LDEXP_LIBM" ;;
  93     esac
  94     dnl Append $SQRT_LIBM to HYPOT_LIBM, avoiding gratuitous duplicates.
  95     case " $HYPOT_LIBM " in
  96       *" $SQRT_LIBM "*) ;;
  97       *) HYPOT_LIBM="$HYPOT_LIBM $SQRT_LIBM" ;;
  98     esac
  99   fi
 100 ])