m4/poll.m4

   1 # poll.m4 serial 14
   2 dnl Copyright (c) 2003, 2005-2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_POLL],
   8 [
   9   AC_REQUIRE([gl_POLL_H])
  10   if test "$ac_cv_header_poll_h" = no; then
  11     ac_cv_func_poll=no
  12     gl_cv_func_poll=no
  13   else
  14     AC_CHECK_FUNC([poll],
  15       [# Check whether poll() works on special files (like /dev/null) and
  16        # and ttys (like /dev/tty). On MacOS X 10.4.0 and AIX 5.3, it doesn't.
  17        AC_RUN_IFELSE([AC_LANG_SOURCE([[
  18 #include <fcntl.h>
  19 #include <poll.h>
  20          int main()
  21          {
  22            int result = 0;
  23            struct pollfd ufd;
  24            /* Try /dev/null for reading.  */
  25            ufd.fd = open ("/dev/null", O_RDONLY);
  26            /* If /dev/null does not exist, it's not MacOS X nor AIX. */
  27            if (ufd.fd >= 0)
  28              {
  29                ufd.events = POLLIN;
  30                ufd.revents = 0;
  31                if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLIN))
  32                  result |= 1;
  33              }
  34            /* Try /dev/null for writing.  */
  35            ufd.fd = open ("/dev/null", O_WRONLY);
  36            /* If /dev/null does not exist, it's not MacOS X nor AIX. */
  37            if (ufd.fd >= 0)
  38              {
  39                ufd.events = POLLOUT;
  40                ufd.revents = 0;
  41                if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLOUT))
  42                  result |= 2;
  43              }
  44            /* Trying /dev/tty may be too environment dependent.  */
  45            return result;
  46          }]])],
  47          [gl_cv_func_poll=yes],
  48          [gl_cv_func_poll=no],
  49          [# When cross-compiling, assume that poll() works everywhere except on
  50           # MacOS X or AIX, regardless of its version.
  51           AC_EGREP_CPP([MacOSX], [
  52 #if (defined(__APPLE__) && defined(__MACH__)) || defined(_AIX)
  53 This is MacOSX or AIX
  54 #endif
  55 ], [gl_cv_func_poll=no], [gl_cv_func_poll=yes])])])
  56   fi
  57   if test $gl_cv_func_poll != yes; then
  58     AC_CHECK_FUNC([poll], [ac_cv_func_poll=yes], [ac_cv_func_poll=no])
  59     if test $ac_cv_func_poll = no; then
  60       HAVE_POLL=0
  61     else
  62       REPLACE_POLL=1
  63     fi
  64   fi
  65   if test $HAVE_POLL = 0 || test $REPLACE_POLL = 1; then
  66     :
  67   else
  68     AC_DEFINE([HAVE_POLL], [1],
  69       [Define to 1 if you have the 'poll' function and it works.])
  70   fi
  71 ])
  72
  73 # Prerequisites of lib/poll.c.
  74 AC_DEFUN([gl_PREREQ_POLL],
  75 [
  76   AC_CHECK_HEADERS_ONCE([sys/ioctl.h sys/filio.h])
  77 ])