m4/sys_select_h.m4

   1 # sys_select_h.m4 serial 5
   2 dnl Copyright (C) 2006-2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_SYS_SELECT],
   8 [
   9   AC_REQUIRE([gl_HEADER_SYS_SOCKET])
  10   AC_CACHE_CHECK([whether <sys/select.h> is self-contained],
  11     [gl_cv_header_sys_select_h_selfcontained],
  12     [
  13       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/select.h>]], [[]])],
  14         [gl_cv_header_sys_select_h_selfcontained=yes],
  15         [gl_cv_header_sys_select_h_selfcontained=no])
  16     ])
  17   if test $gl_cv_header_sys_select_h_selfcontained = yes; then
  18     SYS_SELECT_H=''
  19   else
  20     SYS_SELECT_H='sys/select.h'
  21     gl_CHECK_NEXT_HEADERS([sys/select.h])
  22     if test $ac_cv_header_sys_select_h = yes; then
  23       HAVE_SYS_SELECT_H=1
  24     else
  25       HAVE_SYS_SELECT_H=0
  26     fi
  27     AC_SUBST([HAVE_SYS_SELECT_H])
  28     gl_PREREQ_SYS_H_WINSOCK2
  29   fi
  30   AC_SUBST([SYS_SELECT_H])
  31   if test x$ac_cv_header_winsock2_h = xyes; then
  32     AC_LIBOBJ(winsock-select)
  33   fi
  34 ])