m4/locale-ar.m4

   1 # locale-ar.m4 serial 6
   2 dnl Copyright (C) 2003, 2005-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Ben Pfaff, based on locale-fr.m4 by Bruno Haible.
   8
   9 dnl Determine the name of an Arabic locale with traditional encoding.
  10 AC_DEFUN([gt_LOCALE_AR],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a traditional Arabic locale], [gt_cv_locale_ar], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  16 changequote(,)dnl
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main () {
  27   /* Check whether the given locale name is recognized by the system.  */
  28 #if (defined _WIN32 || defined __WIN32__) && !defined __CYGWIN__
  29   /* On native Windows, setlocale(category, "") looks at the system settings,
  30      not at the environment variables.  Also, when an encoding suffix such
  31      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  32      category of the locale to "C".  */
  33   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  34       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  35     return 1;
  36 #else
  37   if (setlocale (LC_ALL, "") == NULL) return 1;
  38 #endif
  39   /* Check that nl_langinfo(CODESET) is nonempty and not "ASCII" or "646"
  40      and ends in "6". */
  41 #if HAVE_LANGINFO_CODESET
  42   {
  43     const char *cs = nl_langinfo (CODESET);
  44     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  45         || cs[strlen (cs) - 1] != '6')
  46       return 1;
  47   }
  48 #endif
  49 #ifdef __CYGWIN__
  50   /* On Cygwin, avoid locale names without encoding suffix, because the
  51      locale_charset() function relies on the encoding suffix.  Note that
  52      LC_ALL is set on the command line.  */
  53   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  54 #endif
  55   return 0;
  56 }
  57 changequote([,])dnl
  58       ])])
  59     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  60       case "$host_os" in
  61         # Handle native Windows specially, because there setlocale() interprets
  62         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  63         # "fr" or "fra" as "French" or "French_France.1252",
  64         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  65         # "ja" as "Japanese" or "Japanese_Japan.932",
  66         # and similar.
  67         mingw*)
  68           # Note that on native Windows, the Arabic locale is
  69           # "Arabic_Saudi Arabia.1256", and CP1256 is very different from
  70           # ISO-8859-6, so we cannot use it here.
  71           gt_cv_locale_ar=none
  72           ;;
  73         *)
  74           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  75           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
  76           # configure script would override the LC_ALL setting. Likewise for
  77           # LC_CTYPE, which is also set at the beginning of the configure script.
  78           # Values tested:
  79           #   - The usual locale name:                         ar_SA
  80           #   - The locale name with explicit encoding suffix: ar_SA.ISO-8859-6
  81           #   - The HP-UX locale name:                         ar_SA.iso88596
  82           #   - The Solaris 7 locale name:                     ar
  83           # Also try ar_EG instead of ar_SA because Egypt is a large country too.
  84           for gt_cv_locale_ar in ar_SA ar_SA.ISO-8859-6 ar_SA.iso88596 ar_EG ar_EG.ISO-8859-6 ar_EG.iso88596 ar none; do
  85             if test $gt_cv_locale_ar = none; then
  86               break
  87             fi
  88             if (LC_ALL=$gt_cv_locale_ar LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  89               break
  90             fi
  91           done
  92           ;;
  93       esac
  94     fi
  95     rm -fr conftest*
  96   ])
  97   LOCALE_AR=$gt_cv_locale_ar
  98   AC_SUBST([LOCALE_AR])
  99 ])