m4/round.m4

   1 # round.m4 serial 5
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUND],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare round().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   AC_CHECK_DECLS([round], , , [#include <math.h>])
  13   if test "$ac_cv_have_decl_round" = yes; then
  14     gl_CHECK_MATH_LIB([ROUND_LIBM], [x = round (x);])
  15   fi
  16   if test "$ac_cv_have_decl_round" = yes && test "$ROUND_LIBM" != missing; then
  17     dnl Test whether round() produces correct results. On NetBSD 3.0, for
  18     dnl x = 1/2 - 2^-54, the system's round() returns a wrong result.
  19     AC_REQUIRE([AC_PROG_CC])
  20     AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  21     AC_CACHE_CHECK([whether round works], [gl_cv_func_round_works],
  22       [
  23         save_LIBS="$LIBS"
  24         LIBS="$LIBS $ROUND_LIBM"
  25         AC_TRY_RUN([
  26 #include <float.h>
  27 #include <math.h>
  28 int main()
  29 {
  30   /* 2^DBL_MANT_DIG.  */
  31   static const double TWO_MANT_DIG =
  32     /* Assume DBL_MANT_DIG <= 5 * 31.
  33        Use the identity
  34        n = floor(n/5) + floor((n+1)/5) + ... + floor((n+4)/5).  */
  35     (double) (1U << (DBL_MANT_DIG / 5))
  36     * (double) (1U << ((DBL_MANT_DIG + 1) / 5))
  37     * (double) (1U << ((DBL_MANT_DIG + 2) / 5))
  38     * (double) (1U << ((DBL_MANT_DIG + 3) / 5))
  39     * (double) (1U << ((DBL_MANT_DIG + 4) / 5));
  40   volatile double x = 0.5 - 0.5 / TWO_MANT_DIG;
  41   exit (x < 0.5 && round (x) != 0.0);
  42 }], [gl_cv_func_round_works=yes], [gl_cv_func_round_works=no],
  43         [case "$host_os" in
  44            netbsd*) gl_cv_func_round_works="guessing no";;
  45            *)       gl_cv_func_round_works="guessing yes";;
  46          esac
  47         ])
  48         LIBS="$save_LIBS"
  49       ])
  50     case "$gl_cv_func_round_works" in
  51       *no) ROUND_LIBM=missing ;;
  52     esac
  53   fi
  54   if test "$ac_cv_have_decl_round" != yes || test "$ROUND_LIBM" = missing; then
  55     REPLACE_ROUND=1
  56     AC_LIBOBJ([round])
  57     gl_FUNC_FLOOR_LIBS
  58     gl_FUNC_CEIL_LIBS
  59     ROUND_LIBM="$FLOOR_LIBM $CEIL_LIBM"
  60   fi
  61   AC_SUBST([ROUND_LIBM])
  62 ])