m4/stat-time.m4

   1 # Checks for stat-related time functions.
   2
   3 # Copyright (C) 1998, 1999, 2001, 2003, 2005, 2006, 2007 Free Software
   4 # Foundation, Inc.
   5
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 dnl From Paul Eggert.
  11
  12 # st_atim.tv_nsec - Linux, Solaris
  13 # st_atimespec.tv_nsec - FreeBSD, if ! defined _POSIX_SOURCE
  14 # st_atimensec - FreeBSD, if defined _POSIX_SOURCE
  15 # st_atim.st__tim.tv_nsec - UnixWare (at least 2.1.2 through 7.1)
  16 # st_spare1 - Cygwin?
  17
  18 AC_DEFUN([gl_STAT_TIME],
  19 [
  20   AC_REQUIRE([AC_C_INLINE])
  21   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  22   AC_CHECK_HEADERS_ONCE([sys/time.h])
  23
  24   AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
  25     [AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
  26        [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
  27        [AC_TRY_COMPILE(
  28           [
  29             #include <sys/types.h>
  30             #include <sys/stat.h>
  31             #if HAVE_SYS_TIME_H
  32             # include <sys/time.h>
  33             #endif
  34             #include <time.h>
  35             struct timespec ts;
  36             struct stat st;
  37           ],
  38           [
  39             st.st_atim = ts;
  40           ],
  41           [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
  42           [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
  43      if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
  44        AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], 1,
  45          [Define to 1 if the type of the st_atim member of a struct stat is
  46           struct timespec.])
  47      fi],
  48     [AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
  49        [AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
  50           [AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [],
  51              [AC_CHECK_MEMBERS([struct stat.st_spare1], [],
  52                 [],
  53                 [#include <sys/types.h>
  54                  #include <sys/stat.h>])],
  55              [#include <sys/types.h>
  56               #include <sys/stat.h>])],
  57           [#include <sys/types.h>
  58            #include <sys/stat.h>])],
  59        [#include <sys/types.h>
  60         #include <sys/stat.h>])],
  61     [#include <sys/types.h>
  62      #include <sys/stat.h>])
  63 ])