m4/net_if_h.m4

   1 # net_if_h.m4 serial 1
   2 dnl Copyright (C) 2006-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_NET_IF],
   8 [
   9   AC_CACHE_CHECK([whether <net/if.h> is self-contained],
  10     [gl_cv_header_net_if_h_selfcontained],
  11     [
  12       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <net/if.h>]], [[]])],
  13         [gl_cv_header_net_if_h_selfcontained=yes],
  14         [gl_cv_header_net_if_h_selfcontained=no])
  15     ])
  16   if test $gl_cv_header_net_if_h_selfcontained = yes; then
  17     NET_IF_H=''
  18   else
  19     NET_IF_H='net/if.h'
  20     AC_CHECK_HEADERS([net/if.h], [], [], [[#include <sys/socket.h>]])
  21     gl_NEXT_HEADERS([net/if.h])
  22     if test $ac_cv_header_net_if_h = yes; then
  23       HAVE_NET_IF_H=1
  24     else
  25       HAVE_NET_IF_H=0
  26     fi
  27     AC_SUBST([HAVE_NET_IF_H])
  28   fi
  29   AC_SUBST([NET_IF_H])
  30   AM_CONDITIONAL([GL_GENERATE_NET_IF_H], [test -n "$NET_IF_H"])
  31 ])