m4/locale_h.m4

   1 # locale_h.m4 serial 15
   2 dnl Copyright (C) 2007, 2009-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_LOCALE_H],
   8 [
   9   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  10   dnl once only, before all statements that occur in other macros.
  11   AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
  12
  13   dnl Persuade glibc <locale.h> to define locale_t and the int_p_*, int_n_*
  14   dnl members of 'struct lconv'.
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl If <stddef.h> is replaced, then <locale.h> must also be replaced.
  18   AC_REQUIRE([gl_STDDEF_H])
  19
  20   AC_CACHE_CHECK([whether locale.h conforms to POSIX:2001],
  21     [gl_cv_header_locale_h_posix2001],
  22     [AC_COMPILE_IFELSE(
  23        [AC_LANG_PROGRAM(
  24           [[#include <locale.h>
  25             int x = LC_MESSAGES;
  26             int y = sizeof (((struct lconv *) 0)->decimal_point);]],
  27           [[]])],
  28        [gl_cv_header_locale_h_posix2001=yes],
  29        [gl_cv_header_locale_h_posix2001=no])])
  30
  31   dnl Check for <xlocale.h>.
  32   AC_CHECK_HEADERS_ONCE([xlocale.h])
  33   if test $ac_cv_header_xlocale_h = yes; then
  34     HAVE_XLOCALE_H=1
  35     dnl Check whether use of locale_t requires inclusion of <xlocale.h>,
  36     dnl e.g. on MacOS X 10.5. If <locale.h> does not define locale_t by
  37     dnl itself, we assume that <xlocale.h> will do so.
  38     AC_CACHE_CHECK([whether locale.h defines locale_t],
  39       [gl_cv_header_locale_has_locale_t],
  40       [AC_COMPILE_IFELSE(
  41          [AC_LANG_PROGRAM(
  42             [[#include <locale.h>
  43               locale_t x;]],
  44             [[]])],
  45          [gl_cv_header_locale_has_locale_t=yes],
  46          [gl_cv_header_locale_has_locale_t=no])
  47       ])
  48     if test $gl_cv_header_locale_has_locale_t = yes; then
  49       gl_cv_header_locale_h_needs_xlocale_h=no
  50     else
  51       gl_cv_header_locale_h_needs_xlocale_h=yes
  52     fi
  53   else
  54     HAVE_XLOCALE_H=0
  55     gl_cv_header_locale_h_needs_xlocale_h=no
  56   fi
  57   AC_SUBST([HAVE_XLOCALE_H])
  58
  59   dnl Check whether 'struct lconv' is well-defined.
  60   dnl Bionic libc's 'struct lconv' is just a dummy.
  61   AC_CACHE_CHECK([whether struct lconv is properly defined],
  62     [gl_cv_sys_struct_lconv_ok],
  63     [AC_COMPILE_IFELSE(
  64        [AC_LANG_PROGRAM(
  65           [[#include <locale.h>
  66             struct lconv l;
  67             int x = sizeof (l.decimal_point);]],
  68           [[]])],
  69        [gl_cv_sys_struct_lconv_ok=yes],
  70        [gl_cv_sys_struct_lconv_ok=no])
  71     ])
  72   if test $gl_cv_sys_struct_lconv_ok = no; then
  73     REPLACE_STRUCT_LCONV=1
  74   fi
  75
  76   dnl <locale.h> is always overridden, because of GNULIB_POSIXCHECK.
  77   gl_NEXT_HEADERS([locale.h])
  78
  79   dnl Check for declarations of anything we want to poison if the
  80   dnl corresponding gnulib module is not in use.
  81   gl_WARN_ON_USE_PREPARE([[#include <locale.h>
  82 /* Some systems provide declarations in a non-standard header.  */
  83 #if HAVE_XLOCALE_H
  84 # include <xlocale.h>
  85 #endif
  86     ]],
  87     [setlocale duplocale])
  88 ])
  89
  90 AC_DEFUN([gl_LOCALE_MODULE_INDICATOR],
  91 [
  92   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  93   AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
  94   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  95   dnl Define it also as a C macro, for the benefit of the unit tests.
  96   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  97 ])
  98
  99 AC_DEFUN([gl_LOCALE_H_DEFAULTS],
 100 [
 101   GNULIB_SETLOCALE=0;  AC_SUBST([GNULIB_SETLOCALE])
 102   GNULIB_DUPLOCALE=0;  AC_SUBST([GNULIB_DUPLOCALE])
 103   dnl Assume proper GNU behavior unless another module says otherwise.
 104   HAVE_DUPLOCALE=1;       AC_SUBST([HAVE_DUPLOCALE])
 105   REPLACE_SETLOCALE=0;    AC_SUBST([REPLACE_SETLOCALE])
 106   REPLACE_DUPLOCALE=0;    AC_SUBST([REPLACE_DUPLOCALE])
 107   REPLACE_STRUCT_LCONV=0; AC_SUBST([REPLACE_STRUCT_LCONV])
 108 ])