m4/locale-tr.m4

   1 # locale-tr.m4 serial 10
   2 dnl Copyright (C) 2003, 2005-2013 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a turkish locale with UTF-8 encoding.
  10 AC_DEFUN([gt_LOCALE_TR_UTF8],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a turkish Unicode locale], [gt_cv_locale_tr_utf8], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  16 changequote(,)dnl
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main () {
  27   /* On BeOS, locales are not implemented in libc.  Rather, libintl
  28      imitates locale dependent behaviour by looking at the environment
  29      variables, and all locales use the UTF-8 encoding.  But BeOS does not
  30      implement the Turkish upper-/lowercase mappings.  Therefore, let this
  31      program return 1 on BeOS.  */
  32   /* Check whether the given locale name is recognized by the system.  */
  33 #if (defined _WIN32 || defined __WIN32__) && !defined __CYGWIN__
  34   /* On native Windows, setlocale(category, "") looks at the system settings,
  35      not at the environment variables.  Also, when an encoding suffix such
  36      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  37      category of the locale to "C".  */
  38   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  39       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  40     return 1;
  41 #else
  42   if (setlocale (LC_ALL, "") == NULL) return 1;
  43 #endif
  44   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  45      On Mac OS X 10.3.5 (Darwin 7.5) in the tr_TR locale, nl_langinfo(CODESET)
  46      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  47      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  48      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  49      some unit tests fail.  */
  50 #if HAVE_LANGINFO_CODESET
  51   {
  52     const char *cs = nl_langinfo (CODESET);
  53     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0)
  54       return 1;
  55   }
  56 #endif
  57 #ifdef __CYGWIN__
  58   /* On Cygwin, avoid locale names without encoding suffix, because the
  59      locale_charset() function relies on the encoding suffix.  Note that
  60      LC_ALL is set on the command line.  */
  61   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  62 #endif
  63   /* Check whether in the abbreviation of the eighth month, the second
  64      character (should be U+011F: LATIN SMALL LETTER G WITH BREVE) is
  65      two bytes long, with UTF-8 encoding.  */
  66   t.tm_year = 1992 - 1900; t.tm_mon = 8 - 1; t.tm_mday = 19;
  67   if (strftime (buf, sizeof (buf), "%b", &t) < 4
  68       || buf[1] != (char) 0xc4 || buf[2] != (char) 0x9f)
  69     return 1;
  70   /* Check whether the upper-/lowercase mappings are as expected for
  71      Turkish.  */
  72   if (towupper ('i') != 0x0130 || towlower (0x0130) != 'i'
  73       || towupper(0x0131) != 'I' || towlower ('I') != 0x0131)
  74     return 1;
  75   return 0;
  76 }
  77 changequote([,])dnl
  78       ])])
  79     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  80       case "$host_os" in
  81         # Handle native Windows specially, because there setlocale() interprets
  82         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  83         # "fr" or "fra" as "French" or "French_France.1252",
  84         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  85         # "ja" as "Japanese" or "Japanese_Japan.932",
  86         # and similar.
  87         mingw*)
  88           # Test for the hypothetical native Windows locale name.
  89           if (LC_ALL=Turkish_Turkey.65001 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  90             gt_cv_locale_tr_utf8=Turkish_Turkey.65001
  91           else
  92             # None found.
  93             gt_cv_locale_tr_utf8=none
  94           fi
  95           ;;
  96         *)
  97           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  98           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
  99           # configure script would override the LC_ALL setting. Likewise for
 100           # LC_CTYPE, which is also set at the beginning of the configure script.
 101           # Test for the usual locale name.
 102           if (LC_ALL=tr_TR LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 103             gt_cv_locale_tr_utf8=tr_TR
 104           else
 105             # Test for the locale name with explicit encoding suffix.
 106             if (LC_ALL=tr_TR.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 107               gt_cv_locale_tr_utf8=tr_TR.UTF-8
 108             else
 109               # Test for the Solaris 7 locale name.
 110               if (LC_ALL=tr.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 111                 gt_cv_locale_tr_utf8=tr.UTF-8
 112               else
 113                 # None found.
 114                 gt_cv_locale_tr_utf8=none
 115               fi
 116             fi
 117           fi
 118           ;;
 119       esac
 120     else
 121       gt_cv_locale_tr_utf8=none
 122     fi
 123     rm -fr conftest*
 124   ])
 125   LOCALE_TR_UTF8=$gt_cv_locale_tr_utf8
 126   AC_SUBST([LOCALE_TR_UTF8])
 127 ])