m4/longlong.m4

   1 # longlong.m4 serial 15
   2 dnl Copyright (C) 1999-2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert.
   8
   9 # Define HAVE_LONG_LONG_INT if 'long long int' works.
  10 # This fixes a bug in Autoconf 2.61, and can be faster
  11 # than what's in Autoconf 2.62 through 2.68.
  12
  13 # Note: If the type 'long long int' exists but is only 32 bits large
  14 # (as on some very old compilers), HAVE_LONG_LONG_INT will not be
  15 # defined. In this case you can treat 'long long int' like 'long int'.
  16
  17 AC_DEFUN([AC_TYPE_LONG_LONG_INT],
  18 [
  19   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  20   AC_CACHE_CHECK([for long long int], [ac_cv_type_long_long_int],
  21      [ac_cv_type_long_long_int=yes
  22       if test "x${ac_cv_prog_cc_c99-no}" = xno; then
  23         ac_cv_type_long_long_int=$ac_cv_type_unsigned_long_long_int
  24         if test $ac_cv_type_long_long_int = yes; then
  25           dnl Catch a bug in Tandem NonStop Kernel (OSS) cc -O circa 2004.
  26           dnl If cross compiling, assume the bug is not important, since
  27           dnl nobody cross compiles for this platform as far as we know.
  28           AC_RUN_IFELSE(
  29             [AC_LANG_PROGRAM(
  30                [[@%:@include <limits.h>
  31                  @%:@ifndef LLONG_MAX
  32                  @%:@ define HALF \
  33                           (1LL << (sizeof (long long int) * CHAR_BIT - 2))
  34                  @%:@ define LLONG_MAX (HALF - 1 + HALF)
  35                  @%:@endif]],
  36                [[long long int n = 1;
  37                  int i;
  38                  for (i = 0; ; i++)
  39                    {
  40                      long long int m = n << i;
  41                      if (m >> i != n)
  42                        return 1;
  43                      if (LLONG_MAX / 2 < m)
  44                        break;
  45                    }
  46                  return 0;]])],
  47             [],
  48             [ac_cv_type_long_long_int=no])
  49         fi
  50       fi])
  51   if test $ac_cv_type_long_long_int = yes; then
  52     AC_DEFINE([HAVE_LONG_LONG_INT], [1],
  53       [Define to 1 if the system has the type `long long int'.])
  54   fi
  55 ])
  56
  57 # Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
  58 # This fixes a bug in Autoconf 2.61, and can be faster
  59 # than what's in Autoconf 2.62 through 2.68.
  60
  61 # Note: If the type 'unsigned long long int' exists but is only 32 bits
  62 # large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
  63 # will not be defined. In this case you can treat 'unsigned long long int'
  64 # like 'unsigned long int'.
  65
  66 AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
  67 [
  68   AC_CACHE_CHECK([for unsigned long long int],
  69     [ac_cv_type_unsigned_long_long_int],
  70     [ac_cv_type_unsigned_long_long_int=yes
  71      if test "x${ac_cv_prog_cc_c99-no}" = xno; then
  72        AC_LINK_IFELSE(
  73          [_AC_TYPE_LONG_LONG_SNIPPET],
  74          [],
  75          [ac_cv_type_unsigned_long_long_int=no])
  76      fi])
  77   if test $ac_cv_type_unsigned_long_long_int = yes; then
  78     AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], [1],
  79       [Define to 1 if the system has the type `unsigned long long int'.])
  80   fi
  81 ])
  82
  83 # Expands to a C program that can be used to test for simultaneous support
  84 # of 'long long' and 'unsigned long long'. We don't want to say that
  85 # 'long long' is available if 'unsigned long long' is not, or vice versa,
  86 # because too many programs rely on the symmetry between signed and unsigned
  87 # integer types (excluding 'bool').
  88 AC_DEFUN([_AC_TYPE_LONG_LONG_SNIPPET],
  89 [
  90   AC_LANG_PROGRAM(
  91     [[/* For now, do not test the preprocessor; as of 2007 there are too many
  92          implementations with broken preprocessors.  Perhaps this can
  93          be revisited in 2012.  In the meantime, code should not expect
  94          #if to work with literals wider than 32 bits.  */
  95       /* Test literals.  */
  96       long long int ll = 9223372036854775807ll;
  97       long long int nll = -9223372036854775807LL;
  98       unsigned long long int ull = 18446744073709551615ULL;
  99       /* Test constant expressions.   */
 100       typedef int a[((-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
 101                      ? 1 : -1)];
 102       typedef int b[(18446744073709551615ULL <= (unsigned long long int) -1
 103                      ? 1 : -1)];
 104       int i = 63;]],
 105     [[/* Test availability of runtime routines for shift and division.  */
 106       long long int llmax = 9223372036854775807ll;
 107       unsigned long long int ullmax = 18446744073709551615ull;
 108       return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
 109               | (llmax / ll) | (llmax % ll)
 110               | (ull << 63) | (ull >> 63) | (ull << i) | (ull >> i)
 111               | (ullmax / ull) | (ullmax % ull));]])
 112 ])