m4/mathfunc.m4

   1 # mathfunc.m4 serial 5
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_MATHFUNC(FUNC, RETTYPE, PARAMTYPES)
   8 # --------------------------------------------------
   9 # tests whether the function FUNC is available in libc or libm.
  10 # RETTYPE is the return type. PARAMTYPES is a parameter list, with parentheses.
  11 # It sets FUNC_LIBM to empty or "-lm" accordingly.
  12
  13 AC_DEFUN([gl_MATHFUNC],
  14 [
  15   dnl We need the RETTYPE and PARAMTYPES in order to force linking with the
  16   dnl function. With gcc >= 4.3 on glibc/x86_64, calls to the 'fabs' function
  17   dnl are inlined by the compiler, therefore linking of these calls does not
  18   dnl require -lm, but taking the function pointer of 'fabs' does.
  19   m4_pushdef([func], [$1])
  20   m4_pushdef([FUNC], [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
  21                                        [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
  22   FUNC[]_LIBM=
  23   AC_CACHE_CHECK([whether func() can be used without linking with libm],
  24     [gl_cv_func_]func[_no_libm],
  25     [
  26       AC_LINK_IFELSE(
  27         [AC_LANG_PROGRAM([[#ifndef __NO_MATH_INLINES
  28                            # define __NO_MATH_INLINES 1 /* for glibc */
  29                            #endif
  30                            #include <math.h>
  31                            $2 (*funcptr) $3 = ]func[;]],
  32                          [[return 0;]])],
  33         [gl_cv_func_]func[_no_libm=yes],
  34         [gl_cv_func_]func[_no_libm=no])
  35     ])
  36   if test $gl_cv_func_[]func[]_no_libm = no; then
  37     AC_CACHE_CHECK([whether func() can be used with libm],
  38       [gl_cv_func_]func[_in_libm],
  39       [
  40         save_LIBS="$LIBS"
  41         LIBS="$LIBS -lm"
  42         AC_LINK_IFELSE(
  43           [AC_LANG_PROGRAM([[#ifndef __NO_MATH_INLINES
  44                              # define __NO_MATH_INLINES 1 /* for glibc */
  45                              #endif
  46                              #include <math.h>
  47                              $2 (*funcptr) $3 = ]func[;]],
  48                            [[return 0;]])],
  49           [gl_cv_func_]func[_in_libm=yes],
  50           [gl_cv_func_]func[_in_libm=no])
  51         LIBS="$save_LIBS"
  52       ])
  53     if test $gl_cv_func_[]func[]_in_libm = yes; then
  54       FUNC[]_LIBM=-lm
  55     fi
  56   fi
  57   AC_SUBST(FUNC[_LIBM])
  58   m4_popdef([FUNC])
  59   m4_popdef([func])
  60 ])
  61
  62 # gl_COMMON_DOUBLE_MATHFUNC(FUNC)
  63 # -------------------------------
  64 # tests whether the function FUNC is available in libc or libm.
  65 # It sets FUNC_LIBM to empty or "-lm" accordingly.
  66 # FUNC must be one of the following functions, that are present on all systems
  67 # and provided by libm on all systems except MacOS X, BeOS, Haiku:
  68 #   acos asin atan atan2 cbrt cos cosh erf erfc exp fmod hypot j0 j1 jn lgamma
  69 #   log log10 log1p pow remainder sin sinh sqrt tan tanh y0 y1 yn
  70
  71 AC_DEFUN([gl_COMMON_DOUBLE_MATHFUNC],
  72 [
  73   AC_REQUIRE([gl_COMMON_DOUBLE_MATHFUNC_TEST])
  74   m4_pushdef([FUNC], [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
  75                                        [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
  76   FUNC[]_LIBM="$POW_LIBM"
  77   AC_SUBST(FUNC[_LIBM])
  78   m4_popdef([FUNC])
  79 ])
  80
  81 AC_DEFUN([gl_COMMON_DOUBLE_MATHFUNC_TEST],
  82 [
  83   dnl We could use any of the following:
  84   dnl gl_MATHFUNC([acos], [double], [(double)])
  85   dnl gl_MATHFUNC([asin], [double], [(double)])
  86   dnl gl_MATHFUNC([atan], [double], [(double)])
  87   dnl gl_MATHFUNC([atan2], [double], [(double, double)])
  88   dnl gl_MATHFUNC([cbrt], [double], [(double)])
  89   dnl gl_MATHFUNC([cos], [double], [(double)])
  90   dnl gl_MATHFUNC([cosh], [double], [(double)])
  91   dnl gl_MATHFUNC([erf], [double], [(double)])
  92   dnl gl_MATHFUNC([erfc], [double], [(double)])
  93   dnl gl_MATHFUNC([exp], [double], [(double)])
  94   dnl gl_MATHFUNC([fmod], [double], [(double, double)])
  95   dnl gl_MATHFUNC([hypot], [double], [(double, double)])
  96   dnl gl_MATHFUNC([j0], [double], [(double)])
  97   dnl gl_MATHFUNC([j1], [double], [(double)])
  98   dnl gl_MATHFUNC([jn], [double], [(int, double)])
  99   dnl gl_MATHFUNC([lgamma], [double], [(double)])
 100   dnl gl_MATHFUNC([log], [double], [(double)])
 101   dnl gl_MATHFUNC([log10], [double], [(double)])
 102   dnl gl_MATHFUNC([log1p], [double], [(double)])
 103   dnl gl_MATHFUNC([pow], [double], [(double, double)])
 104   dnl gl_MATHFUNC([remainder], [double], [(double, double)])
 105   dnl gl_MATHFUNC([sin], [double], [(double)])
 106   dnl gl_MATHFUNC([sinh], [double], [(double)])
 107   dnl gl_MATHFUNC([sqrt], [double], [(double)])
 108   dnl gl_MATHFUNC([tan], [double], [(double)])
 109   dnl gl_MATHFUNC([tanh], [double], [(double)])
 110   dnl gl_MATHFUNC([y0], [double], [(double)])
 111   dnl gl_MATHFUNC([y1], [double], [(double)])
 112   dnl gl_MATHFUNC([yn], [double], [(int, double)])
 113   gl_MATHFUNC([pow], [double], [(double, double)])
 114 ])