m4/sleep.m4

   1 # sleep.m4 serial 6
   2 dnl Copyright (C) 2007-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SLEEP],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   dnl We expect to see the declaration of sleep() in a header file.
  11   dnl Older versions of mingw have a sleep() function that is an alias to
  12   dnl _sleep() in MSVCRT. It has a different signature than POSIX sleep():
  13   dnl it takes the number of milliseconds as argument and returns void.
  14   dnl mingw does not declare this function.
  15   AC_CHECK_DECLS([sleep], , , [[#include <unistd.h>]])
  16   AC_CHECK_FUNCS_ONCE([sleep])
  17   if test $ac_cv_have_decl_sleep != yes; then
  18     HAVE_SLEEP=0
  19   else
  20     dnl Cygwin 1.5.x has a bug where sleep can't exceed 49.7 days.
  21     AC_CACHE_CHECK([for working sleep], [gl_cv_func_sleep_works],
  22       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  23 #include <errno.h>
  24 #include <unistd.h>
  25 #include <signal.h>
  26 static void
  27 handle_alarm (int sig)
  28 {
  29   if (sig != SIGALRM)
  30     _exit (2);
  31 }
  32 ]], [[
  33     /* Failure to compile this test due to missing alarm is okay,
  34        since all such platforms (mingw) also lack sleep.  */
  35     unsigned int pentecost = 50 * 24 * 60 * 60; /* 50 days.  */
  36     unsigned int remaining;
  37     signal (SIGALRM, handle_alarm);
  38     alarm (1);
  39     remaining = sleep (pentecost);
  40     if (remaining > pentecost)
  41       return 3;
  42     if (remaining <= pentecost - 10)
  43       return 4;
  44     return 0;
  45     ]])],
  46       [gl_cv_func_sleep_works=yes], [gl_cv_func_sleep_works=no],
  47       [gl_cv_func_sleep_works="guessing no"])])
  48     if test "$gl_cv_func_sleep_works" != yes; then
  49       REPLACE_SLEEP=1
  50     fi
  51   fi
  52 ])