m4/regex.m4

   1 # serial 64
   2
   3 # Copyright (C) 1996-2001, 2003-2013 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 dnl Initially derived from code in GNU grep.
  10 dnl Mostly written by Jim Meyering.
  11
  12 AC_PREREQ([2.50])
  13
  14 AC_DEFUN([gl_REGEX],
  15 [
  16   AC_ARG_WITH([included-regex],
  17     [AS_HELP_STRING([--without-included-regex],
  18                     [don't compile regex; this is the default on systems
  19                      with recent-enough versions of the GNU C Library
  20                      (use with caution on other systems).])])
  21
  22   case $with_included_regex in #(
  23   yes|no) ac_use_included_regex=$with_included_regex
  24         ;;
  25   '')
  26     # If the system regex support is good enough that it passes the
  27     # following run test, then default to *not* using the included regex.c.
  28     # If cross compiling, assume the test would fail and use the included
  29     # regex.c.
  30     AC_CHECK_DECLS_ONCE([alarm])
  31     AC_CACHE_CHECK([for working re_compile_pattern],
  32                    [gl_cv_func_re_compile_pattern_working],
  33       [AC_RUN_IFELSE(
  34         [AC_LANG_PROGRAM(
  35           [[#include <regex.h>
  36
  37             #include <locale.h>
  38             #include <limits.h>
  39             #include <string.h>
  40             #if HAVE_DECL_ALARM
  41             # include <unistd.h>
  42             # include <signal.h>
  43             #endif
  44           ]],
  45           [[int result = 0;
  46             static struct re_pattern_buffer regex;
  47             unsigned char folded_chars[UCHAR_MAX + 1];
  48             int i;
  49             const char *s;
  50             struct re_registers regs;
  51
  52 #if HAVE_DECL_ALARM
  53             /* Some builds of glibc go into an infinite loop on this test.  */
  54             signal (SIGALRM, SIG_DFL);
  55             alarm (2);
  56 #endif
  57             if (setlocale (LC_ALL, "en_US.UTF-8"))
  58               {
  59                 {
  60                   /* http://sourceware.org/ml/libc-hacker/2006-09/msg00008.html
  61                      This test needs valgrind to catch the bug on Debian
  62                      GNU/Linux 3.1 x86, but it might catch the bug better
  63                      on other platforms and it shouldn't hurt to try the
  64                      test here.  */
  65                   static char const pat[] = "insert into";
  66                   static char const data[] =
  67                     "\xFF\0\x12\xA2\xAA\xC4\xB1,K\x12\xC4\xB1*\xACK";
  68                   re_set_syntax (RE_SYNTAX_GREP | RE_HAT_LISTS_NOT_NEWLINE
  69                                  | RE_ICASE);
  70                   memset (&regex, 0, sizeof regex);
  71                   s = re_compile_pattern (pat, sizeof pat - 1, &regex);
  72                   if (s)
  73                     result |= 1;
  74                   else if (re_search (&regex, data, sizeof data - 1,
  75                                       0, sizeof data - 1, &regs)
  76                            != -1)
  77                     result |= 1;
  78                 }
  79
  80                 {
  81                   /* This test is from glibc bug 15078.
  82                      The test case is from Andreas Schwab in
  83                      <http://www.sourceware.org/ml/libc-alpha/2013-01/msg00967.html>.
  84                      */
  85                   static char const pat[] = "[^x]x";
  86                   static char const data[] =
  87                     /* <U1000><U103B><U103D><U1014><U103A><U102F><U1015><U103A> */
  88                     "\xe1\x80\x80"
  89                     "\xe1\x80\xbb"
  90                     "\xe1\x80\xbd"
  91                     "\xe1\x80\x94"
  92                     "\xe1\x80\xba"
  93                     "\xe1\x80\xaf"
  94                     "\xe1\x80\x95"
  95                     "\xe1\x80\xba"
  96                     "x";
  97                   re_set_syntax (0);
  98                   memset (&regex, 0, sizeof regex);
  99                   s = re_compile_pattern (pat, sizeof pat - 1, &regex);
 100                   if (s)
 101                     result |= 1;
 102                   else
 103                     {
 104                       i = re_search (&regex, data, sizeof data - 1,
 105                                      0, sizeof data - 1, 0);
 106                       if (i != 0 && i != 21)
 107                         result |= 1;
 108                     }
 109                 }
 110
 111                 if (! setlocale (LC_ALL, "C"))
 112                   return 1;
 113               }
 114
 115             /* This test is from glibc bug 3957, reported by Andrew Mackey.  */
 116             re_set_syntax (RE_SYNTAX_EGREP | RE_HAT_LISTS_NOT_NEWLINE);
 117             memset (&regex, 0, sizeof regex);
 118             s = re_compile_pattern ("a[^x]b", 6, &regex);
 119             if (s)
 120               result |= 2;
 121             /* This should fail, but succeeds for glibc-2.5.  */
 122             else if (re_search (&regex, "a\nb", 3, 0, 3, &regs) != -1)
 123               result |= 2;
 124
 125             /* This regular expression is from Spencer ere test number 75
 126                in grep-2.3.  */
 127             re_set_syntax (RE_SYNTAX_POSIX_EGREP);
 128             memset (&regex, 0, sizeof regex);
 129             for (i = 0; i <= UCHAR_MAX; i++)
 130               folded_chars[i] = i;
 131             regex.translate = folded_chars;
 132             s = re_compile_pattern ("a[[:@:>@:]]b\n", 11, &regex);
 133             /* This should fail with _Invalid character class name_ error.  */
 134             if (!s)
 135               result |= 4;
 136
 137             /* Ensure that [b-a] is diagnosed as invalid, when
 138                using RE_NO_EMPTY_RANGES. */
 139             re_set_syntax (RE_SYNTAX_POSIX_EGREP | RE_NO_EMPTY_RANGES);
 140             memset (&regex, 0, sizeof regex);
 141             s = re_compile_pattern ("a[b-a]", 6, &regex);
 142             if (s == 0)
 143               result |= 8;
 144
 145             /* This should succeed, but does not for glibc-2.1.3.  */
 146             memset (&regex, 0, sizeof regex);
 147             s = re_compile_pattern ("{1", 2, &regex);
 148             if (s)
 149               result |= 8;
 150
 151             /* The following example is derived from a problem report
 152                against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
 153             memset (&regex, 0, sizeof regex);
 154             s = re_compile_pattern ("[an\371]*n", 7, &regex);
 155             if (s)
 156               result |= 8;
 157             /* This should match, but does not for glibc-2.2.1.  */
 158             else if (re_match (&regex, "an", 2, 0, &regs) != 2)
 159               result |= 8;
 160
 161             memset (&regex, 0, sizeof regex);
 162             s = re_compile_pattern ("x", 1, &regex);
 163             if (s)
 164               result |= 8;
 165             /* glibc-2.2.93 does not work with a negative RANGE argument.  */
 166             else if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
 167               result |= 8;
 168
 169             /* The version of regex.c in older versions of gnulib
 170                ignored RE_ICASE.  Detect that problem too.  */
 171             re_set_syntax (RE_SYNTAX_EMACS | RE_ICASE);
 172             memset (&regex, 0, sizeof regex);
 173             s = re_compile_pattern ("x", 1, &regex);
 174             if (s)
 175               result |= 16;
 176             else if (re_search (&regex, "WXY", 3, 0, 3, &regs) < 0)
 177               result |= 16;
 178
 179             /* Catch a bug reported by Vin Shelton in
 180                http://lists.gnu.org/archive/html/bug-coreutils/2007-06/msg00089.html
 181                */
 182             re_set_syntax (RE_SYNTAX_POSIX_BASIC
 183                            & ~RE_CONTEXT_INVALID_DUP
 184                            & ~RE_NO_EMPTY_RANGES);
 185             memset (&regex, 0, sizeof regex);
 186             s = re_compile_pattern ("[[:alnum:]_-]\\\\+$", 16, &regex);
 187             if (s)
 188               result |= 32;
 189
 190             /* REG_STARTEND was added to glibc on 2004-01-15.
 191                Reject older versions.  */
 192             if (! REG_STARTEND)
 193               result |= 64;
 194
 195 #if 0
 196             /* It would be nice to reject hosts whose regoff_t values are too
 197                narrow (including glibc on hosts with 64-bit ptrdiff_t and
 198                32-bit int), but we should wait until glibc implements this
 199                feature.  Otherwise, support for equivalence classes and
 200                multibyte collation symbols would always be broken except
 201                when compiling --without-included-regex.   */
 202             if (sizeof (regoff_t) < sizeof (ptrdiff_t)
 203                 || sizeof (regoff_t) < sizeof (ssize_t))
 204               result |= 64;
 205 #endif
 206
 207             return result;
 208           ]])],
 209        [gl_cv_func_re_compile_pattern_working=yes],
 210        [gl_cv_func_re_compile_pattern_working=no],
 211        dnl When crosscompiling, assume it is not working.
 212        [gl_cv_func_re_compile_pattern_working=no])])
 213     case $gl_cv_func_re_compile_pattern_working in #(
 214     yes) ac_use_included_regex=no;; #(
 215     no) ac_use_included_regex=yes;;
 216     esac
 217     ;;
 218   *) AC_MSG_ERROR([Invalid value for --with-included-regex: $with_included_regex])
 219     ;;
 220   esac
 221
 222   if test $ac_use_included_regex = yes; then
 223     AC_DEFINE([_REGEX_INCLUDE_LIMITS_H], [1],
 224       [Define if you want <regex.h> to include <limits.h>, so that it
 225        consistently overrides <limits.h>'s RE_DUP_MAX.])
 226     AC_DEFINE([_REGEX_LARGE_OFFSETS], [1],
 227       [Define if you want regoff_t to be at least as wide POSIX requires.])
 228     AC_DEFINE([re_syntax_options], [rpl_re_syntax_options],
 229       [Define to rpl_re_syntax_options if the replacement should be used.])
 230     AC_DEFINE([re_set_syntax], [rpl_re_set_syntax],
 231       [Define to rpl_re_set_syntax if the replacement should be used.])
 232     AC_DEFINE([re_compile_pattern], [rpl_re_compile_pattern],
 233       [Define to rpl_re_compile_pattern if the replacement should be used.])
 234     AC_DEFINE([re_compile_fastmap], [rpl_re_compile_fastmap],
 235       [Define to rpl_re_compile_fastmap if the replacement should be used.])
 236     AC_DEFINE([re_search], [rpl_re_search],
 237       [Define to rpl_re_search if the replacement should be used.])
 238     AC_DEFINE([re_search_2], [rpl_re_search_2],
 239       [Define to rpl_re_search_2 if the replacement should be used.])
 240     AC_DEFINE([re_match], [rpl_re_match],
 241       [Define to rpl_re_match if the replacement should be used.])
 242     AC_DEFINE([re_match_2], [rpl_re_match_2],
 243       [Define to rpl_re_match_2 if the replacement should be used.])
 244     AC_DEFINE([re_set_registers], [rpl_re_set_registers],
 245       [Define to rpl_re_set_registers if the replacement should be used.])
 246     AC_DEFINE([re_comp], [rpl_re_comp],
 247       [Define to rpl_re_comp if the replacement should be used.])
 248     AC_DEFINE([re_exec], [rpl_re_exec],
 249       [Define to rpl_re_exec if the replacement should be used.])
 250     AC_DEFINE([regcomp], [rpl_regcomp],
 251       [Define to rpl_regcomp if the replacement should be used.])
 252     AC_DEFINE([regexec], [rpl_regexec],
 253       [Define to rpl_regexec if the replacement should be used.])
 254     AC_DEFINE([regerror], [rpl_regerror],
 255       [Define to rpl_regerror if the replacement should be used.])
 256     AC_DEFINE([regfree], [rpl_regfree],
 257       [Define to rpl_regfree if the replacement should be used.])
 258   fi
 259 ])
 260
 261 # Prerequisites of lib/regex.c and lib/regex_internal.c.
 262 AC_DEFUN([gl_PREREQ_REGEX],
 263 [
 264   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 265   AC_REQUIRE([AC_C_INLINE])
 266   AC_REQUIRE([AC_C_RESTRICT])
 267   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 268   AC_REQUIRE([gl_EEMALLOC])
 269   AC_REQUIRE([gl_GLIBC21])
 270   AC_CHECK_HEADERS([libintl.h])
 271   AC_CHECK_FUNCS_ONCE([isblank iswctype])
 272   AC_CHECK_DECLS([isblank], [], [], [[#include <ctype.h>]])
 273 ])