m4/stpncpy.m4

   1 # stpncpy.m4 serial 12
   2 dnl Copyright (C) 2002-2003, 2005-2007, 2009-2010 Free Software Foundation,
   3 dnl Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_STPNCPY],
   9 [
  10   dnl Persuade glibc <string.h> to declare stpncpy().
  11   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  12
  13   dnl The stpncpy() declaration in lib/string.in.h uses 'restrict'.
  14   AC_REQUIRE([AC_C_RESTRICT])
  15
  16   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  17
  18   dnl Both glibc and AIX (4.3.3, 5.1) have an stpncpy() function
  19   dnl declared in <string.h>. Its side effects are the same as those
  20   dnl of strncpy():
  21   dnl      stpncpy (dest, src, n)
  22   dnl overwrites dest[0..n-1], min(strlen(src),n) bytes coming from src,
  23   dnl and the remaining bytes being NULs.  However, the return value is
  24   dnl   in glibc:   dest + min(strlen(src),n)
  25   dnl   in AIX:     dest + max(0,n-1)
  26   dnl Only the glibc return value is useful in practice.
  27
  28   AC_CHECK_DECLS_ONCE([stpncpy])
  29   AC_CHECK_FUNCS_ONCE([stpncpy])
  30   if test $ac_cv_func_stpncpy = yes; then
  31     AC_CACHE_CHECK([for working stpncpy], [gl_cv_func_stpncpy], [
  32       AC_TRY_RUN([
  33 #include <stdlib.h>
  34 #include <string.h> /* for strcpy */
  35 /* The stpncpy prototype is missing in <string.h> on AIX 4.  */
  36 #if !HAVE_DECL_STPNCPY
  37 extern char *stpncpy (char *dest, const char *src, size_t n);
  38 #endif
  39 int main () {
  40   const char *src = "Hello";
  41   char dest[10];
  42   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+1 here.  */
  43   strcpy (dest, "\377\377\377\377\377\377");
  44   if (stpncpy (dest, src, 2) != dest + 2) exit(1);
  45   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+4 here.  */
  46   strcpy (dest, "\377\377\377\377\377\377");
  47   if (stpncpy (dest, src, 5) != dest + 5) exit(1);
  48   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+6 here.  */
  49   strcpy (dest, "\377\377\377\377\377\377");
  50   if (stpncpy (dest, src, 7) != dest + 5) exit(1);
  51   exit(0);
  52 }
  53 ], [gl_cv_func_stpncpy=yes], [gl_cv_func_stpncpy=no],
  54         [AC_EGREP_CPP([Thanks for using GNU], [
  55 #include <features.h>
  56 #ifdef __GNU_LIBRARY__
  57   Thanks for using GNU
  58 #endif
  59 ], [gl_cv_func_stpncpy=yes], [gl_cv_func_stpncpy=no])
  60         ])
  61     ])
  62     if test $gl_cv_func_stpncpy = yes; then
  63       AC_DEFINE([HAVE_STPNCPY], [1],
  64         [Define if you have the stpncpy() function and it works.])
  65     else
  66       REPLACE_STPNCPY=1
  67       AC_LIBOBJ([stpncpy])
  68       gl_PREREQ_STPNCPY
  69     fi
  70   else
  71     HAVE_STPNCPY=0
  72     AC_LIBOBJ([stpncpy])
  73     gl_PREREQ_STPNCPY
  74   fi
  75 ])
  76
  77 # Prerequisites of lib/stpncpy.c.
  78 AC_DEFUN([gl_PREREQ_STPNCPY], [
  79   :
  80 ])