m4/strstr.m4

   1 # strstr.m4 serial 5
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check that strstr is efficient.
   8 AC_DEFUN([gl_FUNC_STRSTR],
   9 [
  10   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  11   AC_CACHE_CHECK([whether strstr works in linear time],
  12     [gl_cv_func_strstr_linear],
  13     [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  14 #include <signal.h> /* for signal */
  15 #include <string.h> /* for memmem */
  16 #include <stdlib.h> /* for malloc */
  17 #include <unistd.h> /* for alarm */
  18 ]], [[size_t m = 1000000;
  19     char *haystack = (char *) malloc (2 * m + 2);
  20     char *needle = (char *) malloc (m + 2);
  21     void *result = 0;
  22     /* Failure to compile this test due to missing alarm is okay,
  23        since all such platforms (mingw) also have quadratic strstr.  */
  24     signal (SIGALRM, SIG_DFL);
  25     alarm (5);
  26     /* Check for quadratic performance.  */
  27     if (haystack && needle)
  28       {
  29         memset (haystack, 'A', 2 * m);
  30         haystack[2 * m] = 'B';
  31         haystack[2 * m + 1] = 0;
  32         memset (needle, 'A', m);
  33         needle[m] = 'B';
  34         needle[m + 1] = 0;
  35         result = strstr (haystack, needle);
  36       }
  37     return !result;]])],
  38       [gl_cv_func_strstr_linear=yes], [gl_cv_func_strstr_linear=no],
  39       [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
  40        dnl strstr that works in linear time.
  41        AC_EGREP_CPP([Lucky user],
  42          [
  43 #include <features.h>
  44 #ifdef __GNU_LIBRARY__
  45  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
  46   Lucky user
  47  #endif
  48 #endif
  49 #ifdef __CYGWIN__
  50  #include <cygwin/version.h>
  51  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
  52   Lucky user
  53  #endif
  54 #endif
  55          ],
  56          [gl_cv_func_strstr_linear=yes],
  57          [gl_cv_func_strstr_linear="guessing no"])
  58       ])
  59     ])
  60   if test "$gl_cv_func_strstr_linear" != yes; then
  61     REPLACE_STRSTR=1
  62     AC_LIBOBJ([strstr])
  63   fi
  64 ]) # gl_FUNC_STRSTR