m4/round.m4

   1 # round.m4 serial 14
   2 dnl Copyright (C) 2007, 2009-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUND],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_round_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare round().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   AC_CHECK_DECLS([round], , , [[#include <math.h>]])
  14   if test "$ac_cv_have_decl_round" = yes; then
  15     gl_CHECK_MATH_LIB([ROUND_LIBM], [x = round (x);])
  16     if test "$ROUND_LIBM" != missing; then
  17       dnl Test whether round() produces correct results. On NetBSD 3.0, for
  18       dnl x = 1/2 - 2^-54, the system's round() returns a wrong result.
  19       AC_REQUIRE([AC_PROG_CC])
  20       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  21       AC_CACHE_CHECK([whether round works], [gl_cv_func_round_works],
  22         [
  23           save_LIBS="$LIBS"
  24           LIBS="$LIBS $ROUND_LIBM"
  25           AC_RUN_IFELSE([AC_LANG_SOURCE([[
  26 #include <float.h>
  27 #include <math.h>
  28 #ifdef _MSC_VER
  29 # pragma fenv_access (off)
  30 #endif
  31 int main()
  32 {
  33   /* 2^DBL_MANT_DIG.  */
  34   static const double TWO_MANT_DIG =
  35     /* Assume DBL_MANT_DIG <= 5 * 31.
  36        Use the identity
  37        n = floor(n/5) + floor((n+1)/5) + ... + floor((n+4)/5).  */
  38     (double) (1U << (DBL_MANT_DIG / 5))
  39     * (double) (1U << ((DBL_MANT_DIG + 1) / 5))
  40     * (double) (1U << ((DBL_MANT_DIG + 2) / 5))
  41     * (double) (1U << ((DBL_MANT_DIG + 3) / 5))
  42     * (double) (1U << ((DBL_MANT_DIG + 4) / 5));
  43   volatile double x = 0.5 - 0.5 / TWO_MANT_DIG;
  44   exit (x < 0.5 && round (x) != 0.0);
  45 }]])], [gl_cv_func_round_works=yes], [gl_cv_func_round_works=no],
  46           [case "$host_os" in
  47              netbsd* | aix*) gl_cv_func_round_works="guessing no";;
  48              *)              gl_cv_func_round_works="guessing yes";;
  49            esac
  50           ])
  51           LIBS="$save_LIBS"
  52         ])
  53       case "$gl_cv_func_round_works" in
  54         *no) ROUND_LIBM=missing ;;
  55       esac
  56     fi
  57     if test "$ROUND_LIBM" = missing; then
  58       REPLACE_ROUND=1
  59     fi
  60     m4_ifdef([gl_FUNC_ROUND_IEEE], [
  61       if test $gl_round_required = ieee && test $REPLACE_ROUND = 0; then
  62         AC_CACHE_CHECK([whether round works according to ISO C 99 with IEC 60559],
  63           [gl_cv_func_round_ieee],
  64           [
  65             save_LIBS="$LIBS"
  66             LIBS="$LIBS $ROUND_LIBM"
  67             AC_RUN_IFELSE(
  68               [AC_LANG_SOURCE([[
  69 #ifndef __NO_MATH_INLINES
  70 # define __NO_MATH_INLINES 1 /* for glibc */
  71 #endif
  72 #include <math.h>
  73 ]gl_DOUBLE_MINUS_ZERO_CODE[
  74 ]gl_DOUBLE_SIGNBIT_CODE[
  75 static double dummy (double f) { return 0; }
  76 int main (int argc, char *argv[])
  77 {
  78   double (*my_round) (double) = argc ? round : dummy;
  79   /* Test whether round (-0.0) is -0.0.  */
  80   if (signbitd (minus_zerod) && !signbitd (my_round (minus_zerod)))
  81     return 1;
  82   return 0;
  83 }
  84               ]])],
  85               [gl_cv_func_round_ieee=yes],
  86               [gl_cv_func_round_ieee=no],
  87               [gl_cv_func_round_ieee="guessing no"])
  88             LIBS="$save_LIBS"
  89           ])
  90         case "$gl_cv_func_round_ieee" in
  91           *yes) ;;
  92           *) REPLACE_ROUND=1 ;;
  93         esac
  94       fi
  95     ])
  96   else
  97     HAVE_DECL_ROUND=0
  98   fi
  99   if test $HAVE_DECL_ROUND = 0 || test $REPLACE_ROUND = 1; then
 100     dnl Find libraries needed to link lib/round.c.
 101     gl_FUNC_FLOOR_LIBS
 102     gl_FUNC_CEIL_LIBS
 103     ROUND_LIBM=
 104     dnl Append $FLOOR_LIBM to ROUND_LIBM, avoiding gratuitous duplicates.
 105     case " $ROUND_LIBM " in
 106       *" $FLOOR_LIBM "*) ;;
 107       *) ROUND_LIBM="$ROUND_LIBM $FLOOR_LIBM" ;;
 108     esac
 109     dnl Append $CEIL_LIBM to ROUND_LIBM, avoiding gratuitous duplicates.
 110     case " $ROUND_LIBM " in
 111       *" $CEIL_LIBM "*) ;;
 112       *) ROUND_LIBM="$ROUND_LIBM $CEIL_LIBM" ;;
 113     esac
 114   fi
 115   AC_SUBST([ROUND_LIBM])
 116 ])