m4/mknod.m4

   1 # serial 5
   2 # See if we need to provide mknod replacement.
   3
   4 dnl Copyright (C) 2009-2012 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_MKNOD],
  12 [
  13   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  14   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  15   AC_REQUIRE([gl_FUNC_MKFIFO])
  16   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  17   AC_CHECK_FUNCS_ONCE([mknod])
  18   if test $ac_cv_func_mknod = no; then
  19     HAVE_MKNOD=0
  20   else
  21     dnl Detect BSD bug, where mknod requires root privileges to create fifo.
  22     AC_CACHE_CHECK([whether mknod can create fifo without root privileges],
  23       [gl_cv_func_mknod_works],
  24       [AC_RUN_IFELSE(
  25          [AC_LANG_PROGRAM(
  26            [[#include <sys/stat.h>
  27              #include <unistd.h>
  28 ]], [[/* Indeterminate for super-user, assume no.  Why are you running
  29          configure as root, anyway?  */
  30       if (!geteuid ()) return 99;
  31       if (mknod ("conftest.fifo", S_IFIFO | 0600, 0)) return 2;]])],
  32          [gl_cv_func_mknod_works=yes],
  33          [if test $? = 99 && test x"$FORCE_UNSAFE_CONFIGURE" = x; then
  34             AC_MSG_FAILURE([you should not run configure as root ]dnl
  35 [(set FORCE_UNSAFE_CONFIGURE=1 in environment to bypass this check)])
  36           fi
  37           gl_cv_func_mknod_works=no],
  38          [case "$host_os" in
  39                     # Guess yes on glibc systems.
  40             *-gnu*) gl_cv_func_mknod_works="guessing yes" ;;
  41                     # If we don't know, assume the worst.
  42             *)      gl_cv_func_mknod_works="guessing no" ;;
  43           esac
  44          ])
  45        rm -f conftest.fifo])
  46     case "$gl_cv_func_mknod_works" in
  47       *yes) ;;
  48       *)
  49         REPLACE_MKNOD=1
  50         AC_DEFINE([MKNOD_FIFO_BUG], [1], [Define to 1 if mknod cannot create
  51           a fifo without super-user privileges])
  52         ;;
  53     esac
  54     dnl Systems that mishandle trailing slash on mkfifo also goof on mknod.
  55     if test $REPLACE_MKFIFO = 1; then
  56       REPLACE_MKNOD=1
  57     fi
  58   fi
  59 ])