m4/spawn_h.m4

   1 # spawn_h.m4 serial 10
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SPAWN_H],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  14
  15   dnl <spawn.h> is always overridden, because of GNULIB_POSIXCHECK.
  16   gl_CHECK_NEXT_HEADERS([spawn.h])
  17
  18   AC_CHECK_HEADERS_ONCE([spawn.h])
  19   if test $ac_cv_header_spawn_h = yes; then
  20     HAVE_SPAWN_H=1
  21     AC_CHECK_TYPES([posix_spawnattr_t], [], [HAVE_POSIX_SPAWNATTR_T=0], [[
  22 #include <spawn.h>
  23       ]])
  24     AC_CHECK_TYPES([posix_spawn_file_actions_t], [],
  25       [HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0], [[
  26 #include <spawn.h>
  27       ]])
  28   else
  29     HAVE_SPAWN_H=0
  30     HAVE_POSIX_SPAWNATTR_T=0
  31     HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0
  32     gl_REPLACE_SPAWN_H
  33   fi
  34   AC_SUBST([HAVE_SPAWN_H])
  35
  36   AC_REQUIRE([gl_HAVE_POSIX_SPAWN])
  37
  38   AC_REQUIRE([AC_C_RESTRICT])
  39
  40   dnl Check for declarations of anything we want to poison if the
  41   dnl corresponding gnulib module is not in use.
  42   gl_WARN_ON_USE_PREPARE([[#include <spawn.h>
  43     ]], [posix_spawn posix_spawnp posix_spawnattr_init posix_spawnattr_destroy
  44     posix_spawnattr_getsigdefault posix_spawnattr_setsigdefault
  45     posix_spawnattr_getsigmask posix_spawnattr_setsigmask
  46     posix_spawnattr_getflags posix_spawnattr_setflags
  47     posix_spawnattr_getpgroup posix_spawnattr_setpgroup
  48     posix_spawnattr_getschedpolicy posix_spawnattr_setschedpolicy
  49     posix_spawnattr_getschedparam posix_spawnattr_setschedparam
  50     posix_spawn_file_actions_init posix_spawn_file_actions_destroy
  51     posix_spawn_file_actions_addopen posix_spawn_file_actions_addclose
  52     posix_spawn_file_actions_adddup2])
  53 ])
  54
  55 dnl Checks whether the system has the functions posix_spawn.
  56 dnl Sets ac_cv_func_posix_spawn and HAVE_POSIX_SPAWN.
  57 AC_DEFUN([gl_HAVE_POSIX_SPAWN],
  58 [
  59   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  60   dnl once only, before all statements that occur in other macros.
  61   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  62
  63   AC_CHECK_FUNCS_ONCE([posix_spawn])
  64   if test $ac_cv_func_posix_spawn != yes; then
  65     HAVE_POSIX_SPAWN=0
  66   fi
  67 ])
  68
  69 dnl Unconditionally enables the replacement of <spawn.h>.
  70 AC_DEFUN([gl_REPLACE_SPAWN_H],
  71 [
  72   dnl This is a no-op, because <spawn.h> is always overridden.
  73   :
  74 ])
  75
  76 AC_DEFUN([gl_SPAWN_MODULE_INDICATOR],
  77 [
  78   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  79   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  80   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  81   dnl Define it also as a C macro, for the benefit of the unit tests.
  82   gl_MODULE_INDICATOR([$1])
  83 ])
  84
  85 AC_DEFUN([gl_SPAWN_H_DEFAULTS],
  86 [
  87   GNULIB_POSIX_SPAWN=0;                       AC_SUBST([GNULIB_POSIX_SPAWN])
  88   GNULIB_POSIX_SPAWNP=0;                      AC_SUBST([GNULIB_POSIX_SPAWNP])
  89   GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT=0;     AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT])
  90   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE=0; AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE])
  91   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2])
  92   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN])
  93   GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY])
  94   GNULIB_POSIX_SPAWNATTR_INIT=0;              AC_SUBST([GNULIB_POSIX_SPAWNATTR_INIT])
  95   GNULIB_POSIX_SPAWNATTR_GETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETFLAGS])
  96   GNULIB_POSIX_SPAWNATTR_SETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETFLAGS])
  97   GNULIB_POSIX_SPAWNATTR_GETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETPGROUP])
  98   GNULIB_POSIX_SPAWNATTR_SETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETPGROUP])
  99   GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM])
 100   GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM])
 101   GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY])
 102   GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY])
 103   GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT])
 104   GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT])
 105   GNULIB_POSIX_SPAWNATTR_GETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGMASK])
 106   GNULIB_POSIX_SPAWNATTR_SETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGMASK])
 107   GNULIB_POSIX_SPAWNATTR_DESTROY=0;           AC_SUBST([GNULIB_POSIX_SPAWNATTR_DESTROY])
 108   dnl Assume proper GNU behavior unless another module says otherwise.
 109   HAVE_POSIX_SPAWN=1;        AC_SUBST([HAVE_POSIX_SPAWN])
 110   HAVE_POSIX_SPAWNATTR_T=1;  AC_SUBST([HAVE_POSIX_SPAWNATTR_T])
 111   HAVE_POSIX_SPAWN_FILE_ACTIONS_T=1;
 112                              AC_SUBST([HAVE_POSIX_SPAWN_FILE_ACTIONS_T])
 113   REPLACE_POSIX_SPAWN=0;     AC_SUBST([REPLACE_POSIX_SPAWN])
 114 ])