m4/libunistring-base.m4

   1 # libunistring-base.m4 serial 4
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paolo Bonzini and Bruno Haible.
   8
   9 dnl gl_LIBUNISTRING_LIBSOURCE([VERSION], [SourceFile])
  10 dnl Declares that SourceFile should be compiled, unless we are linking
  11 dnl with libunistring and its version is >= the given VERSION.
  12 dnl SourceFile should be relative to the lib directory and end in '.c'.
  13 dnl This macro is to be used for public libunistring API, not for
  14 dnl undocumented API.
  15 dnl
  16 dnl You have to bump the VERSION argument to the next projected version
  17 dnl number each time you make a change that affects the behaviour of the
  18 dnl functions defined in SourceFile (even if SourceFile itself does not
  19 dnl change).
  20
  21 AC_DEFUN([gl_LIBUNISTRING_LIBSOURCE],
  22 [
  23   AC_REQUIRE([gl_LIBUNISTRING_LIB_PREPARE])
  24   dnl Use the variables HAVE_LIBUNISTRING, LIBUNISTRING_VERSION from
  25   dnl gl_LIBUNISTRING_CORE if that macro has been run.
  26   if gl_LIBUNISTRING_VERSION_CMP([$1]); then
  27     m4_foreach_w([gl_source_file], [$2],
  28       [AC_LIBOBJ(m4_bpatsubst(m4_defn([gl_source_file]), [\.c$], []))
  29       ])
  30   fi
  31 ])
  32
  33 dnl gl_LIBUNISTRING_LIBHEADER([VERSION], [HeaderFile])
  34 dnl Declares that HeaderFile should be created, unless we are linking
  35 dnl with libunistring and its version is >= the given VERSION.
  36 dnl HeaderFile should be relative to the lib directory and end in '.h'.
  37 dnl Prepares for substituting LIBUNISTRING_HEADERFILE (to HeaderFile or empty).
  38 dnl
  39 dnl When we are linking with the already installed libunistring and its version
  40 dnl is < VERSION, we create HeaderFile here, because we may compile functions
  41 dnl (via gl_LIBUNISTRING_LIBSOURCE above) that are not contained in the
  42 dnl installed version.
  43 dnl When we are linking with the already installed libunistring and its version
  44 dnl is > VERSION, we don't create HeaderFile here: it could cause compilation
  45 dnl errors in other libunistring header files if some types are missing.
  46 dnl
  47 dnl You have to bump the VERSION argument to the next projected version
  48 dnl number each time you make a non-comment change to the HeaderFile.
  49
  50 AC_DEFUN([gl_LIBUNISTRING_LIBHEADER],
  51 [
  52   AC_REQUIRE([gl_LIBUNISTRING_LIB_PREPARE])
  53   dnl Use the variables HAVE_LIBUNISTRING, LIBUNISTRING_VERSION from
  54   dnl gl_LIBUNISTRING_CORE if that macro has been run.
  55   if gl_LIBUNISTRING_VERSION_CMP([$1]); then
  56     LIBUNISTRING_[]AS_TR_CPP([$2])='$2'
  57   else
  58     LIBUNISTRING_[]AS_TR_CPP([$2])=
  59   fi
  60   AC_SUBST([LIBUNISTRING_]AS_TR_CPP([$2]))
  61 ])
  62
  63 dnl Miscellaneous preparations/initializations.
  64
  65 AC_DEFUN([gl_LIBUNISTRING_LIB_PREPARE],
  66 [
  67   dnl Ensure that HAVE_LIBUNISTRING is fully determined at this point.
  68   m4_ifdef([gl_LIBUNISTRING], [AC_REQUIRE([gl_LIBUNISTRING])])
  69
  70   AC_REQUIRE([AC_PROG_AWK])
  71
  72 dnl Sed expressions to extract the parts of a version number.
  73 changequote(,)
  74 gl_libunistring_sed_extract_major='/^[0-9]/{s/^\([0-9]*\).*/\1/p;q;}
  75 i\
  76 0
  77 q
  78 '
  79 gl_libunistring_sed_extract_minor='/^[0-9][0-9]*[.][0-9]/{s/^[0-9]*[.]\([0-9]*\).*/\1/p;q;}
  80 i\
  81 0
  82 q
  83 '
  84 gl_libunistring_sed_extract_subminor='/^[0-9][0-9]*[.][0-9][0-9]*[.][0-9]/{s/^[0-9]*[.][0-9]*[.]\([0-9]*\).*/\1/p;q;}
  85 i\
  86 0
  87 q
  88 '
  89 changequote([,])
  90
  91   if test "$HAVE_LIBUNISTRING" = yes; then
  92     LIBUNISTRING_VERSION_MAJOR=`echo "$LIBUNISTRING_VERSION" | sed -n -e "$gl_libunistring_sed_extract_major"`
  93     LIBUNISTRING_VERSION_MINOR=`echo "$LIBUNISTRING_VERSION" | sed -n -e "$gl_libunistring_sed_extract_minor"`
  94     LIBUNISTRING_VERSION_SUBMINOR=`echo "$LIBUNISTRING_VERSION" | sed -n -e "$gl_libunistring_sed_extract_subminor"`
  95   fi
  96 ])
  97
  98 dnl gl_LIBUNISTRING_VERSION_CMP([VERSION])
  99 dnl Expands to a shell statement that evaluates to true if LIBUNISTRING_VERSION
 100 dnl is less than the VERSION argument.
 101 AC_DEFUN([gl_LIBUNISTRING_VERSION_CMP],
 102 [ { test "$HAVE_LIBUNISTRING" != yes \
 103     || {
 104          dnl AS_LITERAL_IF exists and works fine since autoconf-2.59 at least.
 105          AS_LITERAL_IF([$1],
 106            [dnl This is the optimized variant, that assumes the argument is a literal:
 107             m4_pushdef([requested_version_major],
 108               [gl_LIBUNISTRING_ARG_OR_ZERO(m4_bpatsubst([$1], [^\([0-9]*\).*], [\1]), [])])
 109             m4_pushdef([requested_version_minor],
 110               [gl_LIBUNISTRING_ARG_OR_ZERO(m4_bpatsubst([$1], [^[0-9]*[.]\([0-9]*\).*], [\1]), [$1])])
 111             m4_pushdef([requested_version_subminor],
 112               [gl_LIBUNISTRING_ARG_OR_ZERO(m4_bpatsubst([$1], [^[0-9]*[.][0-9]*[.]\([0-9]*\).*], [\1]), [$1])])
 113             test $LIBUNISTRING_VERSION_MAJOR -lt requested_version_major \
 114             || { test $LIBUNISTRING_VERSION_MAJOR -eq requested_version_major \
 115                  && { test $LIBUNISTRING_VERSION_MINOR -lt requested_version_minor \
 116                       || { test $LIBUNISTRING_VERSION_MINOR -eq requested_version_minor \
 117                            && test $LIBUNISTRING_VERSION_SUBMINOR -lt requested_version_subminor
 118                          }
 119                     }
 120                }
 121             m4_popdef([requested_version_subminor])
 122             m4_popdef([requested_version_minor])
 123             m4_popdef([requested_version_major])
 124            ],
 125            [dnl This is the unoptimized variant:
 126             requested_version_major=`echo '$1' | sed -n -e "$gl_libunistring_sed_extract_major"`
 127             requested_version_minor=`echo '$1' | sed -n -e "$gl_libunistring_sed_extract_minor"`
 128             requested_version_subminor=`echo '$1' | sed -n -e "$gl_libunistring_sed_extract_subminor"`
 129             test $LIBUNISTRING_VERSION_MAJOR -lt $requested_version_major \
 130             || { test $LIBUNISTRING_VERSION_MAJOR -eq $requested_version_major \
 131                  && { test $LIBUNISTRING_VERSION_MINOR -lt $requested_version_minor \
 132                       || { test $LIBUNISTRING_VERSION_MINOR -eq $requested_version_minor \
 133                            && test $LIBUNISTRING_VERSION_SUBMINOR -lt $requested_version_subminor
 134                          }
 135                     }
 136                }
 137            ])
 138        }
 139   }])
 140
 141 dnl gl_LIBUNISTRING_ARG_OR_ZERO([ARG], [ORIG]) expands to ARG if it is not the
 142 dnl same as ORIG, otherwise to 0.
 143 m4_define([gl_LIBUNISTRING_ARG_OR_ZERO], [m4_if([$1], [$2], [0], [$1])])