m4/strtok_r.m4

   1 # strtok_r.m4 serial 9
   2 dnl Copyright (C) 2002, 2003, 2004, 2007, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_STRTOK_R],
   8 [
   9   dnl The strtok_r() declaration in lib/string.in.h uses 'restrict'.
  10   AC_REQUIRE([AC_C_RESTRICT])
  11
  12   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  13   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  14   AC_CHECK_FUNCS([strtok_r])
  15   if test $ac_cv_func_strtok_r = yes; then
  16     dnl glibc 2.7 has a bug in strtok_r that causes a segmentation fault
  17     dnl when the second argument to strtok_r is a constant string that has
  18     dnl exactly one byte and compiling with optimization.  This bug is, for
  19     dnl example, present in the glibc 2.7-18 package in Debian "lenny".
  20     dnl See <http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614>.
  21     AC_CACHE_CHECK([whether strtok_r works], [gl_cv_func_strtok_r_works],
  22       [AC_RUN_IFELSE(
  23          [AC_LANG_PROGRAM([[
  24               #ifndef __OPTIMIZE__
  25               # define __OPTIMIZE__ 1
  26               #endif
  27               #undef __OPTIMIZE_SIZE__
  28               #undef __NO_INLINE__
  29               #include <stdlib.h>
  30               #include <string.h>
  31             ]],
  32             [[char delimiters[] = "xxxxxxxx";
  33               char *save_ptr = (char *) 0xd0d0;
  34               strtok_r (delimiters, "x", &save_ptr);
  35               strtok_r (NULL, "x", &save_ptr);
  36               return 0;
  37             ]])
  38          ],
  39          [gl_cv_func_strtok_r_works=yes],
  40          [gl_cv_func_strtok_r_works=no],
  41          [
  42 changequote(,)dnl
  43           case "$host_os" in
  44                     # Guess no on glibc systems.
  45             *-gnu*) gl_cv_func_strtok_r_works="guessing no";;
  46             *)      gl_cv_func_strtok_r_works="guessing yes";;
  47           esac
  48 changequote([,])dnl
  49          ])
  50       ])
  51     case "$gl_cv_func_strtok_r_works" in
  52       *no)
  53         dnl We could set REPLACE_STRTOK_R=1 and AC_LIBOBJ([strtok_r]) here,
  54         dnl but it's only the macro version in <bits/string2.h> which is wrong.
  55         dnl The code compiled into libc is fine.
  56         UNDEFINE_STRTOK_R=1
  57         ;;
  58     esac
  59   else
  60     AC_LIBOBJ([strtok_r])
  61   fi
  62   AC_CHECK_DECLS_ONCE([strtok_r])
  63   if test $ac_cv_have_decl_strtok_r = no; then
  64     HAVE_DECL_STRTOK_R=0
  65   fi
  66   gl_PREREQ_STRTOK_R
  67 ])
  68
  69 # Prerequisites of lib/strtok_r.c.
  70 AC_DEFUN([gl_PREREQ_STRTOK_R], [
  71   :
  72 ])