m4/intl.m4

   1 # intl.m4 serial 24 (gettext-0.18.3)
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6 dnl
   7 dnl This file can can be used in projects which are not available under
   8 dnl the GNU General Public License or the GNU Library General Public
   9 dnl License but which still want to provide support for the GNU gettext
  10 dnl functionality.
  11 dnl Please note that the actual code of the GNU gettext library is covered
  12 dnl by the GNU Library General Public License, and the rest of the GNU
  13 dnl gettext package package is covered by the GNU General Public License.
  14 dnl They are *not* in the public domain.
  15
  16 dnl Authors:
  17 dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
  18 dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2009.
  19
  20 AC_PREREQ([2.60])
  21
  22 dnl Checks for all prerequisites of the intl subdirectory,
  23 dnl except for INTL_LIBTOOL_SUFFIX_PREFIX (and possibly LIBTOOL), INTLOBJS,
  24 dnl            USE_INCLUDED_LIBINTL, BUILD_INCLUDED_LIBINTL.
  25 AC_DEFUN([AM_INTL_SUBDIR],
  26 [
  27   AC_REQUIRE([AC_PROG_INSTALL])dnl
  28   AC_REQUIRE([AC_PROG_MKDIR_P])dnl
  29   AC_REQUIRE([AC_PROG_CC])dnl
  30   AC_REQUIRE([AC_CANONICAL_HOST])dnl
  31   AC_REQUIRE([gt_GLIBC2])dnl
  32   AC_REQUIRE([AC_PROG_RANLIB])dnl
  33   AC_REQUIRE([gl_VISIBILITY])dnl
  34   AC_REQUIRE([gt_INTL_SUBDIR_CORE])dnl
  35   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])dnl
  36   AC_REQUIRE([gt_TYPE_WCHAR_T])dnl
  37   AC_REQUIRE([gt_TYPE_WINT_T])dnl
  38   AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
  39   AC_REQUIRE([gt_TYPE_INTMAX_T])
  40   AC_REQUIRE([gt_PRINTF_POSIX])
  41   AC_REQUIRE([gl_GLIBC21])dnl
  42   AC_REQUIRE([gl_XSIZE])dnl
  43   AC_REQUIRE([gl_FCNTL_O_FLAGS])dnl
  44   AC_REQUIRE([gt_INTL_MACOSX])dnl
  45
  46   dnl Support for automake's --enable-silent-rules.
  47   case "$enable_silent_rules" in
  48     yes) INTL_DEFAULT_VERBOSITY=0;;
  49     no)  INTL_DEFAULT_VERBOSITY=1;;
  50     *)   INTL_DEFAULT_VERBOSITY=1;;
  51   esac
  52   AC_SUBST([INTL_DEFAULT_VERBOSITY])
  53
  54   AC_CHECK_TYPE([ptrdiff_t], ,
  55     [AC_DEFINE([ptrdiff_t], [long],
  56        [Define as the type of the result of subtracting two pointers, if the system doesn't define it.])
  57     ])
  58   AC_CHECK_HEADERS([features.h stddef.h stdlib.h string.h])
  59   AC_CHECK_FUNCS([asprintf fwprintf newlocale putenv setenv setlocale \
  60     snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
  61
  62   dnl Use the _snprintf function only if it is declared (because on NetBSD it
  63   dnl is defined as a weak alias of snprintf; we prefer to use the latter).
  64   AC_CHECK_DECLS([_snprintf, _snwprintf], , , [#include <stdio.h>])
  65
  66   dnl Use the *_unlocked functions only if they are declared.
  67   dnl (because some of them were defined without being declared in Solaris
  68   dnl 2.5.1 but were removed in Solaris 2.6, whereas we want binaries built
  69   dnl on Solaris 2.5.1 to run on Solaris 2.6).
  70   AC_CHECK_DECLS([getc_unlocked], , , [#include <stdio.h>])
  71
  72   case $gt_cv_func_printf_posix in
  73     *yes) HAVE_POSIX_PRINTF=1 ;;
  74     *) HAVE_POSIX_PRINTF=0 ;;
  75   esac
  76   AC_SUBST([HAVE_POSIX_PRINTF])
  77   if test "$ac_cv_func_asprintf" = yes; then
  78     HAVE_ASPRINTF=1
  79   else
  80     HAVE_ASPRINTF=0
  81   fi
  82   AC_SUBST([HAVE_ASPRINTF])
  83   if test "$ac_cv_func_snprintf" = yes; then
  84     HAVE_SNPRINTF=1
  85   else
  86     HAVE_SNPRINTF=0
  87   fi
  88   AC_SUBST([HAVE_SNPRINTF])
  89   if test "$ac_cv_func_newlocale" = yes; then
  90     HAVE_NEWLOCALE=1
  91   else
  92     HAVE_NEWLOCALE=0
  93   fi
  94   AC_SUBST([HAVE_NEWLOCALE])
  95   if test "$ac_cv_func_wprintf" = yes; then
  96     HAVE_WPRINTF=1
  97   else
  98     HAVE_WPRINTF=0
  99   fi
 100   AC_SUBST([HAVE_WPRINTF])
 101
 102   AM_LANGINFO_CODESET
 103   gt_LC_MESSAGES
 104
 105   dnl Compilation on mingw and Cygwin needs special Makefile rules, because
 106   dnl 1. when we install a shared library, we must arrange to export
 107   dnl    auxiliary pointer variables for every exported variable,
 108   dnl 2. when we install a shared library and a static library simultaneously,
 109   dnl    the include file specifies __declspec(dllimport) and therefore we
 110   dnl    must arrange to define the auxiliary pointer variables for the
 111   dnl    exported variables _also_ in the static library.
 112   if test "$enable_shared" = yes; then
 113     case "$host_os" in
 114       mingw* | cygwin*) is_woe32dll=yes ;;
 115       *) is_woe32dll=no ;;
 116     esac
 117   else
 118     is_woe32dll=no
 119   fi
 120   WOE32DLL=$is_woe32dll
 121   AC_SUBST([WOE32DLL])
 122
 123   dnl On mingw and Cygwin, we can activate special Makefile rules which add
 124   dnl version information to the shared libraries and executables.
 125   case "$host_os" in
 126     mingw* | cygwin*) is_woe32=yes ;;
 127     *) is_woe32=no ;;
 128   esac
 129   WOE32=$is_woe32
 130   AC_SUBST([WOE32])
 131   if test $WOE32 = yes; then
 132     dnl Check for a program that compiles Windows resource files.
 133     AC_CHECK_TOOL([WINDRES], [windres])
 134   fi
 135
 136   dnl Determine whether when creating a library, "-lc" should be passed to
 137   dnl libtool or not. On many platforms, it is required for the libtool option
 138   dnl -no-undefined to work. On HP-UX, however, the -lc - stored by libtool
 139   dnl in the *.la files - makes it impossible to create multithreaded programs,
 140   dnl because libtool also reorders the -lc to come before the -pthread, and
 141   dnl this disables pthread_create() <http://docs.hp.com/en/1896/pthreads.html>.
 142   case "$host_os" in
 143     hpux*) LTLIBC="" ;;
 144     *)     LTLIBC="-lc" ;;
 145   esac
 146   AC_SUBST([LTLIBC])
 147
 148   dnl Rename some macros and functions used for locking.
 149   AH_BOTTOM([
 150 #define __libc_lock_t                   gl_lock_t
 151 #define __libc_lock_define              gl_lock_define
 152 #define __libc_lock_define_initialized  gl_lock_define_initialized
 153 #define __libc_lock_init                gl_lock_init
 154 #define __libc_lock_lock                gl_lock_lock
 155 #define __libc_lock_unlock              gl_lock_unlock
 156 #define __libc_lock_recursive_t                   gl_recursive_lock_t
 157 #define __libc_lock_define_recursive              gl_recursive_lock_define
 158 #define __libc_lock_define_initialized_recursive  gl_recursive_lock_define_initialized
 159 #define __libc_lock_init_recursive                gl_recursive_lock_init
 160 #define __libc_lock_lock_recursive                gl_recursive_lock_lock
 161 #define __libc_lock_unlock_recursive              gl_recursive_lock_unlock
 162 #define glthread_in_use  libintl_thread_in_use
 163 #define glthread_lock_init_func     libintl_lock_init_func
 164 #define glthread_lock_lock_func     libintl_lock_lock_func
 165 #define glthread_lock_unlock_func   libintl_lock_unlock_func
 166 #define glthread_lock_destroy_func  libintl_lock_destroy_func
 167 #define glthread_rwlock_init_multithreaded     libintl_rwlock_init_multithreaded
 168 #define glthread_rwlock_init_func              libintl_rwlock_init_func
 169 #define glthread_rwlock_rdlock_multithreaded   libintl_rwlock_rdlock_multithreaded
 170 #define glthread_rwlock_rdlock_func            libintl_rwlock_rdlock_func
 171 #define glthread_rwlock_wrlock_multithreaded   libintl_rwlock_wrlock_multithreaded
 172 #define glthread_rwlock_wrlock_func            libintl_rwlock_wrlock_func
 173 #define glthread_rwlock_unlock_multithreaded   libintl_rwlock_unlock_multithreaded
 174 #define glthread_rwlock_unlock_func            libintl_rwlock_unlock_func
 175 #define glthread_rwlock_destroy_multithreaded  libintl_rwlock_destroy_multithreaded
 176 #define glthread_rwlock_destroy_func           libintl_rwlock_destroy_func
 177 #define glthread_recursive_lock_init_multithreaded     libintl_recursive_lock_init_multithreaded
 178 #define glthread_recursive_lock_init_func              libintl_recursive_lock_init_func
 179 #define glthread_recursive_lock_lock_multithreaded     libintl_recursive_lock_lock_multithreaded
 180 #define glthread_recursive_lock_lock_func              libintl_recursive_lock_lock_func
 181 #define glthread_recursive_lock_unlock_multithreaded   libintl_recursive_lock_unlock_multithreaded
 182 #define glthread_recursive_lock_unlock_func            libintl_recursive_lock_unlock_func
 183 #define glthread_recursive_lock_destroy_multithreaded  libintl_recursive_lock_destroy_multithreaded
 184 #define glthread_recursive_lock_destroy_func           libintl_recursive_lock_destroy_func
 185 #define glthread_once_func            libintl_once_func
 186 #define glthread_once_singlethreaded  libintl_once_singlethreaded
 187 #define glthread_once_multithreaded   libintl_once_multithreaded
 188 ])
 189 ])
 190
 191
 192 dnl Checks for the core files of the intl subdirectory:
 193 dnl   dcigettext.c
 194 dnl   eval-plural.h
 195 dnl   explodename.c
 196 dnl   finddomain.c
 197 dnl   gettextP.h
 198 dnl   gmo.h
 199 dnl   hash-string.h hash-string.c
 200 dnl   l10nflist.c
 201 dnl   libgnuintl.h.in (except the *printf stuff)
 202 dnl   loadinfo.h
 203 dnl   loadmsgcat.c
 204 dnl   localealias.c
 205 dnl   log.c
 206 dnl   plural-exp.h plural-exp.c
 207 dnl   plural.y
 208 dnl Used by libglocale.
 209 AC_DEFUN([gt_INTL_SUBDIR_CORE],
 210 [
 211   AC_REQUIRE([AC_C_INLINE])dnl
 212   AC_REQUIRE([AC_TYPE_SIZE_T])dnl
 213   AC_REQUIRE([gl_AC_HEADER_STDINT_H])
 214   AC_REQUIRE([AC_FUNC_ALLOCA])dnl
 215   AC_REQUIRE([AC_FUNC_MMAP])dnl
 216   AC_REQUIRE([gt_INTDIV0])dnl
 217   AC_REQUIRE([gl_AC_TYPE_UINTMAX_T])dnl
 218   AC_REQUIRE([gt_INTTYPES_PRI])dnl
 219   AC_REQUIRE([gl_LOCK])dnl
 220
 221   AC_LINK_IFELSE(
 222     [AC_LANG_PROGRAM(
 223        [[int foo (int a) { a = __builtin_expect (a, 10); return a == 10 ? 0 : 1; }]],
 224        [[]])],
 225     [AC_DEFINE([HAVE_BUILTIN_EXPECT], [1],
 226        [Define to 1 if the compiler understands __builtin_expect.])])
 227
 228   AC_CHECK_HEADERS([argz.h inttypes.h limits.h unistd.h sys/param.h])
 229   AC_CHECK_FUNCS([getcwd getegid geteuid getgid getuid mempcpy munmap \
 230     stpcpy strcasecmp strdup strtoul tsearch uselocale argz_count \
 231     argz_stringify argz_next __fsetlocking])
 232
 233   dnl Use the *_unlocked functions only if they are declared.
 234   dnl (because some of them were defined without being declared in Solaris
 235   dnl 2.5.1 but were removed in Solaris 2.6, whereas we want binaries built
 236   dnl on Solaris 2.5.1 to run on Solaris 2.6).
 237   AC_CHECK_DECLS([feof_unlocked, fgets_unlocked], , , [#include <stdio.h>])
 238
 239   AM_ICONV
 240
 241   dnl intl/plural.c is generated from intl/plural.y. It requires bison,
 242   dnl because plural.y uses bison specific features. It requires at least
 243   dnl bison-1.26 because earlier versions generate a plural.c that doesn't
 244   dnl compile.
 245   dnl bison is only needed for the maintainer (who touches plural.y). But in
 246   dnl order to avoid separate Makefiles or --enable-maintainer-mode, we put
 247   dnl the rule in general Makefile. Now, some people carelessly touch the
 248   dnl files or have a broken "make" program, hence the plural.c rule will
 249   dnl sometimes fire. To avoid an error, defines BISON to ":" if it is not
 250   dnl present or too old.
 251   AC_CHECK_PROGS([INTLBISON], [bison])
 252   if test -z "$INTLBISON"; then
 253     ac_verc_fail=yes
 254   else
 255     dnl Found it, now check the version.
 256     AC_MSG_CHECKING([version of bison])
 257 changequote(<<,>>)dnl
 258     ac_prog_version=`$INTLBISON --version 2>&1 | sed -n 's/^.*GNU Bison.* \([0-9]*\.[0-9.]*\).*$/\1/p'`
 259     case $ac_prog_version in
 260       '') ac_prog_version="v. ?.??, bad"; ac_verc_fail=yes;;
 261       1.2[6-9]* | 1.[3-9][0-9]* | [2-9].*)
 262 changequote([,])dnl
 263          ac_prog_version="$ac_prog_version, ok"; ac_verc_fail=no;;
 264       *) ac_prog_version="$ac_prog_version, bad"; ac_verc_fail=yes;;
 265     esac
 266     AC_MSG_RESULT([$ac_prog_version])
 267   fi
 268   if test $ac_verc_fail = yes; then
 269     INTLBISON=:
 270   fi
 271 ])