m4/regex.m4

   1 # serial 62
   2
   3 # Copyright (C) 1996-2001, 2003-2013 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 dnl Initially derived from code in GNU grep.
  10 dnl Mostly written by Jim Meyering.
  11
  12 AC_PREREQ([2.50])
  13
  14 AC_DEFUN([gl_REGEX],
  15 [
  16   AC_ARG_WITH([included-regex],
  17     [AS_HELP_STRING([--without-included-regex],
  18                     [don't compile regex; this is the default on systems
  19                      with recent-enough versions of the GNU C Library
  20                      (use with caution on other systems).])])
  21
  22   case $with_included_regex in #(
  23   yes|no) ac_use_included_regex=$with_included_regex
  24         ;;
  25   '')
  26     # If the system regex support is good enough that it passes the
  27     # following run test, then default to *not* using the included regex.c.
  28     # If cross compiling, assume the test would fail and use the included
  29     # regex.c.
  30     AC_CACHE_CHECK([for working re_compile_pattern],
  31                    [gl_cv_func_re_compile_pattern_working],
  32       [AC_RUN_IFELSE(
  33         [AC_LANG_PROGRAM(
  34           [AC_INCLUDES_DEFAULT[
  35            #include <locale.h>
  36            #include <limits.h>
  37            #include <regex.h>
  38            ]],
  39           [[int result = 0;
  40             static struct re_pattern_buffer regex;
  41             unsigned char folded_chars[UCHAR_MAX + 1];
  42             int i;
  43             const char *s;
  44             struct re_registers regs;
  45
  46             if (setlocale (LC_ALL, "en_US.UTF-8"))
  47               {
  48                 {
  49                   /* http://sourceware.org/ml/libc-hacker/2006-09/msg00008.html
  50                      This test needs valgrind to catch the bug on Debian
  51                      GNU/Linux 3.1 x86, but it might catch the bug better
  52                      on other platforms and it shouldn't hurt to try the
  53                      test here.  */
  54                   static char const pat[] = "insert into";
  55                   static char const data[] =
  56                     "\xFF\0\x12\xA2\xAA\xC4\xB1,K\x12\xC4\xB1*\xACK";
  57                   re_set_syntax (RE_SYNTAX_GREP | RE_HAT_LISTS_NOT_NEWLINE
  58                                  | RE_ICASE);
  59                   memset (&regex, 0, sizeof regex);
  60                   s = re_compile_pattern (pat, sizeof pat - 1, &regex);
  61                   if (s)
  62                     result |= 1;
  63                   else if (re_search (&regex, data, sizeof data - 1,
  64                                       0, sizeof data - 1, &regs)
  65                            != -1)
  66                     result |= 1;
  67                 }
  68
  69                 {
  70                   /* This test is from glibc bug 15078.
  71                      The test case is from Andreas Schwab in
  72                      <http://www.sourceware.org/ml/libc-alpha/2013-01/msg00967.html>.
  73                      */
  74                   static char const pat[] = "[^x]x";
  75                   static char const data[] =
  76                     "\xe1\x80\x80\xe1\x80\xbb\xe1\x80\xbd\xe1\x80\x94\xe1\x80"
  77                     "\xba\xe1\x80\xaf\xe1\x80\x95\xe1\x80\xbax";
  78                   re_set_syntax (0);
  79                   memset (&regex, 0, sizeof regex);
  80                   s = re_compile_pattern (pat, sizeof pat - 1, &regex);
  81                   if (s)
  82                     result |= 1;
  83                   else if (re_search (&regex, data, sizeof data - 1,
  84                                       0, sizeof data - 1, 0)
  85                            != 20)
  86                     result |= 1;
  87                 }
  88
  89                 if (! setlocale (LC_ALL, "C"))
  90                   return 1;
  91               }
  92
  93             /* This test is from glibc bug 3957, reported by Andrew Mackey.  */
  94             re_set_syntax (RE_SYNTAX_EGREP | RE_HAT_LISTS_NOT_NEWLINE);
  95             memset (&regex, 0, sizeof regex);
  96             s = re_compile_pattern ("a[^x]b", 6, &regex);
  97             if (s)
  98               result |= 2;
  99             /* This should fail, but succeeds for glibc-2.5.  */
 100             else if (re_search (&regex, "a\nb", 3, 0, 3, &regs) != -1)
 101               result |= 2;
 102
 103             /* This regular expression is from Spencer ere test number 75
 104                in grep-2.3.  */
 105             re_set_syntax (RE_SYNTAX_POSIX_EGREP);
 106             memset (&regex, 0, sizeof regex);
 107             for (i = 0; i <= UCHAR_MAX; i++)
 108               folded_chars[i] = i;
 109             regex.translate = folded_chars;
 110             s = re_compile_pattern ("a[[:@:>@:]]b\n", 11, &regex);
 111             /* This should fail with _Invalid character class name_ error.  */
 112             if (!s)
 113               result |= 4;
 114
 115             /* Ensure that [b-a] is diagnosed as invalid, when
 116                using RE_NO_EMPTY_RANGES. */
 117             re_set_syntax (RE_SYNTAX_POSIX_EGREP | RE_NO_EMPTY_RANGES);
 118             memset (&regex, 0, sizeof regex);
 119             s = re_compile_pattern ("a[b-a]", 6, &regex);
 120             if (s == 0)
 121               result |= 8;
 122
 123             /* This should succeed, but does not for glibc-2.1.3.  */
 124             memset (&regex, 0, sizeof regex);
 125             s = re_compile_pattern ("{1", 2, &regex);
 126             if (s)
 127               result |= 8;
 128
 129             /* The following example is derived from a problem report
 130                against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
 131             memset (&regex, 0, sizeof regex);
 132             s = re_compile_pattern ("[an\371]*n", 7, &regex);
 133             if (s)
 134               result |= 8;
 135             /* This should match, but does not for glibc-2.2.1.  */
 136             else if (re_match (&regex, "an", 2, 0, &regs) != 2)
 137               result |= 8;
 138
 139             memset (&regex, 0, sizeof regex);
 140             s = re_compile_pattern ("x", 1, &regex);
 141             if (s)
 142               result |= 8;
 143             /* glibc-2.2.93 does not work with a negative RANGE argument.  */
 144             else if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
 145               result |= 8;
 146
 147             /* The version of regex.c in older versions of gnulib
 148                ignored RE_ICASE.  Detect that problem too.  */
 149             re_set_syntax (RE_SYNTAX_EMACS | RE_ICASE);
 150             memset (&regex, 0, sizeof regex);
 151             s = re_compile_pattern ("x", 1, &regex);
 152             if (s)
 153               result |= 16;
 154             else if (re_search (&regex, "WXY", 3, 0, 3, &regs) < 0)
 155               result |= 16;
 156
 157             /* Catch a bug reported by Vin Shelton in
 158                http://lists.gnu.org/archive/html/bug-coreutils/2007-06/msg00089.html
 159                */
 160             re_set_syntax (RE_SYNTAX_POSIX_BASIC
 161                            & ~RE_CONTEXT_INVALID_DUP
 162                            & ~RE_NO_EMPTY_RANGES);
 163             memset (&regex, 0, sizeof regex);
 164             s = re_compile_pattern ("[[:alnum:]_-]\\\\+$", 16, &regex);
 165             if (s)
 166               result |= 32;
 167
 168             /* REG_STARTEND was added to glibc on 2004-01-15.
 169                Reject older versions.  */
 170             if (! REG_STARTEND)
 171               result |= 64;
 172
 173 #if 0
 174             /* It would be nice to reject hosts whose regoff_t values are too
 175                narrow (including glibc on hosts with 64-bit ptrdiff_t and
 176                32-bit int), but we should wait until glibc implements this
 177                feature.  Otherwise, support for equivalence classes and
 178                multibyte collation symbols would always be broken except
 179                when compiling --without-included-regex.   */
 180             if (sizeof (regoff_t) < sizeof (ptrdiff_t)
 181                 || sizeof (regoff_t) < sizeof (ssize_t))
 182               result |= 64;
 183 #endif
 184
 185             return result;
 186           ]])],
 187        [gl_cv_func_re_compile_pattern_working=yes],
 188        [gl_cv_func_re_compile_pattern_working=no],
 189        dnl When crosscompiling, assume it is not working.
 190        [gl_cv_func_re_compile_pattern_working=no])])
 191     case $gl_cv_func_re_compile_pattern_working in #(
 192     yes) ac_use_included_regex=no;; #(
 193     no) ac_use_included_regex=yes;;
 194     esac
 195     ;;
 196   *) AC_MSG_ERROR([Invalid value for --with-included-regex: $with_included_regex])
 197     ;;
 198   esac
 199
 200   if test $ac_use_included_regex = yes; then
 201     AC_DEFINE([_REGEX_INCLUDE_LIMITS_H], [1],
 202       [Define if you want <regex.h> to include <limits.h>, so that it
 203        consistently overrides <limits.h>'s RE_DUP_MAX.])
 204     AC_DEFINE([_REGEX_LARGE_OFFSETS], [1],
 205       [Define if you want regoff_t to be at least as wide POSIX requires.])
 206     AC_DEFINE([re_syntax_options], [rpl_re_syntax_options],
 207       [Define to rpl_re_syntax_options if the replacement should be used.])
 208     AC_DEFINE([re_set_syntax], [rpl_re_set_syntax],
 209       [Define to rpl_re_set_syntax if the replacement should be used.])
 210     AC_DEFINE([re_compile_pattern], [rpl_re_compile_pattern],
 211       [Define to rpl_re_compile_pattern if the replacement should be used.])
 212     AC_DEFINE([re_compile_fastmap], [rpl_re_compile_fastmap],
 213       [Define to rpl_re_compile_fastmap if the replacement should be used.])
 214     AC_DEFINE([re_search], [rpl_re_search],
 215       [Define to rpl_re_search if the replacement should be used.])
 216     AC_DEFINE([re_search_2], [rpl_re_search_2],
 217       [Define to rpl_re_search_2 if the replacement should be used.])
 218     AC_DEFINE([re_match], [rpl_re_match],
 219       [Define to rpl_re_match if the replacement should be used.])
 220     AC_DEFINE([re_match_2], [rpl_re_match_2],
 221       [Define to rpl_re_match_2 if the replacement should be used.])
 222     AC_DEFINE([re_set_registers], [rpl_re_set_registers],
 223       [Define to rpl_re_set_registers if the replacement should be used.])
 224     AC_DEFINE([re_comp], [rpl_re_comp],
 225       [Define to rpl_re_comp if the replacement should be used.])
 226     AC_DEFINE([re_exec], [rpl_re_exec],
 227       [Define to rpl_re_exec if the replacement should be used.])
 228     AC_DEFINE([regcomp], [rpl_regcomp],
 229       [Define to rpl_regcomp if the replacement should be used.])
 230     AC_DEFINE([regexec], [rpl_regexec],
 231       [Define to rpl_regexec if the replacement should be used.])
 232     AC_DEFINE([regerror], [rpl_regerror],
 233       [Define to rpl_regerror if the replacement should be used.])
 234     AC_DEFINE([regfree], [rpl_regfree],
 235       [Define to rpl_regfree if the replacement should be used.])
 236   fi
 237 ])
 238
 239 # Prerequisites of lib/regex.c and lib/regex_internal.c.
 240 AC_DEFUN([gl_PREREQ_REGEX],
 241 [
 242   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 243   AC_REQUIRE([AC_C_INLINE])
 244   AC_REQUIRE([AC_C_RESTRICT])
 245   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 246   AC_REQUIRE([gl_EEMALLOC])
 247   AC_CHECK_HEADERS([libintl.h])
 248   AC_CHECK_FUNCS_ONCE([isblank iswctype wcscoll])
 249   AC_CHECK_DECLS([isblank], [], [], [[#include <ctype.h>]])
 250 ])