m4/strstr.m4

   1 # strstr.m4 serial 8
   2 dnl Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check that strstr works.
   8 AC_DEFUN([gl_FUNC_STRSTR_SIMPLE],
   9 [
  10   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_MEMCHR])
  12   if test "$gl_cv_func_memchr_works" != yes; then
  13     REPLACE_STRSTR=1
  14     AC_LIBOBJ([strstr])
  15   fi
  16 ]) # gl_FUNC_STRSTR_SIMPLE
  17
  18 dnl Additionally, check that strstr is efficient.
  19 AC_DEFUN([gl_FUNC_STRSTR],
  20 [
  21   AC_REQUIRE([gl_FUNC_STRSTR_SIMPLE])
  22   if test $REPLACE_STRSTR = 0; then
  23     AC_CACHE_CHECK([whether strstr works in linear time],
  24       [gl_cv_func_strstr_linear],
  25       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  26 #include <signal.h> /* for signal */
  27 #include <string.h> /* for memmem */
  28 #include <stdlib.h> /* for malloc */
  29 #include <unistd.h> /* for alarm */
  30 static void quit (int sig) { exit (sig + 128); }
  31 ]], [[size_t m = 1000000;
  32     char *haystack = (char *) malloc (2 * m + 2);
  33     char *needle = (char *) malloc (m + 2);
  34     void *result = 0;
  35     /* Failure to compile this test due to missing alarm is okay,
  36        since all such platforms (mingw) also have quadratic strstr.  */
  37     signal (SIGALRM, quit);
  38     alarm (5);
  39     /* Check for quadratic performance.  */
  40     if (haystack && needle)
  41       {
  42         memset (haystack, 'A', 2 * m);
  43         haystack[2 * m] = 'B';
  44         haystack[2 * m + 1] = 0;
  45         memset (needle, 'A', m);
  46         needle[m] = 'B';
  47         needle[m + 1] = 0;
  48         result = strstr (haystack, needle);
  49       }
  50     return !result;]])],
  51         [gl_cv_func_strstr_linear=yes], [gl_cv_func_strstr_linear=no],
  52         [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
  53          dnl strstr that works in linear time.
  54          AC_EGREP_CPP([Lucky user],
  55            [
  56 #include <features.h>
  57 #ifdef __GNU_LIBRARY__
  58  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
  59   Lucky user
  60  #endif
  61 #endif
  62 #ifdef __CYGWIN__
  63  #include <cygwin/version.h>
  64  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
  65   Lucky user
  66  #endif
  67 #endif
  68            ],
  69            [gl_cv_func_strstr_linear=yes],
  70            [gl_cv_func_strstr_linear="guessing no"])
  71         ])
  72       ])
  73     if test "$gl_cv_func_strstr_linear" != yes; then
  74       REPLACE_STRSTR=1
  75     fi
  76   fi
  77   if test $REPLACE_STRSTR = 1; then
  78     AC_LIBOBJ([strstr])
  79   fi
  80 ]) # gl_FUNC_STRSTR