m4/signal_h.m4

   1 # signal_h.m4 serial 8
   2 dnl Copyright (C) 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_SIGNAL_H],
   8 [
   9   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  10   gl_CHECK_NEXT_HEADERS([signal.h])
  11 # AIX declares sig_atomic_t to already include volatile, and C89 compilers
  12 # then choke on 'volatile sig_atomic_t'.  C99 requires that it compile.
  13   AC_CHECK_TYPE([volatile sig_atomic_t], [],
  14     [HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=0], [[
  15 #include <signal.h>
  16     ]])
  17   AC_REQUIRE([AC_TYPE_UID_T])
  18 ])
  19
  20 AC_DEFUN([gl_SIGNAL_MODULE_INDICATOR],
  21 [
  22   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  23   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  24   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  25 ])
  26
  27 AC_DEFUN([gl_SIGNAL_H_DEFAULTS],
  28 [
  29   GNULIB_SIGNAL_H_SIGPIPE=0;   AC_SUBST([GNULIB_SIGNAL_H_SIGPIPE])
  30   GNULIB_SIGPROCMASK=0;        AC_SUBST([GNULIB_SIGPROCMASK])
  31   GNULIB_SIGACTION=0;          AC_SUBST([GNULIB_SIGACTION])
  32   dnl Assume proper GNU behavior unless another module says otherwise.
  33   HAVE_POSIX_SIGNALBLOCKING=1; AC_SUBST([HAVE_POSIX_SIGNALBLOCKING])
  34   HAVE_SIGSET_T=1;             AC_SUBST([HAVE_SIGSET_T])
  35   HAVE_SIGINFO_T=1;            AC_SUBST([HAVE_SIGINFO_T])
  36   HAVE_SIGACTION=1;            AC_SUBST([HAVE_SIGACTION])
  37   HAVE_STRUCT_SIGACTION_SA_SIGACTION=1;
  38                                AC_SUBST([HAVE_STRUCT_SIGACTION_SA_SIGACTION])
  39   HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=1;
  40                                AC_SUBST([HAVE_TYPE_VOLATILE_SIG_ATOMIC_T])
  41 ])