m4/roundl.m4

   1 # roundl.m4 serial 10
   2 dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUNDL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_roundl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare roundl().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   AC_CHECK_DECLS([roundl], , , [#include <math.h>])
  14   if test "$ac_cv_have_decl_roundl" = yes; then
  15     gl_CHECK_MATH_LIB([ROUNDL_LIBM], [x = roundl (x);])
  16     if test "$ROUNDL_LIBM" = missing; then
  17       REPLACE_ROUNDL=1
  18     fi
  19     m4_ifdef([gl_FUNC_ROUNDL_IEEE], [
  20       if test $gl_roundl_required = ieee && test $REPLACE_ROUNDL = 0; then
  21         AC_CACHE_CHECK([whether roundl works according to ISO C 99 with IEC 60559],
  22           [gl_cv_func_roundl_ieee],
  23           [
  24             save_LIBS="$LIBS"
  25             LIBS="$LIBS $ROUNDL_LIBM"
  26             AC_RUN_IFELSE(
  27               [AC_LANG_SOURCE([[
  28 #ifndef __NO_MATH_INLINES
  29 # define __NO_MATH_INLINES 1 /* for glibc */
  30 #endif
  31 #include <math.h>
  32 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  33 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  34 static long double dummy (long double f) { return 0; }
  35 int main (int argc, char *argv[])
  36 {
  37   long double (*my_roundl) (long double) = argc ? roundl : dummy;
  38   /* Test whether roundl (-0.0L) is -0.0L.  */
  39   if (signbitl (minus_zerol) && !signbitl (my_roundl (minus_zerol)))
  40     return 1;
  41   return 0;
  42 }
  43               ]])],
  44               [gl_cv_func_roundl_ieee=yes],
  45               [gl_cv_func_roundl_ieee=no],
  46               [gl_cv_func_roundl_ieee="guessing no"])
  47             LIBS="$save_LIBS"
  48           ])
  49         case "$gl_cv_func_roundl_ieee" in
  50           *yes) ;;
  51           *) REPLACE_ROUNDL=1 ;;
  52         esac
  53       fi
  54     ])
  55   else
  56     HAVE_DECL_ROUNDL=0
  57   fi
  58   if test $HAVE_DECL_ROUNDL = 0 || test $REPLACE_ROUNDL = 1; then
  59     dnl Find libraries needed to link lib/roundl.c.
  60     AC_CHECK_DECLS([ceill, floorl], , , [#include <math.h>])
  61     if test "$ac_cv_have_decl_floorl" = yes \
  62        && test "$ac_cv_have_decl_ceill" = yes; then
  63       gl_FUNC_FLOORL_LIBS
  64       gl_FUNC_CEILL_LIBS
  65       if test "$FLOORL_LIBM" != '?' && test "$CEILL_LIBM" != '?'; then
  66         AC_DEFINE([HAVE_FLOORL_AND_CEILL], [1],
  67           [Define if the both the floorl() and ceill() functions exist.])
  68         ROUNDL_LIBM=
  69         dnl Append $FLOORL_LIBM to ROUNDL_LIBM, avoiding gratuitous duplicates.
  70         case " $ROUNDL_LIBM " in
  71           *" $FLOORL_LIBM "*) ;;
  72           *) ROUNDL_LIBM="$ROUNDL_LIBM $FLOORL_LIBM" ;;
  73         esac
  74         dnl Append $CEILL_LIBM to ROUNDL_LIBM, avoiding gratuitous duplicates.
  75         case " $ROUNDL_LIBM " in
  76           *" $CEILL_LIBM "*) ;;
  77           *) ROUNDL_LIBM="$ROUNDL_LIBM $CEILL_LIBM" ;;
  78         esac
  79       else
  80         ROUNDL_LIBM=
  81       fi
  82     else
  83       ROUNDL_LIBM=
  84     fi
  85   fi
  86   AC_SUBST([ROUNDL_LIBM])
  87 ])