m4/snprintf-posix.m4

   1 # snprintf-posix.m4 serial 10
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE])
  13   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  20   AC_REQUIRE([gl_PRINTF_PRECISION])
  21   AC_REQUIRE([gl_PRINTF_ENOMEM])
  22   gl_cv_func_snprintf_posix=no
  23   AC_CHECK_FUNCS([snprintf])
  24   if test $ac_cv_func_snprintf = yes; then
  25     gl_SNPRINTF_TRUNCATION_C99
  26     gl_SNPRINTF_RETVAL_C99
  27     gl_SNPRINTF_DIRECTIVE_N
  28     gl_VSNPRINTF_ZEROSIZE_C99
  29     case "$gl_cv_func_printf_sizes_c99" in
  30       *yes)
  31         case "$gl_cv_func_printf_long_double" in
  32           *yes)
  33             case "$gl_cv_func_printf_infinite" in
  34               *yes)
  35                 case "$gl_cv_func_printf_infinite_long_double" in
  36                   *yes)
  37                     case "$gl_cv_func_printf_directive_a" in
  38                       *yes)
  39                         case "$gl_cv_func_printf_directive_f" in
  40                           *yes)
  41                             case "$gl_cv_func_printf_directive_n" in
  42                               *yes)
  43                                 case "$gl_cv_func_printf_positions" in
  44                                   *yes)
  45                                     case "$gl_cv_func_printf_flag_grouping" in
  46                                       *yes)
  47                                         case "$gl_cv_func_printf_flag_zero" in
  48                                           *yes)
  49                                             case "$gl_cv_func_printf_precision" in
  50                                               *yes)
  51                                                 case "$gl_cv_func_printf_enomem" in
  52                                                   *yes)
  53                                                     case "$gl_cv_func_snprintf_truncation_c99" in
  54                                                       *yes)
  55                                                         case "$gl_cv_func_snprintf_retval_c99" in
  56                                                           *yes)
  57                                                             case "$gl_cv_func_snprintf_directive_n" in
  58                                                               *yes)
  59                                                                 case "$gl_cv_func_vsnprintf_zerosize_c99" in
  60                                                                   *yes)
  61                                                                     # snprintf exists and is
  62                                                                     # already POSIX compliant.
  63                                                                     gl_cv_func_snprintf_posix=yes
  64                                                                     ;;
  65                                                                 esac
  66                                                                 ;;
  67                                                             esac
  68                                                             ;;
  69                                                         esac
  70                                                         ;;
  71                                                     esac
  72                                                     ;;
  73                                                 esac
  74                                                 ;;
  75                                             esac
  76                                             ;;
  77                                         esac
  78                                         ;;
  79                                     esac
  80                                     ;;
  81                                 esac
  82                                 ;;
  83                             esac
  84                             ;;
  85                         esac
  86                         ;;
  87                     esac
  88                     ;;
  89                 esac
  90                 ;;
  91             esac
  92             ;;
  93         esac
  94         ;;
  95     esac
  96   fi
  97   if test $gl_cv_func_snprintf_posix = no; then
  98     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  99     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
 100     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
 101     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
 102     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
 103     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
 104     gl_PREREQ_VASNPRINTF_FLAG_ZERO
 105     gl_PREREQ_VASNPRINTF_PRECISION
 106     gl_PREREQ_VASNPRINTF_ENOMEM
 107     gl_REPLACE_VASNPRINTF
 108     gl_REPLACE_SNPRINTF
 109   fi
 110 ])