m4/pty.m4

   1 # pty.m4 serial 12
   2 dnl Copyright (C) 2010-2013 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_PTY_LIB
   8 # ----------
   9 # Define automake variable PTY_LIB to the library needed (if any).
  10 AC_DEFUN([gl_PTY_LIB],
  11 [
  12   # Check for the library required for forkpty.
  13   PTY_LIB=
  14   save_LIBS="$LIBS"
  15   AC_SEARCH_LIBS([forkpty], [util],
  16     [if test "$ac_cv_search_forkpty" != "none required"; then
  17        PTY_LIB="$ac_cv_search_forkpty"
  18      fi])
  19   LIBS="$save_LIBS"
  20   AC_SUBST([PTY_LIB])
  21 ])
  22
  23 AC_DEFUN([gl_FUNC_FORKPTY],
  24 [
  25   AC_REQUIRE([gl_PTY_LIB])
  26   AC_REQUIRE([gl_PTY_H])
  27
  28   dnl We assume that forkpty exists (possibly in libc, possibly in libutil)
  29   dnl if and only if it is declared.
  30   AC_CHECK_DECLS([forkpty],,, [[
  31 /* <sys/types.h> is a prerequisite of <libutil.h> on FreeBSD 8.0.  */
  32 #include <sys/types.h>
  33 #if HAVE_PTY_H
  34 # include <pty.h>
  35 #endif
  36 #if HAVE_UTIL_H
  37 # include <util.h>
  38 #endif
  39 #if HAVE_LIBUTIL_H
  40 # include <libutil.h>
  41 #endif
  42 ]])
  43   if test $ac_cv_have_decl_forkpty = yes; then
  44     dnl The system has forkpty.
  45     dnl Prefer glibc's const-safe prototype, if available.
  46     AC_CACHE_CHECK([for const-safe forkpty signature],
  47       [gl_cv_func_forkpty_const],
  48       [AC_COMPILE_IFELSE(
  49         [AC_LANG_PROGRAM([[
  50 /* <sys/types.h> is a prerequisite of <libutil.h> on FreeBSD 8.0.  */
  51 #include <sys/types.h>
  52 #if HAVE_PTY_H
  53 # include <pty.h>
  54 #endif
  55 #if HAVE_UTIL_H
  56 # include <util.h>
  57 #endif
  58 #if HAVE_LIBUTIL_H
  59 # include <libutil.h>
  60 #endif
  61           ]], [[
  62             int forkpty (int *, char *, struct termios const *,
  63                          struct winsize const *);
  64           ]])
  65         ],
  66         [gl_cv_func_forkpty_const=yes], [gl_cv_func_forkpty_const=no])
  67       ])
  68     if test $gl_cv_func_forkpty_const != yes; then
  69       REPLACE_FORKPTY=1
  70     fi
  71   else
  72     dnl The system does not have forkpty.
  73     HAVE_FORKPTY=0
  74   fi
  75 ])
  76
  77 AC_DEFUN([gl_FUNC_OPENPTY],
  78 [
  79   AC_REQUIRE([gl_PTY_LIB])
  80   AC_REQUIRE([gl_PTY_H])
  81
  82   dnl Persuade Solaris <stdlib.h> to declare posix_openpt().
  83   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  84
  85   dnl We assume that openpty exists (possibly in libc, possibly in libutil)
  86   dnl if and only if it is declared.
  87   AC_CHECK_DECLS([openpty],,, [[
  88 /* <sys/types.h> is a prerequisite of <libutil.h> on FreeBSD 8.0.  */
  89 #include <sys/types.h>
  90 #if HAVE_PTY_H
  91 # include <pty.h>
  92 #endif
  93 #if HAVE_UTIL_H
  94 # include <util.h>
  95 #endif
  96 #if HAVE_LIBUTIL_H
  97 # include <libutil.h>
  98 #endif
  99 ]])
 100   if test $ac_cv_have_decl_openpty = yes; then
 101     AC_DEFINE([HAVE_OPENPTY], [1],
 102       [Define to 1 if the system has the 'openpty' function.])
 103     dnl The system has openpty.
 104     dnl Prefer glibc's const-safe prototype, if available.
 105     AC_CACHE_CHECK([for const-safe openpty signature],
 106       [gl_cv_func_openpty_const],
 107       [AC_COMPILE_IFELSE(
 108         [AC_LANG_PROGRAM([[
 109 /* <sys/types.h> is a prerequisite of <libutil.h> on FreeBSD 8.0.  */
 110 #include <sys/types.h>
 111 #if HAVE_PTY_H
 112 # include <pty.h>
 113 #endif
 114 #if HAVE_UTIL_H
 115 # include <util.h>
 116 #endif
 117 #if HAVE_LIBUTIL_H
 118 # include <libutil.h>
 119 #endif
 120           ]], [[
 121             int openpty (int *, int *, char *, struct termios const *,
 122                        struct winsize const *);
 123           ]])
 124         ],
 125         [gl_cv_func_openpty_const=yes], [gl_cv_func_openpty_const=no])
 126       ])
 127     if test $gl_cv_func_openpty_const != yes; then
 128       REPLACE_OPENPTY=1
 129     fi
 130   else
 131     dnl The system does not have openpty.
 132     HAVE_OPENPTY=0
 133     dnl Prerequisites of lib/openpty.c in this case.
 134     AC_CHECK_FUNCS([_getpty posix_openpt])
 135   fi
 136 ])
 137
 138 AC_DEFUN([gl_FUNC_LOGIN_TTY],
 139 [
 140   AC_REQUIRE([gl_PTY_LIB])
 141
 142   gl_saved_libs="$LIBS"
 143   LIBS="$LIBS $PTY_LIB"
 144   AC_CHECK_FUNCS([login_tty])
 145   LIBS="$gl_saved_LIBS"
 146 ])