m4/spawn_h.m4

   1 # spawn_h.m4 serial 8
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SPAWN_H],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  14
  15   dnl <spawn.h> is always overridden, because of GNULIB_POSIXCHECK.
  16   gl_CHECK_NEXT_HEADERS([spawn.h])
  17
  18   AC_CHECK_HEADERS_ONCE([spawn.h])
  19   if test $ac_cv_header_spawn_h = yes; then
  20     HAVE_SPAWN_H=1
  21     AC_CHECK_TYPES([posix_spawnattr_t], [], [HAVE_POSIX_SPAWNATTR_T=0], [[
  22 #include <spawn.h>
  23       ]])
  24     AC_CHECK_TYPES([posix_spawn_file_actions_t], [],
  25       [HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0], [[
  26 #include <spawn.h>
  27       ]])
  28   else
  29     HAVE_SPAWN_H=0
  30     HAVE_POSIX_SPAWNATTR_T=0
  31     HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0
  32     gl_REPLACE_SPAWN_H
  33   fi
  34   AC_SUBST([HAVE_SPAWN_H])
  35
  36   AC_CHECK_FUNCS_ONCE([posix_spawn])
  37   if test $ac_cv_func_posix_spawn != yes; then
  38     HAVE_POSIX_SPAWN=0
  39   fi
  40
  41   AC_REQUIRE([AC_C_RESTRICT])
  42
  43   dnl Check for declarations of anything we want to poison if the
  44   dnl corresponding gnulib module is not in use.
  45   gl_WARN_ON_USE_PREPARE([[#include <spawn.h>
  46     ]], [posix_spawn posix_spawnp posix_spawnattr_init posix_spawnattr_destroy
  47     posix_spawnattr_getsigdefault posix_spawnattr_setsigdefault
  48     posix_spawnattr_getsigmask posix_spawnattr_setsigmask
  49     posix_spawnattr_getflags posix_spawnattr_setflags
  50     posix_spawnattr_getpgroup posix_spawnattr_setpgroup
  51     posix_spawnattr_getschedpolicy posix_spawnattr_setschedpolicy
  52     posix_spawnattr_getschedparam posix_spawnattr_setschedparam
  53     posix_spawn_file_actions_init posix_spawn_file_actions_destroy
  54     posix_spawn_file_actions_addopen posix_spawn_file_actions_addclose
  55     posix_spawwn_file_actions_adddup2])
  56 ])
  57
  58 dnl Unconditionally enables the replacement of <spawn.h>.
  59 AC_DEFUN([gl_REPLACE_SPAWN_H],
  60 [
  61   dnl This is a no-op, because <spawn.h> is always overridden.
  62   :
  63 ])
  64
  65 AC_DEFUN([gl_SPAWN_MODULE_INDICATOR],
  66 [
  67   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  68   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  69   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  70   dnl Define it also as a C macro, for the benefit of the unit tests.
  71   gl_MODULE_INDICATOR([$1])
  72 ])
  73
  74 AC_DEFUN([gl_SPAWN_H_DEFAULTS],
  75 [
  76   GNULIB_POSIX_SPAWN=0;                       AC_SUBST([GNULIB_POSIX_SPAWN])
  77   GNULIB_POSIX_SPAWNP=0;                      AC_SUBST([GNULIB_POSIX_SPAWNP])
  78   GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT=0;     AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT])
  79   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE=0; AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE])
  80   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2])
  81   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN])
  82   GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY])
  83   GNULIB_POSIX_SPAWNATTR_INIT=0;              AC_SUBST([GNULIB_POSIX_SPAWNATTR_INIT])
  84   GNULIB_POSIX_SPAWNATTR_GETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETFLAGS])
  85   GNULIB_POSIX_SPAWNATTR_SETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETFLAGS])
  86   GNULIB_POSIX_SPAWNATTR_GETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETPGROUP])
  87   GNULIB_POSIX_SPAWNATTR_SETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETPGROUP])
  88   GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM])
  89   GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM])
  90   GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY])
  91   GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY])
  92   GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT])
  93   GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT])
  94   GNULIB_POSIX_SPAWNATTR_GETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGMASK])
  95   GNULIB_POSIX_SPAWNATTR_SETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGMASK])
  96   GNULIB_POSIX_SPAWNATTR_DESTROY=0;           AC_SUBST([GNULIB_POSIX_SPAWNATTR_DESTROY])
  97   dnl Assume proper GNU behavior unless another module says otherwise.
  98   HAVE_POSIX_SPAWN=1;        AC_SUBST([HAVE_POSIX_SPAWN])
  99   HAVE_POSIX_SPAWNATTR_T=1;  AC_SUBST([HAVE_POSIX_SPAWNATTR_T])
 100   HAVE_POSIX_SPAWN_FILE_ACTIONS_T=1;
 101                              AC_SUBST([HAVE_POSIX_SPAWN_FILE_ACTIONS_T])
 102   REPLACE_POSIX_SPAWN=0;     AC_SUBST([REPLACE_POSIX_SPAWN])
 103 ])