m4/locale-ar.m4

   1 # locale-ar.m4 serial 2
   2 dnl Copyright (C) 2003, 2005-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Ben Pfaff, based on locale-fr.m4 by Bruno Haible.
   8
   9 dnl Determine the name of an Arabic locale with traditional encoding.
  10 AC_DEFUN([gt_LOCALE_AR],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a traditional Arabic locale], [gt_cv_locale_ar], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  16 changequote(,)dnl
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main () {
  27   /* Check whether the given locale name is recognized by the system.  */
  28   if (setlocale (LC_ALL, "") == NULL) return 1;
  29   /* Check that nl_langinfo(CODESET) is nonempty and not "ASCII" or "646"
  30      and ends in "6". */
  31 #if HAVE_LANGINFO_CODESET
  32   {
  33     const char *cs = nl_langinfo (CODESET);
  34     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  35         || cs[strlen (cs) - 1] != '6')
  36       return 1;
  37   }
  38 #endif
  39 #ifdef __CYGWIN__
  40   /* On Cygwin, avoid locale names without encoding suffix, because the
  41      locale_charset() function relies on the encoding suffix.  Note that
  42      LC_ALL is set on the command line.  */
  43   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  44 #endif
  45   return 0;
  46 }
  47 changequote([,])dnl
  48       ])])
  49     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  50       # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  51       # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  52       # configure script would override the LC_ALL setting. Likewise for
  53       # LC_CTYPE, which is also set at the beginning of the configure script.
  54       # Values tested:
  55       #   - The usual locale name:                         ar_SA
  56       #   - The locale name with explicit encoding suffix: ar_SA.ISO-8859-6
  57       #   - The HP-UX locale name:                         ar_SA.iso88596
  58       #   - The Solaris 7 locale name:                     ar
  59       # Also try ar_EG instead of ar_SA because Egypt is a large country too.
  60       for gt_cv_locale_ar in ar_SA ar_SA.ISO-8859-6 ar_SA.iso88596 ar_EG ar_EG.ISO-8859-6 ar_EG.iso88596 ar none; do
  61         if test $gt_cv_locale_ar = none; then
  62           break
  63         fi
  64         if (LC_ALL=$gt_cv_locale_ar LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  65           break
  66         fi
  67       done
  68     fi
  69     rm -fr conftest*
  70   ])
  71   LOCALE_AR=$gt_cv_locale_ar
  72   AC_SUBST([LOCALE_AR])
  73 ])