m4/round.m4

   1 # round.m4 serial 9
   2 dnl Copyright (C) 2007, 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUND],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare round().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   AC_CHECK_DECLS([round], , , [#include <math.h>])
  13   if test "$ac_cv_have_decl_round" = yes; then
  14     gl_CHECK_MATH_LIB([ROUND_LIBM], [x = round (x);])
  15     if test "$ROUND_LIBM" != missing; then
  16       dnl Test whether round() produces correct results. On NetBSD 3.0, for
  17       dnl x = 1/2 - 2^-54, the system's round() returns a wrong result.
  18       AC_REQUIRE([AC_PROG_CC])
  19       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  20       AC_CACHE_CHECK([whether round works], [gl_cv_func_round_works],
  21         [
  22           save_LIBS="$LIBS"
  23           LIBS="$LIBS $ROUND_LIBM"
  24           AC_RUN_IFELSE([AC_LANG_SOURCE([[
  25 #include <float.h>
  26 #include <math.h>
  27 int main()
  28 {
  29   /* 2^DBL_MANT_DIG.  */
  30   static const double TWO_MANT_DIG =
  31     /* Assume DBL_MANT_DIG <= 5 * 31.
  32        Use the identity
  33        n = floor(n/5) + floor((n+1)/5) + ... + floor((n+4)/5).  */
  34     (double) (1U << (DBL_MANT_DIG / 5))
  35     * (double) (1U << ((DBL_MANT_DIG + 1) / 5))
  36     * (double) (1U << ((DBL_MANT_DIG + 2) / 5))
  37     * (double) (1U << ((DBL_MANT_DIG + 3) / 5))
  38     * (double) (1U << ((DBL_MANT_DIG + 4) / 5));
  39   volatile double x = 0.5 - 0.5 / TWO_MANT_DIG;
  40   exit (x < 0.5 && round (x) != 0.0);
  41 }]])], [gl_cv_func_round_works=yes], [gl_cv_func_round_works=no],
  42           [case "$host_os" in
  43              netbsd* | aix*) gl_cv_func_round_works="guessing no";;
  44              *)              gl_cv_func_round_works="guessing yes";;
  45            esac
  46           ])
  47           LIBS="$save_LIBS"
  48         ])
  49       case "$gl_cv_func_round_works" in
  50         *no) ROUND_LIBM=missing ;;
  51       esac
  52     fi
  53     if test "$ROUND_LIBM" = missing; then
  54       REPLACE_ROUND=1
  55     fi
  56   else
  57     HAVE_DECL_ROUND=0
  58   fi
  59   if test $HAVE_DECL_ROUND = 0 || test $REPLACE_ROUND = 1; then
  60     AC_LIBOBJ([round])
  61     gl_FUNC_FLOOR_LIBS
  62     gl_FUNC_CEIL_LIBS
  63     ROUND_LIBM=
  64     dnl Append $FLOOR_LIBM to ROUND_LIBM, avoiding gratuitous duplicates.
  65     case " $ROUND_LIBM " in
  66       *" $FLOOR_LIBM "*) ;;
  67       *) ROUND_LIBM="$ROUND_LIBM $FLOOR_LIBM" ;;
  68     esac
  69     dnl Append $CEIL_LIBM to ROUND_LIBM, avoiding gratuitous duplicates.
  70     case " $ROUND_LIBM " in
  71       *" $CEIL_LIBM "*) ;;
  72       *) ROUND_LIBM="$ROUND_LIBM $CEIL_LIBM" ;;
  73     esac
  74   fi
  75   AC_SUBST([ROUND_LIBM])
  76 ])