m4/stpncpy.m4

   1 # stpncpy.m4 serial 11
   2 dnl Copyright (C) 2002-2003, 2005-2007, 2009-2010 Free Software Foundation,
   3 dnl Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_STPNCPY],
   9 [
  10   dnl Persuade glibc <string.h> to declare stpncpy().
  11   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  12
  13   dnl The stpncpy() declaration in lib/string.in.h uses 'restrict'.
  14   AC_REQUIRE([AC_C_RESTRICT])
  15
  16   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  17
  18   dnl Both glibc and AIX (4.3.3, 5.1) have an stpncpy() function
  19   dnl declared in <string.h>. Its side effects are the same as those
  20   dnl of strncpy():
  21   dnl      stpncpy (dest, src, n)
  22   dnl overwrites dest[0..n-1], min(strlen(src),n) bytes coming from src,
  23   dnl and the remaining bytes being NULs.  However, the return value is
  24   dnl   in glibc:   dest + min(strlen(src),n)
  25   dnl   in AIX:     dest + max(0,n-1)
  26   dnl Only the glibc return value is useful in practice.
  27
  28   AC_CHECK_FUNCS_ONCE([stpncpy])
  29   if test $ac_cv_func_stpncpy = yes; then
  30     AC_CACHE_CHECK([for working stpncpy], [gl_cv_func_stpncpy], [
  31       AC_TRY_RUN([
  32 #include <stdlib.h>
  33 #include <string.h> /* for strcpy */
  34 /* The stpncpy prototype is missing in <string.h> on AIX 4.  */
  35 extern char *stpncpy (char *dest, const char *src, size_t n);
  36 int main () {
  37   const char *src = "Hello";
  38   char dest[10];
  39   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+1 here.  */
  40   strcpy (dest, "\377\377\377\377\377\377");
  41   if (stpncpy (dest, src, 2) != dest + 2) exit(1);
  42   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+4 here.  */
  43   strcpy (dest, "\377\377\377\377\377\377");
  44   if (stpncpy (dest, src, 5) != dest + 5) exit(1);
  45   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+6 here.  */
  46   strcpy (dest, "\377\377\377\377\377\377");
  47   if (stpncpy (dest, src, 7) != dest + 5) exit(1);
  48   exit(0);
  49 }
  50 ], [gl_cv_func_stpncpy=yes], [gl_cv_func_stpncpy=no],
  51         [AC_EGREP_CPP([Thanks for using GNU], [
  52 #include <features.h>
  53 #ifdef __GNU_LIBRARY__
  54   Thanks for using GNU
  55 #endif
  56 ], [gl_cv_func_stpncpy=yes], [gl_cv_func_stpncpy=no])
  57         ])
  58     ])
  59     if test $gl_cv_func_stpncpy = yes; then
  60       AC_DEFINE([HAVE_STPNCPY], [1],
  61         [Define if you have the stpncpy() function and it works.])
  62     else
  63       REPLACE_STPNCPY=1
  64       AC_LIBOBJ([stpncpy])
  65       gl_PREREQ_STPNCPY
  66     fi
  67   else
  68     HAVE_STPNCPY=0
  69     AC_LIBOBJ([stpncpy])
  70     gl_PREREQ_STPNCPY
  71   fi
  72 ])
  73
  74 # Prerequisites of lib/stpncpy.c.
  75 AC_DEFUN([gl_PREREQ_STPNCPY], [
  76   :
  77 ])