m4/log1p.m4

   1 # log1p.m4 serial 2
   2 dnl Copyright (C) 2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOG1P],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_log1p_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Persuade glibc <math.h> to declare log1p().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Determine LOG1P_LIBM.
  16   gl_COMMON_DOUBLE_MATHFUNC([log1p])
  17
  18   dnl Test whether log1p() exists.
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $LOG1P_LIBM"
  21   AC_CHECK_FUNCS([log1p])
  22   LIBS="$save_LIBS"
  23   if test $ac_cv_func_log1p = yes; then
  24     :
  25     m4_ifdef([gl_FUNC_LOG1P_IEEE], [
  26       if test $gl_log1p_required = ieee && test $REPLACE_LOG1P = 0; then
  27         AC_CACHE_CHECK([whether log1p works according to ISO C 99 with IEC 60559],
  28           [gl_cv_func_log1p_ieee],
  29           [
  30             save_LIBS="$LIBS"
  31             LIBS="$LIBS $LOG1P_LIBM"
  32             AC_RUN_IFELSE(
  33               [AC_LANG_SOURCE([[
  34 #ifndef __NO_MATH_INLINES
  35 # define __NO_MATH_INLINES 1 /* for glibc */
  36 #endif
  37 #include <math.h>
  38 ]gl_DOUBLE_MINUS_ZERO_CODE[
  39 ]gl_DOUBLE_SIGNBIT_CODE[
  40 static double dummy (double x) { return 0; }
  41 int main (int argc, char *argv[])
  42 {
  43   double (*my_log1p) (double) = argc ? log1p : dummy;
  44   /* This test fails on AIX, HP-UX 11.  */
  45   double y = my_log1p (minus_zerod);
  46   if (!(y == 0.0) || (signbitd (minus_zerod) && !signbitd (y)))
  47     return 1;
  48   return 0;
  49 }
  50               ]])],
  51               [gl_cv_func_log1p_ieee=yes],
  52               [gl_cv_func_log1p_ieee=no],
  53               [gl_cv_func_log1p_ieee="guessing no"])
  54             LIBS="$save_LIBS"
  55           ])
  56         case "$gl_cv_func_log1p_ieee" in
  57           *yes) ;;
  58           *) REPLACE_LOG1P=1 ;;
  59         esac
  60       fi
  61     ])
  62   else
  63     HAVE_LOG1P=0
  64   fi
  65   if test $HAVE_LOG1P = 0 || test $REPLACE_LOG1P = 1; then
  66     dnl Find libraries needed to link lib/log1p.c.
  67     AC_REQUIRE([gl_FUNC_ISNAND])
  68     AC_REQUIRE([gl_FUNC_LOG])
  69     AC_REQUIRE([gl_FUNC_ROUND])
  70     LOG1P_LIBM=
  71     dnl Append $ISNAND_LIBM to LOG1P_LIBM, avoiding gratuitous duplicates.
  72     case " $LOG1P_LIBM " in
  73       *" $ISNAND_LIBM "*) ;;
  74       *) LOG1P_LIBM="$LOG1P_LIBM $ISNAND_LIBM" ;;
  75     esac
  76     dnl Append $LOG_LIBM to LOG1P_LIBM, avoiding gratuitous duplicates.
  77     case " $LOG1P_LIBM " in
  78       *" $LOG_LIBM "*) ;;
  79       *) LOG1P_LIBM="$LOG1P_LIBM $LOG_LIBM" ;;
  80     esac
  81     dnl Append $ROUND_LIBM to LOG1P_LIBM, avoiding gratuitous duplicates.
  82     case " $LOG1P_LIBM " in
  83       *" $ROUND_LIBM "*) ;;
  84       *) LOG1P_LIBM="$LOG1P_LIBM $ROUND_LIBM" ;;
  85     esac
  86   fi
  87 ])