m4/strerror_r.m4

   1 # strerror_r.m4 serial 12
   2 dnl Copyright (C) 2002, 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_STRERROR_R],
   8 [
   9   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  10   AC_REQUIRE([gl_FUNC_STRERROR_R_WORKS])
  11
  12   dnl Persuade Solaris <string.h> to declare strerror_r().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Some systems don't declare strerror_r() if _THREAD_SAFE and _REENTRANT
  16   dnl are not defined.
  17   AC_CHECK_DECLS_ONCE([strerror_r])
  18   if test $ac_cv_have_decl_strerror_r = no; then
  19     HAVE_DECL_STRERROR_R=0
  20   fi
  21
  22   if test $ac_cv_func_strerror_r = yes; then
  23     if test "$ERRNO_H:$REPLACE_STRERROR_0" = :0; then
  24       if test $gl_cv_func_strerror_r_posix_signature = yes; then
  25         case "$gl_cv_func_strerror_r_works" in
  26           dnl The system's strerror_r has bugs.  Replace it.
  27           *no) REPLACE_STRERROR_R=1 ;;
  28         esac
  29       else
  30         dnl The system's strerror_r() has a wrong signature. Replace it.
  31         REPLACE_STRERROR_R=1
  32       fi
  33     else
  34       dnl The system's strerror_r() cannot know about the new errno values we
  35       dnl add to <errno.h>, or any fix for strerror(0). Replace it.
  36       REPLACE_STRERROR_R=1
  37     fi
  38   fi
  39 ])
  40
  41 # Prerequisites of lib/strerror_r.c.
  42 AC_DEFUN([gl_PREREQ_STRERROR_R], [
  43   dnl glibc >= 2.3.4 and cygwin 1.7.9 have a function __xpg_strerror_r.
  44   AC_CHECK_FUNCS_ONCE([__xpg_strerror_r])
  45   AC_CHECK_FUNCS_ONCE([catgets])
  46 ])
  47
  48 # Detect if strerror_r works, but without affecting whether a replacement
  49 # strerror_r will be used.
  50 AC_DEFUN([gl_FUNC_STRERROR_R_WORKS],
  51 [
  52   AC_REQUIRE([gl_HEADER_ERRNO_H])
  53   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  54   AC_REQUIRE([gl_FUNC_STRERROR_0])
  55
  56   AC_CHECK_FUNCS_ONCE([strerror_r])
  57   if test $ac_cv_func_strerror_r = yes; then
  58     if test "$ERRNO_H:$REPLACE_STRERROR_0" = :0; then
  59       dnl The POSIX prototype is:  int strerror_r (int, char *, size_t);
  60       dnl glibc, Cygwin:           char *strerror_r (int, char *, size_t);
  61       dnl AIX 5.1, OSF/1 5.1:      int strerror_r (int, char *, int);
  62       AC_CACHE_CHECK([for strerror_r with POSIX signature],
  63         [gl_cv_func_strerror_r_posix_signature],
  64         [AC_COMPILE_IFELSE(
  65            [AC_LANG_PROGRAM(
  66               [[#include <string.h>
  67                 int strerror_r (int, char *, size_t);
  68               ]],
  69               [])],
  70            [gl_cv_func_strerror_r_posix_signature=yes],
  71            [gl_cv_func_strerror_r_posix_signature=no])
  72         ])
  73       if test $gl_cv_func_strerror_r_posix_signature = yes; then
  74         dnl AIX 6.1 strerror_r fails by returning -1, not an error number.
  75         dnl HP-UX 11.31 strerror_r always fails when the buffer length argument
  76         dnl is less than 80.
  77         dnl FreeBSD 8.s strerror_r claims failure on 0
  78         dnl MacOS X 10.5 strerror_r treats 0 like -1
  79         dnl Solaris 10 strerror_r corrupts errno on failure
  80         AC_CACHE_CHECK([whether strerror_r works],
  81           [gl_cv_func_strerror_r_works],
  82           [AC_RUN_IFELSE(
  83              [AC_LANG_PROGRAM(
  84                 [[#include <errno.h>
  85                   #include <string.h>
  86                 ]],
  87                 [[int result = 0;
  88                   char buf[79];
  89                   if (strerror_r (EACCES, buf, 0) < 0)
  90                     result |= 1;
  91                   errno = 0;
  92                   if (strerror_r (EACCES, buf, sizeof buf) != 0)
  93                     result |= 2;
  94                   strcpy (buf, "Unknown");
  95                   if (strerror_r (0, buf, sizeof buf) != 0)
  96                     result |= 4;
  97                   if (errno)
  98                     result |= 8;
  99                   if (strstr (buf, "nknown") || strstr (buf, "ndefined"))
 100                     result |= 0x10;
 101                   errno = 0;
 102                   *buf = 0;
 103                   if (strerror_r (-3, buf, sizeof buf) < 0)
 104                     result |= 0x20;
 105                   if (errno)
 106                     result |= 0x40;
 107                   if (!*buf)
 108                     result |= 0x80;
 109                   return result;
 110                 ]])],
 111              [gl_cv_func_strerror_r_works=yes],
 112              [gl_cv_func_strerror_r_works=no],
 113              [
 114 changequote(,)dnl
 115               case "$host_os" in
 116                        # Guess no on AIX.
 117                 aix*)  gl_cv_func_strerror_r_works="guessing no";;
 118                        # Guess no on HP-UX.
 119                 hpux*) gl_cv_func_strerror_r_works="guessing no";;
 120                        # Guess no on BSD variants.
 121                 *bsd*)  gl_cv_func_strerror_r_works="guessing no";;
 122                        # Guess yes otherwise.
 123                 *)     gl_cv_func_strerror_r_works="guessing yes";;
 124               esac
 125 changequote([,])dnl
 126              ])
 127           ])
 128       else
 129         dnl The system's strerror() has a wrong signature.
 130         dnl glibc >= 2.3.4 and cygwin 1.7.9 have a function __xpg_strerror_r.
 131         AC_CHECK_FUNCS_ONCE([__xpg_strerror_r])
 132         dnl In glibc < 2.14, __xpg_strerror_r does not populate buf on failure.
 133         dnl In cygwin < 1.7.10, __xpg_strerror_r clobbers strerror's buffer.
 134         if test $ac_cv_func___xpg_strerror_r = yes; then
 135           AC_CACHE_CHECK([whether __xpg_strerror_r works],
 136             [gl_cv_func_strerror_r_works],
 137             [AC_RUN_IFELSE(
 138                [AC_LANG_PROGRAM(
 139                   [[#include <errno.h>
 140                     #include <string.h>
 141                     extern int __xpg_strerror_r(int, char *, size_t);
 142                   ]],
 143                   [[int result = 0;
 144                     char buf[256] = "^";
 145                     char copy[256];
 146                     char *str = strerror (-1);
 147                     strcpy (copy, str);
 148                     if (__xpg_strerror_r (-2, buf, 1) == 0)
 149                       result |= 1;
 150                     if (*buf)
 151                       result |= 2;
 152                     __xpg_strerror_r (-2, buf, 256);
 153                     if (strcmp (str, copy))
 154                       result |= 4;
 155                     return result;
 156                   ]])],
 157                [gl_cv_func_strerror_r_works=yes],
 158                [gl_cv_func_strerror_r_works=no],
 159                [dnl Guess no on all platforms that have __xpg_strerror_r,
 160                 dnl at least until fixed glibc and cygwin are more common.
 161                 gl_cv_func_strerror_r_works="guessing no"
 162                ])
 163             ])
 164         fi
 165       fi
 166     fi
 167   fi
 168 ])