m4/perl.m4

   1 #serial 7
   2
   3 dnl From Jim Meyering.
   4 dnl Find a new-enough version of Perl.
   5 dnl
   6
   7 # Copyright (C) 1998, 1999, 2000, 2001, 2003, 2004 Free Software
   8 # Foundation, Inc.
   9 #
  10 # This file is free software; the Free Software Foundation
  11 # gives unlimited permission to copy and/or distribute it,
  12 # with or without modifications, as long as this notice is preserved.
  13
  14 AC_DEFUN([gl_PERL],
  15 [
  16   dnl FIXME: don't hard-code 5.003
  17   dnl FIXME: should we cache the result?
  18   AC_MSG_CHECKING([for perl5.003 or newer])
  19   if test "${PERL+set}" = set; then
  20     # `PERL' is set in the user's environment.
  21     candidate_perl_names="$PERL"
  22     perl_specified=yes
  23   else
  24     candidate_perl_names='perl perl5'
  25     perl_specified=no
  26   fi
  27
  28   found=no
  29   AC_SUBST(PERL)
  30   PERL="$am_missing_run perl"
  31   for perl in $candidate_perl_names; do
  32     # Run test in a subshell; some versions of sh will print an error if
  33     # an executable is not found, even if stderr is redirected.
  34     if ( $perl -e 'require 5.003; use File::Compare' ) > /dev/null 2>&1; then
  35       PERL=$perl
  36       found=yes
  37       break
  38     fi
  39   done
  40
  41   AC_MSG_RESULT($found)
  42   test $found = no && AC_MSG_WARN([
  43 WARNING: You don't seem to have perl5.003 or newer installed, or you lack
  44          a usable version of the Perl File::Compare module.  As a result,
  45          you may be unable to run a few tests or to regenerate certain
  46          files if you modify the sources from which they are derived.
  47 ] )
  48 ])