m4/sinl.m4

   1 # sinl.m4 serial 3
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SINL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare sinl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   SINL_LIBM=
  14   AC_CACHE_CHECK([whether sinl() can be used without linking with libm],
  15     [gl_cv_func_sinl_no_libm],
  16     [
  17       AC_LINK_IFELSE(
  18         [AC_LANG_PROGRAM(
  19            [[#ifndef __NO_MATH_INLINES
  20              # define __NO_MATH_INLINES 1 /* for glibc */
  21              #endif
  22              #include <math.h>
  23              long double x;]],
  24            [[return sinl (x) > 0.4;]])],
  25         [gl_cv_func_sinl_no_libm=yes],
  26         [gl_cv_func_sinl_no_libm=no])
  27     ])
  28   if test $gl_cv_func_sinl_no_libm = no; then
  29     AC_CACHE_CHECK([whether sinl() can be used with libm],
  30       [gl_cv_func_sinl_in_libm],
  31       [
  32         save_LIBS="$LIBS"
  33         LIBS="$LIBS -lm"
  34         AC_LINK_IFELSE(
  35           [AC_LANG_PROGRAM(
  36              [[#ifndef __NO_MATH_INLINES
  37                # define __NO_MATH_INLINES 1 /* for glibc */
  38                #endif
  39                #include <math.h>
  40                long double x;]],
  41              [[return sinl (x) > 0.4;]])],
  42           [gl_cv_func_sinl_in_libm=yes],
  43           [gl_cv_func_sinl_in_libm=no])
  44         LIBS="$save_LIBS"
  45       ])
  46     if test $gl_cv_func_sinl_in_libm = yes; then
  47       SINL_LIBM=-lm
  48     fi
  49   fi
  50   if test $gl_cv_func_sinl_no_libm = yes \
  51      || test $gl_cv_func_sinl_in_libm = yes; then
  52     dnl Also check whether it's declared.
  53     dnl MacOS X 10.3 has sinl() in libc but doesn't declare it in <math.h>.
  54     AC_CHECK_DECL([sinl], , [HAVE_DECL_SINL=0], [#include <math.h>])
  55   else
  56     HAVE_DECL_SINL=0
  57     HAVE_SINL=0
  58     AC_LIBOBJ([sinl])
  59     AC_LIBOBJ([sincosl])
  60     AC_LIBOBJ([trigl])
  61     AC_REQUIRE([gl_FUNC_ISNANL])
  62     AC_REQUIRE([gl_FUNC_FLOOR])
  63     AC_REQUIRE([gl_FUNC_FLOORL])
  64     dnl Append $ISNANL_LIBM to SINL_LIBM, avoiding gratuitous duplicates.
  65     case " $SINL_LIBM " in
  66       *" $ISNANL_LIBM "*) ;;
  67       *) SINL_LIBM="$SINL_LIBM $ISNANL_LIBM" ;;
  68     esac
  69     dnl Append $FLOOR_LIBM to SINL_LIBM, avoiding gratuitous duplicates.
  70     case " $SINL_LIBM " in
  71       *" $FLOOR_LIBM "*) ;;
  72       *) SINL_LIBM="$SINL_LIBM $FLOOR_LIBM" ;;
  73     esac
  74     dnl Append $FLOORL_LIBM to SINL_LIBM, avoiding gratuitous duplicates.
  75     case " $SINL_LIBM " in
  76       *" $FLOORL_LIBM "*) ;;
  77       *) SINL_LIBM="$SINL_LIBM $FLOORL_LIBM" ;;
  78     esac
  79   fi
  80   AC_SUBST([SINL_LIBM])
  81 ])