m4/nanosleep.m4

   1 #serial 9
   2
   3 dnl From Jim Meyering.
   4 dnl Check for the nanosleep function.
   5 dnl If not found, use the supplied replacement.
   6 dnl
   7
   8 AC_DEFUN([jm_FUNC_NANOSLEEP],
   9 [
  10  nanosleep_save_libs=$LIBS
  11
  12  # Solaris 2.5.1 needs -lposix4 to get the nanosleep function.
  13  # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
  14  AC_SEARCH_LIBS(nanosleep, [rt posix4], [LIB_NANOSLEEP=$ac_cv_search_nanosleep])
  15  AC_SUBST(LIB_NANOSLEEP)
  16
  17  AC_CACHE_CHECK([whether nanosleep works],
  18   jm_cv_func_nanosleep_works,
  19   [
  20    AC_REQUIRE([AC_HEADER_TIME])
  21    AC_CHECK_HEADERS_ONCE(sys/time.h)
  22    AC_TRY_RUN([
  23 #   if TIME_WITH_SYS_TIME
  24 #    include <sys/time.h>
  25 #    include <time.h>
  26 #   else
  27 #    if HAVE_SYS_TIME_H
  28 #     include <sys/time.h>
  29 #    else
  30 #     include <time.h>
  31 #    endif
  32 #   endif
  33
  34     int
  35     main ()
  36     {
  37       struct timespec ts_sleep, ts_remaining;
  38       ts_sleep.tv_sec = 0;
  39       ts_sleep.tv_nsec = 1;
  40       exit (nanosleep (&ts_sleep, &ts_remaining) == 0 ? 0 : 1);
  41     }
  42           ],
  43          jm_cv_func_nanosleep_works=yes,
  44          jm_cv_func_nanosleep_works=no,
  45          dnl When crosscompiling, assume the worst.
  46          jm_cv_func_nanosleep_works=no)
  47   ])
  48   if test $jm_cv_func_nanosleep_works = no; then
  49     AC_LIBOBJ(nanosleep)
  50     AC_DEFINE(nanosleep, rpl_nanosleep,
  51       [Define to rpl_nanosleep if the replacement function should be used.])
  52     gl_PREREQ_NANOSLEEP
  53   fi
  54
  55  LIBS=$nanosleep_save_libs
  56 ])
  57
  58 # Prerequisites of lib/nanosleep.c.
  59 AC_DEFUN([gl_PREREQ_NANOSLEEP],
  60 [
  61   AC_CHECK_HEADERS_ONCE(unistd.h)
  62 ])