unigbrk: New modules for grapheme clusters.
[gnulib.git] / m4 / locale-ar.m4
1 # locale-ar.m4 serial 1
2 dnl Copyright (C) 2003, 2005-2010 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 dnl From Ben Pfaff, based on locale-fr.m4 by Bruno Haible.
8
9 dnl Determine the name of an Arabic locale with traditional encoding.
10 AC_DEFUN([gt_LOCALE_AR],
11 [
12   AC_REQUIRE([AC_CANONICAL_HOST])
13   AC_REQUIRE([AM_LANGINFO_CODESET])
14   AC_CACHE_CHECK([for a traditional Arabic locale], [gt_cv_locale_ar], [
15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
16 changequote(,)dnl
17 #include <locale.h>
18 #include <time.h>
19 #if HAVE_LANGINFO_CODESET
20 # include <langinfo.h>
21 #endif
22 #include <stdlib.h>
23 #include <string.h>
24 struct tm t;
25 char buf[16];
26 int main () {
27   /* Check whether the given locale name is recognized by the system.  */
28   if (setlocale (LC_ALL, "") == NULL) return 1;
29   /* Check that nl_langinfo(CODESET) is nonempty and not "ASCII" or "646". */
30 #if HAVE_LANGINFO_CODESET
31   {
32     const char *cs = nl_langinfo (CODESET);
33     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
34         || strcmp (cs, "UTF-8") == 0)
35       return 1;
36   }
37 #endif
38 #ifdef __CYGWIN__
39   /* On Cygwin, avoid locale names without encoding suffix, because the
40      locale_charset() function relies on the encoding suffix.  Note that
41      LC_ALL is set on the command line.  */
42   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
43 #endif
44   /* Check that the name of the first month begins with U+0643 (ك) as encoded
45      by ISO 8859-6.  This excludes the UTF-8 encoding.  */
46   t.tm_year = 1975 - 1900; t.tm_mon = 1 - 1; t.tm_mday = 4;
47   strftime (buf, sizeof (buf), "%B", &t);
48   if ((unsigned char) buf[0] != 0xe3) return 1;
49   return 0;
50 }
51 changequote([,])dnl
52       ])])
53     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
54       # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
55       # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
56       # configure script would override the LC_ALL setting. Likewise for
57       # LC_CTYPE, which is also set at the beginning of the configure script.
58       # Test for the usual locale name.
59       for gt_cv_locale_ar in ar_SA ar_SA.ISO-8859-6 ar_EG ar_EG.ISO-8859-6 none; do
60         if test $gt_cv_locale_ar = none || (LC_ALL=$gt_cv_locale_ar LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
61           break
62         fi
63       done
64     fi
65     rm -fr conftest*
66   ])
67   LOCALE_AR=$gt_cv_locale_ar
68   AC_SUBST([LOCALE_AR])
69 ])