m4/roundl.m4

   1 # roundl.m4 serial 11
   2 dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUNDL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_roundl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare roundl().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   AC_CHECK_DECLS([roundl], , , [#include <math.h>])
  14   if test "$ac_cv_have_decl_roundl" = yes; then
  15     gl_CHECK_MATH_LIB([ROUNDL_LIBM], [x = roundl (x);])
  16     if test "$ROUNDL_LIBM" = missing; then
  17       REPLACE_ROUNDL=1
  18     fi
  19     m4_ifdef([gl_FUNC_ROUNDL_IEEE], [
  20       if test $gl_roundl_required = ieee && test $REPLACE_ROUNDL = 0; then
  21         AC_CACHE_CHECK([whether roundl works according to ISO C 99 with IEC 60559],
  22           [gl_cv_func_roundl_ieee],
  23           [
  24             save_LIBS="$LIBS"
  25             LIBS="$LIBS $ROUNDL_LIBM"
  26             AC_RUN_IFELSE(
  27               [AC_LANG_SOURCE([[
  28 #ifndef __NO_MATH_INLINES
  29 # define __NO_MATH_INLINES 1 /* for glibc */
  30 #endif
  31 #include <math.h>
  32 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  33 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  34 static long double dummy (long double f) { return 0; }
  35 int main (int argc, char *argv[])
  36 {
  37   long double (*my_roundl) (long double) = argc ? roundl : dummy;
  38   int result = 0;
  39   /* Test whether roundl (-0.0L) is -0.0L.  */
  40   if (signbitl (minus_zerol) && !signbitl (my_roundl (minus_zerol)))
  41     result |= 1;
  42   /* Test whether roundl (-0.3L) is -0.0L.  */
  43   if (signbitl (-0.3L) && !signbitl (my_roundl (-0.3L)))
  44     result |= 2;
  45   return result;
  46 }
  47               ]])],
  48               [gl_cv_func_roundl_ieee=yes],
  49               [gl_cv_func_roundl_ieee=no],
  50               [gl_cv_func_roundl_ieee="guessing no"])
  51             LIBS="$save_LIBS"
  52           ])
  53         case "$gl_cv_func_roundl_ieee" in
  54           *yes) ;;
  55           *) REPLACE_ROUNDL=1 ;;
  56         esac
  57       fi
  58     ])
  59   else
  60     HAVE_DECL_ROUNDL=0
  61   fi
  62   if test $HAVE_DECL_ROUNDL = 0 || test $REPLACE_ROUNDL = 1; then
  63     dnl Find libraries needed to link lib/roundl.c.
  64     AC_CHECK_DECLS([ceill, floorl], , , [#include <math.h>])
  65     if test "$ac_cv_have_decl_floorl" = yes \
  66        && test "$ac_cv_have_decl_ceill" = yes; then
  67       gl_FUNC_FLOORL_LIBS
  68       gl_FUNC_CEILL_LIBS
  69       if test "$FLOORL_LIBM" != '?' && test "$CEILL_LIBM" != '?'; then
  70         AC_DEFINE([HAVE_FLOORL_AND_CEILL], [1],
  71           [Define if the both the floorl() and ceill() functions exist.])
  72         ROUNDL_LIBM=
  73         dnl Append $FLOORL_LIBM to ROUNDL_LIBM, avoiding gratuitous duplicates.
  74         case " $ROUNDL_LIBM " in
  75           *" $FLOORL_LIBM "*) ;;
  76           *) ROUNDL_LIBM="$ROUNDL_LIBM $FLOORL_LIBM" ;;
  77         esac
  78         dnl Append $CEILL_LIBM to ROUNDL_LIBM, avoiding gratuitous duplicates.
  79         case " $ROUNDL_LIBM " in
  80           *" $CEILL_LIBM "*) ;;
  81           *) ROUNDL_LIBM="$ROUNDL_LIBM $CEILL_LIBM" ;;
  82         esac
  83       else
  84         ROUNDL_LIBM=
  85       fi
  86     else
  87       ROUNDL_LIBM=
  88     fi
  89   fi
  90   AC_SUBST([ROUNDL_LIBM])
  91 ])