m4/readlink.m4

   1 # readlink.m4 serial 6
   2 dnl Copyright (C) 2003, 2007, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_READLINK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_CHECK_FUNCS_ONCE([readlink])
  11   if test $ac_cv_func_readlink = no; then
  12     HAVE_READLINK=0
  13     AC_LIBOBJ([readlink])
  14     gl_PREREQ_READLINK
  15   else
  16     AC_CACHE_CHECK([whether readlink signature is correct],
  17       [gl_cv_decl_readlink_works],
  18       [AC_COMPILE_IFELSE(
  19          [AC_LANG_PROGRAM(
  20            [[#include <unistd.h>
  21       /* Cause compilation failure if original declaration has wrong type.  */
  22       ssize_t readlink (const char *, char *, size_t);]])],
  23          [gl_cv_decl_readlink_works=yes], [gl_cv_decl_readlink_works=no])])
  24     if test "$gl_cv_decl_readlink_works" != yes; then
  25       REPLACE_READLINK=1
  26       AC_LIBOBJ([readlink])
  27     fi
  28   fi
  29 ])
  30
  31 # Like gl_FUNC_READLINK, except prepare for separate compilation (no AC_LIBOBJ).
  32 AC_DEFUN([gl_FUNC_READLINK_SEPARATE],
  33 [
  34   AC_CHECK_FUNCS_ONCE([readlink])
  35   gl_PREREQ_READLINK
  36 ])
  37
  38 # Prerequisites of lib/readlink.c.
  39 AC_DEFUN([gl_PREREQ_READLINK],
  40 [
  41   :
  42 ])