m4/remainderl.m4

   1 # remainderl.m4 serial 7
   2 dnl Copyright (C) 2012-2013 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_REMAINDERL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_remainderl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12   AC_REQUIRE([gl_FUNC_REMAINDER])
  13
  14   dnl Persuade glibc <math.h> to declare remainderl().
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl Test whether remainderl() exists. Assume that remainderl(), if it exists, is
  18   dnl defined in the same library as remainder().
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $REMAINDER_LIBM"
  21   AC_CACHE_CHECK([for remainderl],
  22     [gl_cv_func_remainderl],
  23     [
  24       AC_LINK_IFELSE(
  25         [AC_LANG_PROGRAM(
  26            [[#ifndef __NO_MATH_INLINES
  27              # define __NO_MATH_INLINES 1 /* for glibc */
  28              #endif
  29              #include <math.h>
  30              extern
  31              #ifdef __cplusplus
  32              "C"
  33              #endif
  34              long double remainderl (long double, long double);
  35              long double (*funcptr) (long double, long double) = remainderl;
  36              long double x;
  37              long double y;]],
  38            [[return funcptr (x, y) > 1
  39                     || remainderl (x, y) > 1;]])],
  40         [gl_cv_func_remainderl=yes],
  41         [gl_cv_func_remainderl=no])
  42     ])
  43   LIBS="$save_LIBS"
  44   if test $gl_cv_func_remainderl = yes; then
  45     HAVE_REMAINDERL=1
  46     REMAINDERL_LIBM="$REMAINDER_LIBM"
  47     dnl Also check whether it's declared.
  48     dnl IRIX 6.5 has remainderl() in libm but doesn't declare it in <math.h>.
  49     AC_CHECK_DECLS([remainderl], , [HAVE_DECL_REMAINDERL=0], [[#include <math.h>]])
  50
  51     save_LIBS="$LIBS"
  52     LIBS="$LIBS $REMAINDERL_LIBM"
  53     gl_FUNC_REMAINDERL_WORKS
  54     LIBS="$save_LIBS"
  55     case "$gl_cv_func_remainderl_works" in
  56       *yes) ;;
  57       *) REPLACE_REMAINDERL=1 ;;
  58     esac
  59
  60     m4_ifdef([gl_FUNC_REMAINDERL_IEEE], [
  61       if test $gl_remainderl_required = ieee && test $REPLACE_REMAINDERL = 0; then
  62         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  63         AC_CACHE_CHECK([whether remainderl works according to ISO C 99 with IEC 60559],
  64           [gl_cv_func_remainderl_ieee],
  65           [
  66             save_LIBS="$LIBS"
  67             LIBS="$LIBS $REMAINDERL_LIBM"
  68             AC_RUN_IFELSE(
  69               [AC_LANG_SOURCE([[
  70 #ifndef __NO_MATH_INLINES
  71 # define __NO_MATH_INLINES 1 /* for glibc */
  72 #endif
  73 #include <math.h>
  74 extern
  75 #ifdef __cplusplus
  76 "C"
  77 #endif
  78 long double remainderl (long double, long double);
  79 /* Compare two numbers with ==.
  80    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  81    'x == x' test.  */
  82 static int
  83 numeric_equal (long double x, long double y)
  84 {
  85   return x == y;
  86 }
  87 static long double dummy (long double x, long double y) { return 0; }
  88 int main (int argc, char *argv[])
  89 {
  90   long double (*my_remainderl) (long double, long double) = argc ? remainderl : dummy;
  91   long double f;
  92   /* Test remainderl(...,0.0L).
  93      This test fails on OSF/1 5.1.  */
  94   f = my_remainderl (2.0L, 0.0L);
  95   if (numeric_equal (f, f))
  96     return 1;
  97   return 0;
  98 }
  99               ]])],
 100               [gl_cv_func_remainderl_ieee=yes],
 101               [gl_cv_func_remainderl_ieee=no],
 102               [case "$host_os" in
 103                          # Guess yes on glibc systems.
 104                  *-gnu*) gl_cv_func_remainderl_ieee="guessing yes" ;;
 105                          # If we don't know, assume the worst.
 106                  *)      gl_cv_func_remainderl_ieee="guessing no" ;;
 107                esac
 108               ])
 109             LIBS="$save_LIBS"
 110           ])
 111         case "$gl_cv_func_remainderl_ieee" in
 112           *yes) ;;
 113           *) REPLACE_REMAINDERL=1 ;;
 114         esac
 115       fi
 116     ])
 117   else
 118     HAVE_REMAINDERL=0
 119     HAVE_DECL_REMAINDERL=0
 120   fi
 121   if test $HAVE_REMAINDERL = 0 || test $REPLACE_REMAINDERL = 1; then
 122     dnl Find libraries needed to link lib/remainderl.c.
 123     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
 124       REMAINDERL_LIBM="$REMAINDER_LIBM"
 125     else
 126       AC_REQUIRE([gl_FUNC_FABSL])
 127       AC_REQUIRE([gl_FUNC_FMODL])
 128       AC_REQUIRE([gl_FUNC_ISNANL])
 129       REMAINDERL_LIBM=
 130       dnl Append $FABSL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
 131       case " $REMAINDERL_LIBM " in
 132         *" $FABSL_LIBM "*) ;;
 133         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FABSL_LIBM" ;;
 134       esac
 135       dnl Append $FMODL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
 136       case " $REMAINDERL_LIBM " in
 137         *" $FMODL_LIBM "*) ;;
 138         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FMODL_LIBM" ;;
 139       esac
 140       dnl Append $ISNANL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
 141       case " $REMAINDERL_LIBM " in
 142         *" $ISNANL_LIBM "*) ;;
 143         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $ISNANL_LIBM" ;;
 144       esac
 145     fi
 146   fi
 147   AC_SUBST([REMAINDERL_LIBM])
 148 ])
 149
 150 dnl Test whether remainderl() works.
 151 dnl It produces completely wrong values on OpenBSD 5.1/SPARC.
 152 AC_DEFUN([gl_FUNC_REMAINDERL_WORKS],
 153 [
 154   AC_REQUIRE([AC_PROG_CC])
 155   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 156   AC_CACHE_CHECK([whether remainderl works], [gl_cv_func_remainderl_works],
 157     [
 158       AC_RUN_IFELSE(
 159         [AC_LANG_SOURCE([[
 160 #ifndef __NO_MATH_INLINES
 161 # define __NO_MATH_INLINES 1 /* for glibc */
 162 #endif
 163 #include <math.h>
 164 extern
 165 #ifdef __cplusplus
 166 "C"
 167 #endif
 168 long double remainderl (long double, long double);
 169 volatile long double x;
 170 volatile long double y;
 171 long double z;
 172 int main ()
 173 {
 174   /* This test fails on OpenBSD 5.1/SPARC.  */
 175   x = 9.245907126L;
 176   y = 3.141592654L;
 177   z = remainderl (x, y);
 178   if (z >= 0.0L)
 179     return 1;
 180   return 0;
 181 }
 182 ]])],
 183         [gl_cv_func_remainderl_works=yes],
 184         [gl_cv_func_remainderl_works=no],
 185         [case "$host_os" in
 186            openbsd*) gl_cv_func_remainderl_works="guessing no";;
 187            *)        gl_cv_func_remainderl_works="guessing yes";;
 188          esac
 189         ])
 190     ])
 191 ])