m4/regex.m4

   1 #serial 38
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005,
   4 # 2006 Free Software Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 dnl Initially derived from code in GNU grep.
  11 dnl Mostly written by Jim Meyering.
  12
  13 AC_PREREQ([2.50])
  14
  15 AC_DEFUN([gl_REGEX],
  16 [
  17   AC_LIBSOURCES(
  18     [regcomp.c, regex.c, regex.h,
  19      regex_internal.c, regex_internal.h, regexec.c])
  20
  21   AC_ARG_WITH([included-regex],
  22     [AC_HELP_STRING([--without-included-regex],
  23                     [don't compile regex; this is the default on
  24                      systems with recent-enough versions of the GNU C
  25                      Library (use with caution on other systems)])])
  26
  27   case $with_included_regex in #(
  28   yes|no) ac_use_included_regex=$with_included_regex
  29         ;;
  30   '')
  31     # If the system regex support is good enough that it passes the
  32     # following run test, then default to *not* using the included regex.c.
  33     # If cross compiling, assume the test would fail and use the included
  34     # regex.c.  The first failing regular expression is from `Spencer ere
  35     # test #75' in grep-2.3.
  36     AC_CACHE_CHECK([for working re_compile_pattern],
  37                    [gl_cv_func_re_compile_pattern_working],
  38       [AC_RUN_IFELSE(
  39         [AC_LANG_PROGRAM(
  40           [AC_INCLUDES_DEFAULT
  41            #include <limits.h>
  42            #include <regex.h>
  43            ],
  44           [[static struct re_pattern_buffer regex;
  45             unsigned char folded_chars[UCHAR_MAX + 1];
  46             int i;
  47             const char *s;
  48             struct re_registers regs;
  49             re_set_syntax (RE_SYNTAX_POSIX_EGREP);
  50             memset (&regex, 0, sizeof (regex));
  51             for (i = 0; i <= UCHAR_MAX; i++)
  52               folded_chars[i] = i;
  53             regex.translate = folded_chars;
  54             s = re_compile_pattern ("a[[:@:>@:]]b\n", 11, &regex);
  55             /* This should fail with _Invalid character class name_ error.  */
  56             if (!s)
  57               exit (1);
  58
  59             /* This should succeed, but does not for e.g. glibc-2.1.3.  */
  60             memset (&regex, 0, sizeof (regex));
  61             s = re_compile_pattern ("{1", 2, &regex);
  62
  63             if (s)
  64               exit (1);
  65
  66             /* The following example is derived from a problem report
  67                against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
  68             memset (&regex, 0, sizeof (regex));
  69             s = re_compile_pattern ("[an\371]*n", 7, &regex);
  70             if (s)
  71               exit (1);
  72
  73             /* This should match, but does not for e.g. glibc-2.2.1.  */
  74             if (re_match (&regex, "an", 2, 0, &regs) != 2)
  75               exit (1);
  76
  77             memset (&regex, 0, sizeof (regex));
  78             s = re_compile_pattern ("x", 1, &regex);
  79             if (s)
  80               exit (1);
  81
  82             /* The version of regex.c in e.g. GNU libc-2.2.93 did not
  83                work with a negative RANGE argument.  */
  84             if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
  85               exit (1);
  86
  87             /* The version of regex.c in older versions of gnulib
  88                ignored RE_ICASE.  Detect that problem too.  */
  89             memset (&regex, 0, sizeof (regex));
  90             re_set_syntax (RE_SYNTAX_EMACS | RE_ICASE);
  91             s = re_compile_pattern ("x", 1, &regex);
  92             if (s)
  93               exit (1);
  94
  95             if (re_search (&regex, "WXY", 3, 0, 3, &regs) < 0)
  96               exit (1);
  97
  98             /* REG_STARTEND was added to glibc on 2004-01-15.
  99                Reject older versions.  */
 100             if (! REG_STARTEND)
 101               exit (1);
 102
 103             /* Reject hosts whose regoff_t values are too narrow.
 104                These include glibc 2.3.5 on hosts with 64-bit ptrdiff_t
 105                and 32-bit int.  */
 106             if (sizeof (regoff_t) < sizeof (ptrdiff_t)
 107                 || sizeof (regoff_t) < sizeof (ssize_t))
 108               exit (1);
 109
 110             exit (0);]])],
 111        [gl_cv_func_re_compile_pattern_working=yes],
 112        [gl_cv_func_re_compile_pattern_working=no],
 113        dnl When crosscompiling, assume it is not working.
 114        [gl_cv_func_re_compile_pattern_working=no])])
 115     case $gl_cv_func_re_compile_pattern_working in #(
 116     yes) ac_use_included_regex=no;; #(
 117     no) ac_use_included_regex=yes;;
 118     esac
 119     ;;
 120   *) AC_MSG_ERROR([Invalid value for --with-included-regex: $with_included_regex])
 121     ;;
 122   esac
 123
 124   if test $ac_use_included_regex = yes; then
 125     AC_DEFINE([_REGEX_LARGE_OFFSETS], 1,
 126       [Define if you want regoff_t to be at least as wide POSIX requires.])
 127     AC_DEFINE([re_syntax_options], [rpl_re_syntax_options],
 128       [Define to rpl_re_syntax_options if the replacement should be used.])
 129     AC_DEFINE([re_set_syntax], [rpl_re_set_syntax],
 130       [Define to rpl_re_set_syntax if the replacement should be used.])
 131     AC_DEFINE([re_compile_pattern], [rpl_re_compile_pattern],
 132       [Define to rpl_re_compile_pattern if the replacement should be used.])
 133     AC_DEFINE([re_compile_fastmap], [rpl_re_compile_fastmap],
 134       [Define to rpl_re_compile_fastmap if the replacement should be used.])
 135     AC_DEFINE([re_search], [rpl_re_search],
 136       [Define to rpl_re_search if the replacement should be used.])
 137     AC_DEFINE([re_search_2], [rpl_re_search_2],
 138       [Define to rpl_re_search_2 if the replacement should be used.])
 139     AC_DEFINE([re_match], [rpl_re_match],
 140       [Define to rpl_re_match if the replacement should be used.])
 141     AC_DEFINE([re_match_2], [rpl_re_match_2],
 142       [Define to rpl_re_match_2 if the replacement should be used.])
 143     AC_DEFINE([re_set_registers], [rpl_re_set_registers],
 144       [Define to rpl_re_set_registers if the replacement should be used.])
 145     AC_DEFINE([re_comp], [rpl_re_comp],
 146       [Define to rpl_re_comp if the replacement should be used.])
 147     AC_DEFINE([re_exec], [rpl_re_exec],
 148       [Define to rpl_re_exec if the replacement should be used.])
 149     AC_DEFINE([regcomp], [rpl_regcomp],
 150       [Define to rpl_regcomp if the replacement should be used.])
 151     AC_DEFINE([regexec], [rpl_regexec],
 152       [Define to rpl_regexec if the replacement should be used.])
 153     AC_DEFINE([regerror], [rpl_regerror],
 154       [Define to rpl_regerror if the replacement should be used.])
 155     AC_DEFINE([regfree], [rpl_regfree],
 156       [Define to rpl_regfree if the replacement should be used.])
 157     AC_LIBOBJ([regex])
 158     gl_PREREQ_REGEX
 159   fi
 160 ])
 161
 162 # Prerequisites of lib/regex.c and lib/regex_internal.c.
 163 AC_DEFUN([gl_PREREQ_REGEX],
 164 [
 165   AC_REQUIRE([AC_GNU_SOURCE])
 166   AC_REQUIRE([AC_C_RESTRICT])
 167   AC_REQUIRE([AM_LANGINFO_CODESET])
 168   AC_CHECK_HEADERS_ONCE([locale.h wchar.h wctype.h])
 169   AC_CHECK_FUNCS_ONCE([mbrtowc mempcpy wcrtomb wcscoll])
 170   AC_CHECK_DECLS([isblank], [], [], [#include <ctype.h>])
 171 ])