m4/strstr.m4

   1 # strstr.m4 serial 6
   2 dnl Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check that strstr works.
   8 AC_DEFUN([gl_FUNC_STRSTR_SIMPLE],
   9 [
  10   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_MEMCHR])
  12   if test "$gl_cv_func_memchr_works" != yes; then
  13     REPLACE_STRSTR=1
  14     AC_LIBOBJ([strstr])
  15   fi
  16 ]) # gl_FUNC_STRSTR_SIMPLE
  17
  18 dnl Additionally, check that strstr is efficient.
  19 AC_DEFUN([gl_FUNC_STRSTR],
  20 [
  21   AC_REQUIRE([gl_FUNC_STRSTR_SIMPLE])
  22   AC_CACHE_CHECK([whether strstr works in linear time],
  23     [gl_cv_func_strstr_linear],
  24     [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  25 #include <signal.h> /* for signal */
  26 #include <string.h> /* for memmem */
  27 #include <stdlib.h> /* for malloc */
  28 #include <unistd.h> /* for alarm */
  29 ]], [[size_t m = 1000000;
  30     char *haystack = (char *) malloc (2 * m + 2);
  31     char *needle = (char *) malloc (m + 2);
  32     void *result = 0;
  33     /* Failure to compile this test due to missing alarm is okay,
  34        since all such platforms (mingw) also have quadratic strstr.  */
  35     signal (SIGALRM, SIG_DFL);
  36     alarm (5);
  37     /* Check for quadratic performance.  */
  38     if (haystack && needle)
  39       {
  40         memset (haystack, 'A', 2 * m);
  41         haystack[2 * m] = 'B';
  42         haystack[2 * m + 1] = 0;
  43         memset (needle, 'A', m);
  44         needle[m] = 'B';
  45         needle[m + 1] = 0;
  46         result = strstr (haystack, needle);
  47       }
  48     return !result;]])],
  49       [gl_cv_func_strstr_linear=yes], [gl_cv_func_strstr_linear=no],
  50       [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
  51        dnl strstr that works in linear time.
  52        AC_EGREP_CPP([Lucky user],
  53          [
  54 #include <features.h>
  55 #ifdef __GNU_LIBRARY__
  56  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
  57   Lucky user
  58  #endif
  59 #endif
  60 #ifdef __CYGWIN__
  61  #include <cygwin/version.h>
  62  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
  63   Lucky user
  64  #endif
  65 #endif
  66          ],
  67          [gl_cv_func_strstr_linear=yes],
  68          [gl_cv_func_strstr_linear="guessing no"])
  69       ])
  70     ])
  71   if test "$gl_cv_func_strstr_linear" != yes; then
  72     REPLACE_STRSTR=1
  73     AC_LIBOBJ([strstr])
  74   fi
  75 ]) # gl_FUNC_STRSTR