m4/modfl.m4

   1 # modfl.m4 serial 2
   2 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_MODFL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_modfl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12
  13   dnl Persuade glibc <math.h> to declare modfl().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether modfl() exists. We cannot assume that modfl(), if it
  17   dnl exists, is defined in the same library as modf(). This is not the case
  18   dnl on FreeBSD, Solaris.
  19   gl_MATHFUNC([modfl], [long double], [(long double, long double *)])
  20   if test $gl_cv_func_modfl_no_libm = yes \
  21      || test $gl_cv_func_modfl_in_libm = yes; then
  22     :
  23     m4_ifdef([gl_FUNC_MODFL_IEEE], [
  24       if test $gl_modfl_required = ieee && test $REPLACE_MODFL = 0; then
  25         AC_CACHE_CHECK([whether modfl works according to ISO C 99 with IEC 60559],
  26           [gl_cv_func_modfl_ieee],
  27           [
  28             save_LIBS="$LIBS"
  29             LIBS="$LIBS $MODFL_LIBM"
  30             AC_RUN_IFELSE(
  31               [AC_LANG_SOURCE([[
  32 #ifndef __NO_MATH_INLINES
  33 # define __NO_MATH_INLINES 1 /* for glibc */
  34 #endif
  35 #include <math.h>
  36 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  37 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  38 /* Compare two numbers with ==.
  39    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  40    'x == x' test.  */
  41 static int
  42 numeric_equal (long double x, long double y)
  43 {
  44   return x == y;
  45 }
  46 static long double dummy (long double x, long double *iptr) { return 0; }
  47 long double zero;
  48 long double minus_one = - 1.0L;
  49 int main (int argc, char *argv[])
  50 {
  51   long double (*my_modfl) (long double, long double *) = argc ? modfl : dummy;
  52   long double i;
  53   long double f;
  54   /* Test modfl(-Inf,...).
  55      This test fails on IRIX 6.5, OSF/1 5.1, mingw.  */
  56   f = my_modfl (minus_one / zero, &i);
  57   if (!(f == 0.0L) || (signbitl (minus_zerol) && !signbitl (f)))
  58     return 1;
  59   return 0;
  60 }
  61               ]])],
  62               [gl_cv_func_modfl_ieee=yes],
  63               [gl_cv_func_modfl_ieee=no],
  64               [gl_cv_func_modfl_ieee="guessing no"])
  65             LIBS="$save_LIBS"
  66           ])
  67         case "$gl_cv_func_modfl_ieee" in
  68           *yes) ;;
  69           *) REPLACE_MODFL=1 ;;
  70         esac
  71       fi
  72     ])
  73   else
  74     HAVE_MODFL=0
  75   fi
  76   if test $HAVE_MODFL = 0 || test $REPLACE_MODFL = 1; then
  77     dnl Find libraries needed to link lib/modfl.c.
  78     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  79       AC_REQUIRE([gl_FUNC_MODF])
  80       MODFL_LIBM="$MODF_LIBM"
  81     else
  82       AC_REQUIRE([gl_FUNC_TRUNCL])
  83       MODFL_LIBM="$TRUNCL_LIBM"
  84     fi
  85   fi
  86   AC_SUBST([MODFL_LIBM])
  87 ])