m4/random_r.m4

   1 # serial 5
   2 dnl Copyright (C) 2008-2013 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_RANDOM_R],
   8 [
   9   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11
  12   AC_CHECK_HEADERS([random.h], [], [], [AC_INCLUDES_DEFAULT])
  13   if test $ac_cv_header_random_h = no; then
  14     HAVE_RANDOM_H=0
  15   fi
  16
  17   AC_CHECK_TYPES([struct random_data],
  18     [], [HAVE_STRUCT_RANDOM_DATA=0],
  19     [[#include <stdlib.h>
  20       #if HAVE_RANDOM_H
  21       # include <random.h>
  22       #endif
  23     ]])
  24
  25   dnl On AIX and OSF/1, these functions exist, but with different declarations.
  26   dnl Override them all.
  27   case "$host_os" in
  28     aix* | osf*)
  29       REPLACE_RANDOM_R=1
  30       ;;
  31     *)
  32       AC_CHECK_FUNCS([random_r])
  33       if test $ac_cv_func_random_r = no; then
  34         HAVE_RANDOM_R=0
  35       fi
  36       ;;
  37   esac
  38 ])
  39
  40 # Prerequisites of lib/random_r.c.
  41 AC_DEFUN([gl_PREREQ_RANDOM_R], [
  42   :
  43 ])