m4/snprintf-posix.m4

   1 # snprintf-posix.m4 serial 2
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  13   AC_REQUIRE([gl_PRINTF_POSITIONS])
  14   gl_cv_func_snprintf_posix=no
  15   AC_CHECK_FUNCS([snprintf])
  16   if test $ac_cv_func_snprintf = yes; then
  17     gl_SNPRINTF_TRUNCATION_C99
  18     gl_SNPRINTF_RETVAL_C99
  19     gl_SNPRINTF_DIRECTIVE_N
  20     case "$gl_cv_func_printf_sizes_c99" in
  21       *yes)
  22         case "$gl_cv_func_printf_directive_a" in
  23           *yes)
  24             case "$gl_cv_func_printf_directive_n" in
  25               *yes)
  26                 case "$gl_cv_func_printf_positions" in
  27                   *yes)
  28                     case "$gl_cv_func_snprintf_truncation_c99" in
  29                       *yes)
  30                         case "$gl_cv_func_snprintf_retval_c99" in
  31                           *yes)
  32                             case "$gl_cv_func_snprintf_directive_n" in
  33                               *yes)
  34                                 # snprintf exists and is already POSIX
  35                                 # compliant.
  36                                 gl_cv_func_snprintf_posix=yes
  37                                 ;;
  38                             esac
  39                             ;;
  40                         esac
  41                         ;;
  42                     esac
  43                     ;;
  44                 esac
  45                 ;;
  46             esac
  47             ;;
  48         esac
  49         ;;
  50     esac
  51   fi
  52   if test $gl_cv_func_snprintf_posix = no; then
  53     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  54     gl_REPLACE_VASNPRINTF
  55     gl_REPLACE_SNPRINTF
  56   fi
  57 ])