m4/locale_h.m4

   1 # locale_h.m4 serial 6
   2 dnl Copyright (C) 2007, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_LOCALE_H],
   8 [
   9   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  10   dnl once only, before all statements that occur in other macros.
  11   AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
  12
  13   dnl Persuade glibc <locale.h> to define locale_t.
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl If <stddef.h> is replaced, then <locale.h> must also be replaced.
  17   AC_REQUIRE([gl_STDDEF_H])
  18
  19   AC_CACHE_CHECK([whether locale.h conforms to POSIX:2001],
  20     [gl_cv_header_locale_h_posix2001],
  21     [AC_TRY_COMPILE([#include <locale.h>
  22 int x = LC_MESSAGES;], [],
  23        [gl_cv_header_locale_h_posix2001=yes],
  24        [gl_cv_header_locale_h_posix2001=no])])
  25
  26   dnl Check for <xlocale.h>.
  27   AC_CHECK_HEADERS_ONCE([xlocale.h])
  28   if test $ac_cv_header_xlocale_h = yes; then
  29     HAVE_XLOCALE_H=1
  30     dnl Check whether use of locale_t requires inclusion of <xlocale.h>,
  31     dnl e.g. on MacOS X 10.5. If <locale.h> does not define locale_t by
  32     dnl itself, we assume that <xlocale.h> will do so.
  33     AC_CACHE_CHECK([whether locale.h defines locale_t],
  34       [gl_cv_header_locale_has_locale_t],
  35       [AC_TRY_COMPILE([#include <locale.h>
  36 locale_t x;], [],
  37          [gl_cv_header_locale_has_locale_t=yes],
  38          [gl_cv_header_locale_has_locale_t=no])
  39       ])
  40     if test $gl_cv_header_locale_has_locale_t = yes; then
  41       gl_cv_header_locale_h_needs_xlocale_h=no
  42     else
  43       gl_cv_header_locale_h_needs_xlocale_h=yes
  44     fi
  45   else
  46     HAVE_XLOCALE_H=0
  47     gl_cv_header_locale_h_needs_xlocale_h=no
  48   fi
  49   AC_SUBST([HAVE_XLOCALE_H])
  50
  51   dnl Execute this unconditionally, because LOCALE_H may be set by other
  52   dnl modules, after this code is executed.
  53   gl_CHECK_NEXT_HEADERS([locale.h])
  54
  55   if test -n "$STDDEF_H" \
  56      || test $gl_cv_header_locale_h_posix2001 = no \
  57      || test $gl_cv_header_locale_h_needs_xlocale_h = yes; then
  58     gl_REPLACE_LOCALE_H
  59   fi
  60 ])
  61
  62 dnl Unconditionally enables the replacement of <locale.h>.
  63 AC_DEFUN([gl_REPLACE_LOCALE_H],
  64 [
  65   AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
  66   :
  67 ])
  68
  69 AC_DEFUN([gl_LOCALE_MODULE_INDICATOR],
  70 [
  71   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  72   AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
  73   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  74 ])
  75
  76 AC_DEFUN([gl_LOCALE_H_DEFAULTS],
  77 [
  78   GNULIB_DUPLOCALE=0;  AC_SUBST([GNULIB_DUPLOCALE])
  79   dnl Assume proper GNU behavior unless another module says otherwise.
  80   REPLACE_DUPLOCALE=0; AC_SUBST([REPLACE_DUPLOCALE])
  81 ])