m4/mknod.m4

   1 # serial 1
   2 # See if we need to provide mknod replacement.
   3
   4 dnl Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_MKNOD],
  12 [
  13   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  14   AC_REQUIRE([gl_FUNC_MKFIFO])
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16   AC_CHECK_FUNCS_ONCE([mknod])
  17   if test $ac_cv_func_mknod = no; then
  18     HAVE_MKNOD=0
  19     AC_LIBOBJ([mknod])
  20   else
  21     dnl Detect BSD bug, where mknod requires root privileges to create fifo.
  22     AC_CACHE_CHECK([whether mknod can create fifo without root privileges],
  23       [gl_cv_func_mknod_works],
  24       [AC_RUN_IFELSE(
  25          [AC_LANG_PROGRAM(
  26            [[#include <sys/stat.h>
  27              #include <unistd.h>
  28 ]], [[/* Indeterminate for super-user, assume no.  Why are you running
  29          configure as root, anyway?  */
  30       if (!geteuid ()) return 1;
  31       if (mknod ("conftest.fifo", S_IFIFO | 0600, 0)) return 2;]])],
  32          [gl_cv_func_mknod_works=yes], [gl_cv_func_mknod_works=no],
  33          [gl_cv_func_mknod_works="guessing no"])
  34        rm -f conftest.fifo])
  35     if test "$gl_cv_func_mknod_works" != yes; then
  36       AC_DEFINE([MKNOD_FIFO_BUG], [1], [Define to 1 if mknod cannot create
  37         a fifo without super-user privileges])
  38     fi
  39     dnl Systems that mishandle trailing slash on mkfifo also goof on mknod.
  40     if test $REPLACE_MKFIFO = 1 || test "$gl_cv_func_mknod_works" != yes; then
  41       REPLACE_MKNOD=1
  42       AC_LIBOBJ([mknod])
  43     fi
  44   fi
  45 ])