m4/posixver.m4

   1 # posixver.m4 serial 12
   2 dnl Copyright (C) 2002-2006, 2009-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_POSIXVER],
   8 [
   9   AC_REQUIRE([gl_DEFAULT_POSIX2_VERSION])
  10 ])
  11
  12 # Set the default level of POSIX conformance at configure-time.
  13 # Build with './configure DEFAULT_POSIX2_VERSION=199209 ...' to
  14 # support the older version, thus preserving portability with
  15 # scripts that use sort +1, tail +32, etc.
  16 # Note however, that this breaks tools that might run commands
  17 # like 'sort +some-file' that conform with the newer standard.
  18 AC_DEFUN([gl_DEFAULT_POSIX2_VERSION],
  19 [
  20   AC_MSG_CHECKING([for desired default level of POSIX conformance])
  21   gl_default_posix2_version=none-specified
  22   if test -n "$ac_cv_env_DEFAULT_POSIX2_VERSION_set"; then
  23     gl_default_posix2_version=$ac_cv_env_DEFAULT_POSIX2_VERSION_value
  24     AC_DEFINE_UNQUOTED([DEFAULT_POSIX2_VERSION],
  25       $gl_default_posix2_version,
  26       [Define the default level of POSIX conformance. The value is of
  27        the form YYYYMM, specifying the year and month the standard was
  28        adopted. If not defined here, it defaults to the value of
  29        _POSIX2_VERSION in <unistd.h>. Define to 199209 to default to
  30        POSIX 1003.2-1992, which makes standard programs like 'head',
  31        'tail', and 'sort' accept obsolete options like '+10' and
  32        '-10'. Define to 200112 to default to POSIX 1003.1-2001, which
  33        makes these standard programs treat leading-'+' operands as
  34        file names and require modern usages like '-n 10' instead of
  35        '-10'. Whether defined here or not, the default can be
  36        overridden at run time via the _POSIX2_VERSION environment
  37        variable.])
  38   fi
  39   AC_MSG_RESULT([$gl_default_posix2_version])
  40   AC_ARG_VAR(
  41     [DEFAULT_POSIX2_VERSION],
  42     [POSIX version to default to; see 'config.hin'.])
  43 ])